[Flash 8] Scharfe Übergänge in Bildergalerie mit Script lösen

[ostseepixel]

Hallo,

habe mal versucht eine kleine bildergalerie zu basteln...
habe mehrere buttons untereinander und rechts wird in ein platzhalter moviclip ein bild beim moseover geladen...

mein problem: die übergänge sind sehr hart ... kann man das irgendwie mit dem script regeln?

hab mal hier was zusammengestümpert ... aber irgendwie wird das nichts...

btn_1.onRollOver = function(){
platzhalter_mc.loadMovie("bild1.jpg");
if (getProperty(platzhalter_mc, _alpha)>0) {
setProperty ("platzhalter_mc", _alpha, getProperty(platzhalter_mc, _alpha)+50);
}
}
btn_1.onRollOut = function(){
if (getProperty(platzhalter_mc, _alpha)>0) {
setProperty ("platzhalter_mc", _alpha, getProperty(platzhalter_mc, _alpha)-50);
}
}


btn_2.onRollOver = function(){
platzhalter_mc.loadMovie("bild2.jpg");
if (getProperty(platzhalter_mc, _alpha)>0) {
setProperty ("platzhalter_mc", _alpha, getProperty(platzhalter_mc, _alpha)+50);
}
}
btn_2.onRollOut = function(){
if (getProperty(platzhalter_mc, _alpha)>0) {
setProperty ("platzhalter_mc", _alpha, getProperty(platzhalter_mc, _alpha)-50);
}
}


.
.
.


Vilen dank, bin in Flash noch recht am Anfang

[RustyCake]

Ja da brauchts aber ein bisschen AS, zum aus/einfaden!!

[ostseepixel]

Wie macht man das? würdest du mir das erklären? bitte?

[RustyCake]

Einen Auszug aus einer Galerie kann ich Dir geben!!

////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
var main_navieArray:Array = ["home_base", "basic_things", "movie_things", "navie_things", "loader_things","gallery_things", "other_things", "drawing_things"];
///////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
var tl:MovieClip = this;
var old_basic:String = null;
var old_btn:MovieClip = null;
for (var i:Number = 0; i<main_navieArray.length; i++)
{
    this.createEmptyMovieClip("container_mc"+i, this.getNextHighestDepth());
    this["container_mc"+i]._x = 10;
    this["container_mc"+i]._y = 130;
    var mc:MovieClip = this.main_navie_mc[main_navieArray[i]+"_mc"];
    mc.ID = i;
    mc.onRelease = function()
    {
        old_btn.enabled = true;
        load_x(tl["container_mc"+this.ID], main_navieArray[this.ID]+".swf", tl.main_navie_mc[main_navieArray[this.ID]+"_mc"]);
    };
}
load_x(tl["container_mc"+0], main_navieArray[0]+".swf", this.main_navie_mc[main_navieArray[0]+"_mc"]);
///////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
function load_x(wo:MovieClip, was:String, aus:MovieClip):Void
{
    aus.enabled = false;
    old_btn = aus;
    wo.loadMovie(was);
    wo._alpha = 0;
    function loader_funk():Void
    {
        if (wo.getBytesLoaded()>=4)
        {
            var gesamt:Number = wo.getBytesTotal();
            var bereits:Number = wo.getBytesLoaded();
            var prozent:Number = Math.ceil((bereits/gesamt)*100);
            
            if (prozent == 100)
            {
                wo._alpha += 5;
                tl.old_basic._alpha -= 5;
                if (wo._alpha>=100)
                {
                    tl.old_basic.unloadMovie();
                    tl.old_basic = wo;
                    clearInterval(loadID);
                }
            }
        }
    }
    var loadID:Number = setInterval(loader_funk, 25);
} 

[ostseepixel]

hm das ist ja ganz lieb von dir.. aber ich glaube so ganz ohne erklärung werde ich aus dem script nicht schlau...

[RustyCake]

In das Array schreibst die Namen Deiner Button's, die Buttons schiebst in einen MC mit dem Instanznamen "main_navie_mc", überall wo ".swf" steht, machst ein ".jpg" draus, dann ,müßte des funktionieren
Alles andere geht automatisch,!
Ach ja, die Bilder sollten so heißen, wie die Buttons!!

[~pyropete~]

Uiui, setProperty() das ist ja uralt-Kram

Wenn Du noch Lust hast, dann guck Dir neben rustys Beispiel auch mal
das hier an:

