[Flash CS5] Movieclip nach Mauszeiger rotieren lassen

[student1]

Hallo zusammen,
das wird wahrscheinlich ein etwas längerer Beitrag, aber hoffe trotzdem dass sich jemand kurz die Zeit nehmen könnte und sich mein Problem mal anschaut. ich versuche ein Auge (Movieclip) in AS3 je nach Position des Mauszeigers rotieren zu lassen.
habe folgenden Code (im www gefunden) in Frame 1 des zu rotierenden mc's (auge) kopiert und funktioniert einwandfrei:

stage.addEventListener(Event.ENTER_FRAME,rotate);
function rotate (e:Event){  
    var theX:int = mouseX - auge.x;
    var theY:int = (mouseY - auge.y) * -1;
        var angle = Math.atan(theY/theX)/(Math.PI/180);
    Math.atan(-5/10)/(Math.PI/180);
    if (theX<0) {
    angle += 180;}
        if (theX>=0 && theY<0) {
    angle += 360;
        }
        auge.rotation = (angle*-1) + 90 
} 

jetzt muss ich aber (Aufgabenstellung von unserem Prof.) alles komplett in AS3 und in verschiedene Klassen schreiben.
hier mal meine Klassen (nur mit dem dafür relevanten Code):

Main:

package  {
    
    import flash.display.MovieClip;
    import flash.events.Event;  
    import view.ViewStart;
    
    public class Main extends MovieClip {
 
        public var m_ViewStart : ViewStart;
        
        public function Main() {
            startansicht();
            }
 
        public function startansicht(){
            m_ViewStart = new ViewStart();
            m_ViewStart.viewstartansicht();
            addChild(m_ViewStart);
            }
    }
} 

ViewStart:

package view {
    import flash.display.MovieClip;
    import data.DataAuge;
    import controller.ControllerAuge;
        
    public class ViewStart extends MovieClip{
 
        public var d_auge : DataAuge;
        public var c_auge : ControllerAuge;
        
        public function viewstartansicht(){
 
            d_auge = new DataAuge();
            c_auge = new ControllerAuge();
                 
            d_auge.addauge();
            addChild(d_auge);
            c_auge.augerotate();        
        }
    }
} 

ControllerAuge:

package controller {
    
    import flash.display.MovieClip;
    import flash.events.*;
    import data.DataAuge;
    
    public class ControllerAuge extends MovieClip {
 
        public var d_augerotate : DataAuge;
 
        public function ControllerAuge() {
            super();
        }
        
        public function augerotate(){
            d_augerotate = new DataAuge();      
            stage.addEventListener(Event.ENTER_FRAME,d_augerotate.rotate);
            addChild(d_augerotate);
            }      
    }
} 

DataAuge:

package data {
    
    import flash.events.*;
    import flash.ui.Mouse;
    import flash.display.MovieClip;
    
    public class DataAuge extends MovieClip {
 
        public function DataAuge() {
            super();
        }
 
        public var augerotate : MovieClip;
 
        public function addauge() {
            augerotate = new auge();
            augerotate.x = 200;
            augerotate.y = 345;   
            this.addChild(augerotate);
            }
 
        public function rotate (e:Event) : void {
            var theX : int = mouseX - augerotate.x;
            var theY : int = (mouseY - augerotate.y) * -1;  
            var angle = Math.atan(theY/theX)/(Math.PI/180); 
            Math.atan(-5/10)/(Math.PI/180); 
           if (theX<0) {
                angle += 180;
                }
          if (theX>=0 && theY<0) {
                angle += 360;
                }
          augerotate.rotation = (angle*-1) + 90;
            
            addChild(augerotate);         
            }
    }
    
} 

bekomme jetzt immer folgende fehlermeldung und weiß nicht mehr weiter

TypeError: Error #1009: Der Zugriff auf eine Eigenschaft oder eine Methode eines null-Objektverweises ist nicht möglich.
at controller::ControllerAuge/augerotate()
at view::ViewStart/viewstartansicht()
at Main/startansicht()
at Main()

wäre super wenn mir jemand helfen könnte!
DANKE schon mal im voraus!

[Martin Kraft]

Lösch mal das »stage.« in Zeile 17 von ControllerAuge!

Ansonsten solltest Du überall dort, wo Du MovieClips verwendest, besser auf Sprites zurückgreifen. MovieClips benötigt man in AS3 nämlich nur noch, wenn sie wirklich Zeitleisten Animationen enthalten.

[student1]

Hallo Martin,
DANKE für die schnelle Antwort!
habe das "stage" gelöscht und bekomme jetzt folgenden Fehler:

TypeError: Error #1009: Der Zugriff auf eine Eigenschaft oder eine Methode eines null-Objektverweises ist nicht möglich.
at data:ataAuge/rotate()

werde das mit den Sprites jetzt mal versuchen. bin ziemlicher Neuling in AS und wusste gar nicht dass es die gibt aber danke für den Tipp!
sollte aber doch eigentlich so auch schon funktionieren, oder?
Viele Grüße

[thomas_E]

umständlich, in mehrerlei Hinsicht.

