[Flash CS3] Externer Soundcontroll

[Melissa]

Hi alle miteinander,

ich würde gerne den Sound einer SWF-Datei über eine separate SWF-Datei ein und ausschalten... (Beide Dateien sind in einer HTML-Datei eingebettet).
Hab da aber leider überhaupt kein Plan von wie das gehen soll

Kann mir bitte jemand freundlicher Weise dabei helfen?

Thanx
Mell

[andrelehnert]

Schau mal nach LocalConnection

LG ANdré

[Melissa]

Vielen Dank...
Aber leider bin ich eine Niete darin und blicke das nicht durch..
Ich habe meinen Sound wie folgt eingebettet:

PHP-Code:

var soundReq:URLRequest = new URLRequest("trailer.mp3");
var sound:Sound = new Sound();
var soundControl:SoundChannel = new SoundChannel();
var resumeTime:Number = 0;

sound.load(soundReq);
sound.addEventListener(Event.COMPLETE, onComplete);

function onComplete(event:Event):void
{
    pause_btn.addEventListener(MouseEvent.CLICK, pauseSound);
    videoStream.play("intro_movie.flv");

}

function pauseSound(event:MouseEvent):void
{
    resumeTime = soundControl.position;
    soundControl.stop();
    play_btn.visible = true;
    play_btn.addEventListener(MouseEvent.CLICK, playSound);
    pause_btn.visible = false;
    pause_btn.removeEventListener(MouseEvent.CLICK, pauseSound);
}


function playSound(event:MouseEvent):void
{
    soundControl = sound.play();
    pause_btn.visible = true;
    pause_btn.addEventListener(MouseEvent.CLICK, pauseSound);
    play_btn.visible = false;
    play_btn.removeEventListener(MouseEvent.CLICK, playSound);
} 


Wie kann ich diesen Code mit einer zweiten SWF verbinden, so dass der Sound aus der 2. SWF ein und ausgeschaltet werden kann?
ICh denke da sollte ich die play_btn und pause_btn in die 2. SWF schreiben?!?!

[Melissa]

Kann ich das für meine Lösung anwenden?

Javascript calls Actionscript

[andrelehnert]

Ja klar, wenn Du die Control nicht unbedingt in einer swf haben musst...
LG ANdré

[Melissa]

Oh man o man... Alles zu kompliziert
Kennst jemand eine einfache Methode um den Sound einer SWF-Datei extern zu stoppen? Sei es jetzt eine zweite SWF oder JS oder sonst was?
Muss doch eine einfache Methode geben, oder?

[andrelehnert]

Obwohl Du relativ wenig eigene Initiative zeigst, hier mal ein Beispiel:

Control:

PHP-Code:

import flash.net.LocalConnection;

var lc:LocalConnection = new LocalConnection();

playbtn.addEventListener(MouseEvent.CLICK, playExternSound);
pausebtn.addEventListener(MouseEvent.CLICK, pauseExternSound);

function playExternSound(e:MouseEvent):void{
lc.send("lconnection","playSound");
}
function pauseExternSound(e:MouseEvent):void{
lc.send("lconnection","pauseSound");
} 


Player:

PHP-Code:

import flash.net.LocalConnection;

var lc:LocalConnection = new LocalConnection();
lc.client = this;
lc.connect("lconnection");

var soundReq:URLRequest = new URLRequest("deinSong.mp3");
var sound:Sound = new Sound();
var soundControl:SoundChannel = new SoundChannel();
var resumeTime:Number = 0;

sound.load(soundReq);

function pauseSound():void
{
    trace("Pause...");
    resumeTime = soundControl.position;
    soundControl.stop();    
}

function playSound():void
{
    trace("Playing...");
    soundControl = sound.play(resumeTime);        
} 


LG ANdré

[Melissa]

Hi ANdré...

Da lachte mein Herz als ich deine Antwort sah
Ich werde das sofort ausprobieren...

Vielen lieben Dank

[Melissa]

Juhuuuu... Das funktioniert 1A )))

Danke danke dankeeeeeee....