// Import der Tweenklasse
import mx.transitions.Tween;
import mx.transitions.easing.*;
//
var i:Number = 0;
// die Namen der Buttons
var captions:Array = ["Bild 1 laden", "Bild 2 laden"];
// Ladeziel der Bilder erstellen
var pic:MovieClip = this.createEmptyMovieClip("pic", this.getNextHighestDepth());
// neues MovieClipLoader-Objekt erstellen
var mcl:MovieClipLoader = new MovieClipLoader();
// neues Listener-Objekt
var listener:Object = new Object();
// sobald das Bild geladen wurde, führe die Aktionen von onLoadInit aus
listener.onLoadInit = function(mc) {
    // das geladene Bild einfaden, hier mc von 0 auf 100 in 1 sekunde (true)
    var fadein:Tween = new Tween(mc, "_alpha", Strong.easeInOut, 0, 100, 1, true);
};
// Listener an MovieClipLoader anhängen
mcl.addListener(listener);
// die Buttons zur Laufzeit generieren
for (i=0; i<captions.length; i++) {
    // neuen Button generieren
    var btn:MovieClip = this.attachMovie("button", "btn"+i, this.getNextHighestDepth(), {_x:i*200, _y:300});
    // Button sein Label zuweisen
    btn._caption.text = captions[i];
    // Button einen Zähler für das zu ladene Bild zuweisen
    btn._id = int(i+1);
    btn.onRelease = btn.onReleaseOutside=function () {
        // Bildcounter auf den aktuellen Zähler des gedrückten Button setzen
        var counter:Number = this._id;
        // das bereits geladene Bild (hier pic) ausfaden
        var fadeout:Tween = new Tween(pic, "_alpha", Strong.easeInOut, 100, 0, 1, true);
        // sobald der Tween zum Ausfaden beendet ist
        fadeout.onMotionFinished = function() {
            // neues Bild laden
            mcl.loadClip("bild"+counter+".jpg",pic);
        };
    };
}
// erstes Bild laden in pic
mcl.loadClip("bild1.jpg",pic); 

Spart Dir ne Menge Schreibarbeit mit MovieClipLoader und Tween-Klasse,
weil Du nix mehr von Hand coden musst. Für den MovieClipLoader gibt es
auch noch weitere Methoden (onLoadProgress, onLoadError), guck mal
in die Hilfedatei von Flash.

Damit das funktioniert brauchst Du noch die Bilder (bild1.jpg, bild2.jpg, ...).
Die bitte im selben Ordner ablegen wie die FLA-Datei.
Wenn Du weitere Bilder laden willst, das Array captions dementsprechend
erweitern und die Bilder in den Ordner der FLA legen.

[ostseepixel]

hallo nochmal,

ich danke euch ich hab mal beides ausprobiert...

@rusty: hm klag einfach, ein bild öffnet sich auch echt schnike, dann aber sobald ich die anderen buttons betätige passiert nichts...

@pyropete; funktioniert super nur ... deins ist ein bisschen schwerer nachzuvollziehen, vor allem habe ich jetzt das problem das ganze auf meine eigenen buttons anzuwenden...das ganze soll ja bei einem moseover passieren und nicht erst wenn man drauf klickt...


lg

[Decrone]

Zitat von ostseepixel

@pyropete; funktioniert super nur ... deins ist ein bisschen schwerer nachzuvollziehen, vor allem habe ich jetzt das problem das ganze auf meine eigenen buttons anzuwenden...das ganze soll ja bei einem moseover passieren und nicht erst wenn man drauf klickt...

lg

dann ändere doch das so um

PHP-Code:

btn.onRollOver=function () {...} 


[ostseepixel]

@Decrone; Danke, das hatte ich inzwischen auch schon gelöst , eine Idee vielleicht wie ich jetzt die buttons nach unten hin anordnen lasse... weil die sich hier immer automatisch waagerecht anordnen... ?

[ostseepixel]

hui ich hab jetzt auch das geschafft war gar nicht so schwer... hab einfach das i* vor das y statt vor das x gesetzt und bisschen die werte angepasst wie ichs haben wollte!!!

{_x:i*200, _y:300});


Oh vielen Dank Ihr habt mir sehr geholfen!
komme bestimmt wieder wegen anderen wehwechen!

[ostseepixel]

hihi hab doch noch eine Frage bezüglich des scriptes von pyropete

meine buttons sollten jetzt einen moseover effekt haben, und da habe ich in die mc button unter die ebene _caption eine ebene reingelegt wo ein button drin ist mit dem effekt aber das funktioniert nicht... wieso nicht? und wie mach ich das richtig?

und dann habe ich noch die Frage; wie verlinke ich jeden dieser automatisch erstellten buttons zu einer anderen Seite? geht das überhaupt?

Danke

[Decrone]

schau dir mal die Array in dem die Bilder liegen. Das gleiche machste mit den Links. Also eine Array erstellen und die Links im Stringformat eintragen!

Beispiel:

PHP-Code:

var captions:Array = ["Bild 1 laden", "Bild 2 laden"];
var bildLinks:Array = ["www.zielDomäne1.de", "www.zielDomäne2.de"];

btn.onRelease = function(){
    getURL(bildLinks[this._id], "_blank");
} 


das Geheimnis liegt in der "_id" jeder Button/Bild bekommt beim erstellen eine _id als Nr. mit!

Gruß Dec

[ostseepixel]

Danke, das mit den Arrays hab ich jetzt wirrklich gut verstanden ...

Noch ein Tipp wie man die geladenen Bilder etwas tiefer setzt, oder andere objekte höher, weil meine objekte die dadrüber liegen sollten jetzt alle verdekt werden...

LG und vielen herzlichen Dank - indemutverbeug*