[Flash CS5] Newsticker Lauftext mit .txt Source Datei

[lalelu2]

Hier reichen meine ActionScript-Kenntnisse leider nicht aus, auch wenn die Lösung vielleicht banal sein mag. Der Ticker (s.u.) funktioniert einwandfrei und soll vom Code auch so beibehalten werden. Nur der einfacheren Aktualisierung halber wäre es schön, wenn sich der Ticker-Text zentral aus einer Textdatei auslesen ließe.

Dateiformat ist derzeit FlashPlayer 9 und ActionScript 2.0

Würde mich über eure Hilfe freuen.

PHP-Code:

Stage.scaleMode = "noScale";
Stage.align = "TL";
Stage.showMenu = false;
mcNTBG._width = Stage.width;
var stageListener:Object = new Object();
stageListener.onResize = function() {
    mcNTBG._width = Stage.width;
    txtScroll();
};
Stage.addListener(stageListener);
var scrolltext:String;
if(!st){
    scrolltext = "hier steht derzeit noch der text, der in zukunft aus der zentralen txt.datei ausgelesen werden soll.";
}else{
    scrolltext = st;
}
    var aTextinst:Array = new Array();
    var nXValue:Number = 0;
    var nXValue2:Number = 0;
    var nIID:Number;
    var tfFormat:TextFormat = new TextFormat();
    tfFormat.font = "courier new"; // Schriftart
    tfFormat.size = 12; // Schriftgröße
    tfFormat.color = 0x000000; // Schriftfarbe
    tfFormat.letterSpacing  = 1; //Zeichenabstand
    tfFormat.kerning = false;
    function moveTxt():Void {
        for(values in aTextinst){
            aTextinst[values]._x -= 1;
            if(aTextinst[values]._x < -(aTextinst[values]._width)){
                aTextinst[values]._x = nXValue2;
            }
        }
    }
    function txtScroll() {
        clearInterval(nIID);
        nXValue = 0;
        nXValue2 = 0;
        aTextinst = [];
        for (item in this){
            if(this[item]._name.indexOf("tScroller") == 0){
                trace("name: "+this[item]._name);
                this[item].removeTextField();
            }
        }
        while (nXValue2 < Stage.width){
            var tScroll:TextField = this.createTextField("tScroller"+nXValue, this.getNextHighestDepth(), nXValue, -4, 10, 10)
            tScroll.setNewTextFormat(tfFormat);
            tScroll.text = scrolltext.toUpperCase()+" +++ ";
            tScroll.autoSize = "left";
            nXValue += Math.ceil(tScroll._width);
            nXValue2 = nXValue - Math.ceil(tScroll._width);
            aTextinst.push(tScroll);
        }
       
        nIID = setInterval(this, "moveTxt", 30); // Geschwindigkeit des Lauftextes, je höher desto langsamer
    }
    txtScroll(); 


[RustyCake]

Servus und Willkommen

Das könnte man eigentlich auch aus der Hilfe herausbekommen

PHP-Code:

var text_lv:LoadVars = new LoadVars();
text_lv.onData = function (src:String):Void {
    if (src != undefined) {
       scrolltext = src;
    } else {
        scrolltext = "Unable to load external file.";
    }
    txtScroll();
}
text_lv.load("text.txt"); 


[lalelu2]

funzt. geil. vielen herzlichen dank.