mal davon abgesehen, dass man diese Berechnung in AS3 auch als einzeiler formulieren kann, folgendes:
- deine Controller-Klasse ist momentan völlig überflüssig, und dient höchstens der Verwirrung
- dafür kapselt DataAuge den View und spielt selber controller.
- ViewStart ist eine Komposition aus View und Controller. später durchaus mal sinvoll, aber jetzt solltest du sie erstmal weglassen, bis der restliche Code läuft.
- ist dir eigentlich aufgefallen, dass du 2 DataAugen erzeugst? einen in ViewStart, und einen in ControllerAuge.
und da kommt jetzt dieser Fehler her:
bei dem in ControllerAuge rufst du zwar rotate() auf (Event-Listener), aber du initialisierst das Objekt nicht mit addauge().
und bei dem in ViewStart rufst du zwar addauge() auf, aber rotate() nicht.


hier mal ein Beispiel:

PHP-Code:

//mein Auge
package
{
    import flash.display.Shape;

    class Auge extends Shape
    {
        public function Auge() 
        {
            graphics.lineStyle(1,0x8080FF);
            graphics.drawCircle(0, 0, 20);
            graphics.lineStyle();
            
            graphics.beginFill(0x8080FF);
            graphics.drawCircle(7, 0, 11);
            
            graphics.beginFill(0x000000);
            graphics.drawCircle(7, 0, 7);
            graphics.endFill();
        }
    }
} 


einfach irgendwas sichtbares, völlig dumm, nur Grafik.
(kann natürlich auch animiert sein, nur solltest du darauf achten, dass die Animation sich nicht mit dem Controller beisst)

PHP-Code:

//mein Controller:
package
{
    import flash.display.DisplayObject;
    import flash.events.Event;
        
    class Controller
    {
        private var _target:DisplayObject;
        
        public function Controller(target:DisplayObject)
        {
            _target = target;
            _target.addEventListener(Event.ENTER_FRAME, loop);
        }
        
        private function loop(e:Event):void 
        {
            _target.rotation += Math.atan2(_target.mouseY, _target.mouseX) * 180 / Math.PI;
            //_target.rotation += Math.atan2(_target.mouseY, _target.mouseX) * 5;        //mit easing
        }
    }
} 


nur Programmlogik: kennt sein Zielobjekt, und was es damit machen soll. mehr muss er nicht wissen oder sein. Bspw. ist der Controller (hier) auch kein Anzeigeobjekt, wie bei dir.

PHP-Code:

//Aufruf (in Main):
var auge:Auge = new Auge();
    auge.x = 220;
    auge.y = 180;
addChild(auge);
var controller:Controller = new Controller(auge); 


also kürzer gehts nicht mehr. View erstellen, positionieren und auf die Bühne bringen, dann Controller erstellen, und mit dem View bekannt machen.

[student1]

hallo thomas
also dein code hat mir schon mal sehr geholfen. DANKE!!
auch wenn dein einzeiler bei der berechnung mein "auge" um den Nullpunkt der Bühne dreht und nicht um seinen eigenen Mittelpunkt. aber da kann ich ja meine Berechnung wieder verwenden.
das mit den verschiedenen klassen und verkapselungen ist durchaus beabsichtigt. ich weiß dass es alles etwas umständlich ist und würde es am liebsten auch einfacher machen. aber es handelt sich um eine semesterarbeit und das ist alles so vorgegeben (besteht ja nicht nur aus diesen 4 klassen, sondern soll demnächst ein spiel mit mehreren leveln werden).
gruß

[thomas_E]

auch wenn dein einzeiler bei der berechnung mein "auge" um den Nullpunkt der Bühne dreht und nicht um seinen eigenen Mittelpunkt. aber da kann ich ja meine Berechnung wieder verwenden.

nun der Code dreht das Auge um seinen nullpunkt, nicht um seinen Mittelpunkt.
Öffne das Symbol mal in der Bibliothek, und schau mal wo da sein Nullpunkt angezeigt wird (müsste ein kleines graues Kreuz sein).

das mit den verschiedenen klassen und verkapselungen ist durchaus beabsichtigt. ich weiß dass es alles etwas umständlich ist und würde es am liebsten auch einfacher machen. aber es handelt sich um eine semesterarbeit und das ist alles so vorgegeben (besteht ja nicht nur aus diesen 4 klassen, sondern soll demnächst ein spiel mit mehreren leveln werden).

dann solltest du dir genau anschauen, was genau da vorgeben ist. gerade wenn es ein Spiel wird, wird die Sache an sich schon komplex genug werden, da muss man das ganze nicht noch unnötig aufblasen.
und vor allen Dingen wollte ich dir zeigen, dass nicht alle Objekte in die Anzeigeliste gehören/müssen. Controler bspw.

noch zwei Anmerkungen zur zukünftigen Performance deines Spiels:
- ENTER_FRAME kann ein absoluter performance-killer sein. benutze den Event-listener nicht öfters als nötig. am besten du machst einen main-loop, der dann alles andere aufruft

PHP-Code:

addEventListener(Event.ENTER_FRAME, mainloop);
...
function mainLoop(e:Event):void
{
    moveEyes()
    movePlayers();
    hitTests();
    ...
} 


ist viel schneller, als wenn jedes Objekt seinen eigenen Listener hätte.

- du solltest versuchen die Anzahl der Objekte in der Anzeigeliste zu reduzieren, und die Verschachtelungstiefe auch möglichst flach zu halten.
in deinem Code oben hattest du 4 Objekte ineinander verschachtelt, um dieses Auge zu bewegen. das bedeutet, dass 4 Objekte gerendert werden müssen für dieses eine Auge.