Suche: Einfache Flash-Slideshow mit next-back button und automatischem Durchlauf

[gmadesign]

Hallo!

Wie der Titel schon sagt, suche ich eine einfache Flash-Slideshow mit next-back button und automatischem Durchlauf.

Ich hab hier im Forum schon gesucht, entweder hatten die Files jedoch automatischen Durchlauf und man konnte nicht weiterklicken, oder eben umgekehrt. Vielleicht hat ja jemand einen guten Tipp für ein passendes File.

Danke, lg

Schau mal in den Stuff-Bereich, da findest du Bildergalerien u.ä.

[Der Frager]

Außerdem hatte ich dir gestern schon einen Link geschickt (zu dieser sehr simpel gehaltenen Galerie). Da hättest du nur noch ein Intervall für die automatische Slideshow reinkloppen müssen.
Aber was soll's. Guckst du hier:

PHP-Code:

var tl = this;
var i = -1;
var anz = 4;
var pfad = "bilder/"
var slidePause = 3
tl.createEmptyMovieClip("watcher", 0);
tl.createEmptyMovieClip("loader1", 1);
tl.createEmptyMovieClip("loader2", 2);
function nextPic(back) {
    clearInterval(slideshow);
    next_btn.enabled = prev_btn.enabled=false;
    i += back ? -1 : 1;
    if (i>anz) {
        i = 1;
    } else if (i<=0) {
        i = anz;
    }
    if (mc != tl.loader1) {
        mc = tl.loader1;
    } else {
        mc = tl.loader2;
    }
    mc._alpha = 0;
    mc.swapDepths(2);
    mc.loadMovie(pfad+i+".jpg");
    tl.watcher.onEnterFrame = function() {
        if (mc.getBytesLoaded()>=mc.getBytesTotal() && mc.getBytesLoaded()>4) {
            if (mc._alpha<100) {
                mc._alpha += 10;
            } else {
                delete this.onEnterFrame;
                next_btn.enabled = prev_btn.enabled=true;
                slideshow = setInterval(nextPic, slidePause*1000);
            }
        }
    };
}
//  
nextPic(1);
// 
next_btn.onRelease = function() {
    nextPic();
};
prev_btn.onRelease = function() {
    nextPic(true);
}; 


[gmadesign]

Danke, Frager, ich habs auch durchgesehen. Brauche aber eine Version mit XML, also mit externen XML Files...

Danke trotzdem

[Manollo1987]

Hi Frager,

kann man die ganze Sache auch in einen MC stecken, um maximale Größe und Position festlegen zu können? Ne kleine Anleitung wäre nett...

Gruß, Manollo

[Manollo1987]

Zitat von gmadesign

Danke, Frager, ich habs auch durchgesehen. Brauche aber eine Version mit XML, also mit externen XML Files...

Danke trotzdem

Du kannst dir den Post mal ansehen, die Diashow müsste nach deinen Vorstellungen sein und ist auch in Flash8 gespeichert glaub ich...

Link: Flash Gallery Fade-In-Fade-Out anpassen

Ich habs nur nicht hinbekommen, den ruckartigen Übergang zu korrigieren, sonst hätt ich die auch genommen.

Gruß, Manollo

[Der Frager]

Zitat von gmadesign

Danke, Frager, ich habs auch durchgesehen. Brauche aber eine Version mit XML, also mit externen XML Files...

Und? Ist ja nun gar kein Problem, da einfach ein XML-File zu laden und das dann anstelle des "fixen" Pfades und der einfachen Durchnummerierung der Bild zu verwenden.
Namen (und evtl. Pfad) zu den Bildern in ein Array packen und "i" zum Durchlaufen verwenden. fertig.

[gmadesign]

Hallo Frager!

Hab das jetzt versucht, also ich lade mein XML-File rein, das passt alles. Hab jetzt nur keine Ahnung, ob das mit dem Pfad irgendwie passt...

Kannst du dir das vielleicht mal ansehen?

download

Danke vielmals!

lg

[Der Frager]

Im Prinzip so hier:

PHP-Code:

function loadXML(loaded) {
    if (loaded) {
        xmlNode = this.firstChild;
        image = [];
        description = [];
        total = xmlNode.childNodes.length;
        for (var i=0; i<total; i++) {
            image[i] = xmlNode.childNodes[i].childNodes[0].firstChild.nodeValue;
            description[i] = xmlNode.childNodes[i].childNodes[1].firstChild.nodeValue;
        }
        nextPic();
    } else {
        content = "file not loaded!";
    }
}
xmlData = new XML();
xmlData.ignoreWhite = true;
xmlData.onLoad = loadXML;
xmlData.load("../upload/diashow/"+_root.id+".xml");
//XML Datei mit dem Namen der Variable 
//
var tl = this;
var i = -1;
var anz = 4;
var slidePause = 3;
tl.createEmptyMovieClip("watcher", 0);
tl.createEmptyMovieClip("loader1", 1);
tl.createEmptyMovieClip("loader2", 2);
function nextPic(back) {
    clearInterval(slideshow);
    next_btn.enabled = prev_btn.enabled=false;
    i += back ? -1 : 1;
    if (i>anz) {
        i = 1;
    } else if (i<=0) {
        i = anz;
    }
    if (mc != tl.loader1) {
        mc = tl.loader1;
    } else {
        mc = tl.loader2;
    }
    mc._alpha = 0;
    mc.swapDepths(2);
    mc.loadMovie(image[i]+".jpg");//<---- Evtl. Muss auch das +".jpg" weg, das kann ich nicht wissen
    tl.watcher.onEnterFrame = function() {
        if (mc.getBytesLoaded()>=mc.getBytesTotal() && mc.getBytesLoaded()>4) {
            if (mc._alpha<100) {
                mc._alpha += 10;
            } else {
                delete this.onEnterFrame;
                next_btn.enabled = prev_btn.enabled=true;
                slideshow = setInterval(nextPic, slidePause*1000);
            }
        }
    };
}
//  
next_btn.onRelease = function() {
    nextPic();
};
prev_btn.onRelease = function() {
    nextPic(true);
}; 


