[Flash CS5] Problem mit der Darstellung eines Movieclips

[madmax2003]

Hi,

nach langer Zeit arbeite ich wieder an einer Flash Seite!
Und natürlich habe ich gleich ein paar Fragen:

Meine Flash passt sich der Browsergröße an und der Movieclip passt sich von seiner Größe her auch mit an.
Ich habe ein paar Buttons mit denen ich in einem Movieclip auf der Zeitleiste herumspringe. Auf Frame 1 ist nur ein grauer Hintergrund und auf 2 ein Videoplayer und Videos.

Wenn ich den Video Frame lade, wird der immer verzerrt und zu groß angezeigt. Wenn ich dann auch noch die Größe des Fensters ändere, wird der Frame zwar kleiner aber auch total zusammengestaucht.

Link zur Seite

Code in der Root Ebene:

import flash.display.StageAlign; 
import flash.display.StageScaleMode; 

import com.greensock.easing.*;
import com.greensock.TweenLite;


stage.scaleMode = StageScaleMode.NO_SCALE; 
stage.align = StageAlign.TOP_LEFT; 

var eckeRStartX = 0;
var eckeRStartY = 0;
var eckeLStartX = 0;
var eckeLStartY = 0;
var contentWidth = 0;
var contentHeight = 0;
var aniTime = 1;

stage.addEventListener(Event.RESIZE, resizehandler); 

setPositions();

//*************  EDGE MOVEMENTS  ************

function resizehandler(e:Event):void 
{ 
	setPositions();
}  


function setPositions():void {
	
	eckeRStartX = stage.stageWidth - eckeR.width * 1.5;
	eckeRStartY = eckeR.height / 2;
	eckeLStartX = eckeL.width  / 2;
	eckeLStartY = stage.stageHeight - eckeL.height * 1.5;
	
	contentWidth =  stage.stageWidth  * 0.6;
	contentHeight = stage.stageHeight * 0.5;
	content_mc.width =  contentWidth;
	content_mc.height = contentHeight;
	content_mc.y = stage.stageHeight / 2;
	content_mc.x = stage.stageWidth  / 2;
	
	rect_mc.y = stage.stageHeight - rect_mc.height; 
	rect_mc.x = stage.stageWidth/2 - rect_mc.width/2;

	eckeL.x = eckeLStartX;
	eckeL.y = eckeLStartY;
	
	eckeR.x = eckeRStartX;
	eckeR.y = eckeRStartY ;
}

function moveIn():void {
	
	TweenLite.to(eckeL,aniTime,{x:stage.stageWidth/2-eckeL.width/2,y:stage.stageHeight/2-eckeL.height/2});
	TweenLite.to(eckeR,aniTime,{x:stage.stageWidth/2-eckeR.width/2,y:stage.stageHeight/2-eckeR.height/2});
	//TweenLite.to(content_mc,aniTime,{alpha:0,scaleX:0.3, scaleY:0.3});
	//TweenLite.to(content_mc,aniTime,{alpha:0,width:10, height:10});
}

function moveOut():void {
	
	TweenLite.to(eckeL,aniTime,{x:eckeLStartX,y:eckeLStartY});
	TweenLite.to(eckeR,aniTime,{x:eckeRStartX,y:eckeRStartY});
	//TweenLite.to(content_mc,aniTime,{alpha:1,scaleX:1, scaleY:1});
	//TweenLite.to(content_mc,aniTime,{alpha:1,width:contentWidth, height:contentHeight});
}	

//*************  NAVIGATION  ************
this.rect_mc.btn1.addEventListener(MouseEvent.CLICK, btn1_CLICK);

function btn1_CLICK(e:MouseEvent):void
{
	moveIn();
}

this.rect_mc.btn2.addEventListener(MouseEvent.CLICK, btn2_CLICK);

function btn2_CLICK(e:MouseEvent):void
{
	moveOut();
}

this.rect_mc.btn3.addEventListener(MouseEvent.CLICK, btn3_CLICK);

function btn3_CLICK(e:MouseEvent):void
{
	/*var loader:Loader = new Loader();
	loader.load(new URLRequest("Video Player.swf"));
	loader.x = -100;
	loader.y = -100;
	content_mc.addChild(loader); */
	content_mc.gotoAndStop(2);
}

