[Flash CS5] Flash Wahlschein

[Herzchen]

Hallo liebe Community
Ich habe mir früher eine Dropdownnavigation erstellt seit dem habe ich flash aber nicht mehr angefasst.

Problem:
Ich möchte meinen Usern eine Art Wahlschein erstellen.
Es gibt eine Zahlenreihe von 1 - 10 und die User sollen die Möglichkeit haben 3 dieser Zahlen mit einem Klick zu markieren. Wenn eine Zahl geklickt worden ist möchte ich, dass diese Zahl angekreuzt wird.

Einige Gedanken:

Bei dem Navigationsmenü konnte das alles mit onmouseover Event Händlern realisiert werden. Alternativ könnte man bei dieser Sache alles mit onclick events machen.
"Wenn Onclick go to frame x."
Das ganze könnte sicher auch mit Cookies realisiert werden welche die schon getroffene Entscheidung festhalten, aber es gibt sicher eine elegantere Loesung.

Frage:
Wie bekomme ich es hin, das vorherangekreuzte Zahlen angekreuzt bleiben? Ich kann nicht für jede erdenkliche Kombination ein Frame erstellen da es viel zu viele Möglichkeiten gibt.

Danke für eure Hilfe

[andrelehnert]

Hi,
hier mal ein kleiner Ansatzpunkt:

PHP-Code:

var numChoices:int=10;
var choices:Array = []; // hier kommen imer die aktuell gewählten Instanzen rein
//Setup
function build():void{
    
    for (var i:int=0;i<numChoices;i++){
        var box:Sprite = buildBox();
        box.y = 100;
        box.x = (30+5)*i;
        var tf:TextField = new TextField();
        tf.text = i.toString();
        tf.mouseEnabled = false;
        box.addChild(tf);
        addChild(box);
        box.addEventListener(MouseEvent.CLICK, makeChoice);
    }
}
function buildBox():Sprite{
    var spr:Sprite = new Sprite();
    var g:Graphics = spr.graphics;
    g.lineStyle(3,0);
    g.drawRoundRect(0,0,30,30,3,3);
    return spr;
}
function makeChoice(e:MouseEvent):void
{
    var box:Sprite = Sprite(e.target);
    var g:Graphics = box.graphics;
    if (choices.indexOf(box) == -1){ 
        choices.push(box);
        g.lineStyle(2,0xCC0000);
        g.moveTo(0,0);
        g.lineTo(30,30);
        g.moveTo(0,30);
        g.lineTo(30,0);    
    } else {
        choices.splice(choices.indexOf(box),1)
        g.clear();
        g.lineStyle(3,0);
        g.drawRoundRect(0,0,30,30,3,3);
    }
}

build(); 


einfach in den ersten Frame einer neuen FLA kopieren und testen.

Wenn Du die Wahl für einen Wiederbesuch der Seite speichern möchtest,
schau mal nach SharedObject

LG ANdré

[Herzchen]

Super ich werde es mir gleich morgen anschauen.

Die einzelnen User sind eingeloggt und die Ergebnisse werden in einer MySQL Daatenbank gespeichert. Wie das funktioniert werde ich mir morgen anlesen.