[gmadesign]

Hallo Frager nochmal!

So sieht die XML aus, ich hab also das +".jpg" rausgenommen. Laden tut er trotzdem nichts...

Siehe: klick

Hastu du eine Ahnung, wo da noch der Hund drin sein könnte?

PHP-Code:

<?xml version="1.0" encoding="utf-8" standalone="yes"?>
<images>
<pic>
<image>../upload/gallery/871_fullsize.jpg</image>
<caption>testbild 2</caption>
</pic>
<pic>
<image>../upload/gallery/872_fullsize.jpg</image>
<caption>testbild 3</caption>
</pic>
</images>

vielfach Dankeschön.

Hab jetzt mal die id-Übergabe weggelassen und das xml-file per Hand aufgerufen.

download

Hier hab ich ein file mit dem fla, der xml und den beiden bildern.

Vielleicht kannst du noch einmal einen blick darauf werfen. Tausend Dank!!!

[gmadesign]

view

Genau so würd ich mir die Gallery vom Funktionsumfang vorstellen.

Vielleicht kennt ja jemand ein Gratis-Skript dazu...

Danke nochmal, schönen Tag, alle miteinander

[Der Frager]

Da:

PHP-Code:

function loadXML(loaded) {
    if (loaded) {
        xmlNode = this.firstChild;
        image = [];
        description = [];
        total = xmlNode.childNodes.length;
        for (var i = 0; i<total; i++) {
            image[i] = xmlNode.childNodes[i].childNodes[0].firstChild.nodeValue;
            description[i] = xmlNode.childNodes[i].childNodes[1].firstChild.nodeValue;
        }
        anz = image.length;
        nextPic();
    } else {
        content = "file not loaded!";
    }
}
xmlData = new XML();
xmlData.ignoreWhite = true;
xmlData.onLoad = loadXML;
//xmlData.load("../upload/diashow/"+_root.id+".xml");
xmlData.load("1080.xml");
//XML Datei mit dem Namen der Variable 
//
var tl = this;
var i = -1;
var slidePause = 3;
preloader._visible = false;
tl.createEmptyMovieClip("watcher", 0);
tl.createEmptyMovieClip("loader1", 1);
tl.createEmptyMovieClip("loader2", 2);
function nextPic(back) {
    clearInterval(slideshow);
    next_btn.enabled = previous_btn.enabled=false;
    i += back ? -1 : 1;
    trace(anz);
    if (i>=anz) {
        i = 0;
    } else if (i<0) {
        i = anz-1;
    }
    if (mc != tl.loader1) {
        mc = tl.loader1;
    } else {
        mc = tl.loader2;
    }
    mc._alpha = 0;
    mc.swapDepths(2);
    mc.loadMovie(image[i]);
    preloader._visible = true;
    preloader._xscale = 0;
    tl.watcher.onEnterFrame = function() {
        var l = mc.getBytesLoaded();
        var t = mc.getBytesTotal();
        preloader._xscale = l/t*100;
        if (l>=t && l>4) {
            preloader._visible = false;
            if (mc._alpha<100) {
                mc._alpha += 10;
            } else {
                delete this.onEnterFrame;
                next_btn.enabled = previous_btn.enabled=true;
                slideshow = setInterval(nextPic, slidePause*1000);
            }
        }
    };
}
//  
next_btn.onRelease = function() {
    nextPic();
};
previous_btn.onRelease = function() {
    nextPic(true);
}; 


Die Buttons musst du noch in den Vordergrund holen (wenn du MCs draus machst z.B. mit swapDepths()).
Ansonsten tut das Ding wohl wie's soll.

[gmadesign]

Hey, danke!

Die Sache ist, dass genau das, was ich gebraucht hätte, nicht erfüllt wird. So eine version hatte ich schon, wenn du dich erinnern kannst.

Die Bilder sollten ineinander faden, und nicht einfach darübergeladen werden. Ansonsten sag ich mal : Tausend Dank! Geht das irgendwie noch mit den Übergängen? Mit flüssigeren?

Danke dir!

So wie bei dem Beispiel 2 Posts höher...

[Der Frager]

Hab's gerade noch mal getestet. Die werden übereinander gefaded. Weiß also nciht, wo dein Problem ist...

[Manollo1987]

Ja, würd mich auch mal interessiern, ob das mit den Transition Tweens zu machen ist (statt Alpha zu reduzieren). Wenn ich schon auf meinen Post da oben keine Antwort bekomm, dann vllt auf den hier...

Greets, Manollo