this.rect_mc.btn4.addEventListener(MouseEvent.CLICK, btn4_CLICK);

function btn4_CLICK(e:MouseEvent):void
{
	content_mc.gotoAndStop(2);
}

/*var i:int = 0; 
while(i < numChildren) { 
    trace(getChildAt(i).name + " is at position: " + i++); 
}


var target:DisplayObject = getChildByName("instance20");
//trace(getChildIndex(target));
setChildIndex(target,0);
//target = getChildByName("rect_mc");
//trace(getChildIndex(target));
 i = 0; */

der Code zum Videoplayer:

stop();
import fl.video.*;

var thumb_width:Number;
var thumb_height:Number;
var thumbs_x:Number;
var thumbs_y:Number;
var video_x:Number;
var video_y:Number;
var my_videos:XMLList;
var my_total:Number;

var main_container:Sprite;
var thumbs:Sprite;
var titles:Sprite;
var my_player:FLVPlayback;

var myXMLLoader:URLLoader = new URLLoader();
myXMLLoader.load(new URLRequest("playlist.xml"));
myXMLLoader.addEventListener(Event.COMPLETE, processXML);

function processXML(e:Event):void
{
	var myXML:XML = new XML(e.target.data);

	thumb_width = myXML. @ THUMB_WIDTH;
	thumb_height = myXML. @ THUMB_HEIGHT;
	thumbs_x = myXML. @ THUMBS_X;
	thumbs_y = myXML. @ THUMBS_Y;
	video_x = myXML. @ VIDEO_X;
	video_y = myXML. @ VIDEO_Y;
	my_videos = myXML.VIDEO;
	my_total = my_videos.length();

	makeContainers();
	callThumbs();
	makePlayer();

}

function makePlayer():void
{
	my_player = new FLVPlayback();
	my_player.skin = "SkinOverPlaySeekMute.swf";
	my_player.skinBackgroundColor = 0xAEBEFB;
	my_player.skinBackgroundAlpha = 0.5;

	my_player.x = video_x;
	my_player.y = video_y;
	my_player.width = 380;
	my_player.height = 220;

	main_container.addChild(my_player);
	my_player.source = my_videos[0].@URL;
}

function playVideo(e:MouseEvent):void
{
	var video_url = my_videos[e.target.name]. @ URL;
	my_player.source = video_url;
}

function callThumbs():void
{
	for (var i:Number = 0; i < my_total; i++)
	{

		var thumb_url = my_videos[i]. @ THUMB;
		var thumb_loader = new Loader();
		thumb_loader.name = i;
		thumb_loader.load(new URLRequest(thumb_url));
		thumb_loader.contentLoaderInfo.addEventListener(Event.COMPLETE, thumbLoaded);
		thumb_loader.y = (thumb_height + 10)*i;

		var thumb_title = my_videos[i]. @ TITLE;
		var title_txt:TextField = new TextField();
		title_txt.text = thumb_title;
		title_txt.x = thumb_width + 10;
		title_txt.y = thumb_loader.y;
		title_txt.width = thumb_width;
		title_txt.height = thumb_height;
		title_txt.wordWrap = true;
		titles.addChild(title_txt);
	}
}

function thumbLoaded(e:Event):void
{
	var my_thumb:Loader = Loader(e.target.loader);
	thumbs.addChild(my_thumb);
}

function makeContainers():void
{
	main_container = new Sprite();
	addChild(main_container);

	thumbs = new Sprite();
	thumbs.addEventListener(MouseEvent.CLICK, playVideo);
	thumbs.addEventListener(MouseEvent.MOUSE_OVER, onOver);
	thumbs.addEventListener(MouseEvent.MOUSE_OUT, onOut);
	thumbs.x = thumbs_x;
	thumbs.y = thumbs_y;
	thumbs.buttonMode = true;
	main_container.addChild(thumbs);

	titles = new Sprite();
	titles.x = thumbs_x;
	titles.y = thumbs_y;
	main_container.addChild(titles);
}

function onOver(e:MouseEvent):void
{
	var my_thumb:Loader = Loader(e.target);
	my_thumb.alpha = 0.5;
}

function onOut(e:MouseEvent):void
{
	var my_thumb:Loader = Loader(e.target);
	my_thumb.alpha = 1;
}

Wäre für jeden Tipp dankbar!!

lg Max