[Flash CS4] Externe swf laden und ansprechen

[fr8za]

Hi!

Beim Programmieren in Flash bin ich noch nicht sehr weit, habe mich aber bereits um die Lösung meines Problems bemüht, jedoch leider ohne Erfolg. Es wäre toll, wenn ihr mir dabei helfen könntet.
Ich habe ein Problem mit dem Asprechen meiner MC Instanz nach dem Laden in meinen main_mc. Die Hierarchie sieht so aus:

Bühne
--> main_mc
--> in diesen main_mc soll die externe Datei "milKa_anim.swf" geladen werden, welche wiederum aus dem dort auf der Bühne liegenden "milka_mc" besteht. Diesen Instanznamen habe ich in der externen Datei bereits angelegt.

Nun möchte ich in meiner .fla Datei die externe milKa_anim.swf laden und dem "milka_mc" sagen, dass er bei versch Schlüsselbildern anhalten soll. Die Stops sind im externen MC bereits eingebaut, möchte das also mit gotoAndPlay() steuern.

Der Code bisher ist

var request:URLRequest = new URLRequest("milKa_anim.swf"); 
var milka_loader:Loader = new Loader() 
milka_loader.load(request); 
addChild(milka_loader);

var milkaExt=MovieClip(milka_loader.content);
milkaExt.MovieClip.getChildByName("milka_mc").gotoAndPlay(2);

Die Fehlermeldung dazu meint
1120: Zugriff auf eine nicht definierte Eigenschaft milka_mc.

Wie schaffe ich es, dass dem externen MC der Intanznamen "milka_mc" zugewiesen wird sodass ich diesen mit gotoAndPlay steuern kann?

Über eine schnelle Antwort wüde ich mich sehr freuen!
Danke für euer Verständnis.

Gruß
Fabian

[Martin Kraft]

Wurde das, was Du da nachlädst, auch in AS3 programmiert? Auf AS1/2-SWFs könntest Du nicht so ohne weiteres zugreifen!

Zitat von fr8za

var milkaExt=MovieClip(milka_loader.content);
milkaExt.MovieClip.getChildByName("milka_mc").gotoAndPlay(2);

Was soll denn das .Movieclip. in dieser Zeile?!
Das sollte eher so aussehen:

var milkaExt:MovieClip = milka_loader.content as MovieClip;
if(milkaExt) {
    var milkaMc:MovieClip = milkaExt.getChildByName("milka_mc") as MovieClip;
    if (milkaMc) {
        milkaMc.gotoAndPlay(2);
    } else {
        trace("milka_mc ist kein MovieClip.");
    }
} else {
    trace("swf ist kein MovieClip.");
} 

Oder direkt so:

var milkaExt:MovieClip = milka_loader.content as MovieClip;
if(milkaExt) {
    if ("milka_mc" in milkaExt && milkaExt.milka_mc is MovieClip) {
        milkaExt.milka_mc.gotoAndPlay(2);
    } else {
        trace("milka_mc ist kein MovieClip.");
    }
} else {
    trace("swf ist kein MovieClip.");
} 

[fr8za]

Hi!

Danke für deine schnelle Antwort,
das script funktioniert auch, der trace sagt "swf ist kein MovieClip."
Jedoch möchte ich den extern geladenen "milka_mc" mit einem eingebetteten script steuern, das auf der Bühne von meiner .fla im ersten Frame liegt:

stage.addEventListener(KeyboardEvent.KEY_DOWN, keyHandler);
var n:uint=0;
var frameKey:uint;
var frameArray:Array=[1,2]
function keyHandler(event:KeyboardEvent):void {
	if (event.keyCode==39) {
		if (n<frameArray.length) {
			n++;
			frameKey=frameArray[n];
			trace(main_mc.currentFrame);
			stage.addEventListener(Event.ENTER_FRAME, frameNextCheck);
		}
	}
	if (event.keyCode==37) {
		if (n>0) {
			n--;
			frameKey=frameArray[n];
			trace(main_mc.currentFrame);
		}
		stage.addEventListener(Event.ENTER_FRAME, framePrevCheck);
	}
}
function frameNextCheck(e:Event):void {
	main_mc.nextFrame();
	if (main_mc.currentFrame>=frameKey) {
		main_mc.stop();
		stage.removeEventListener(Event.ENTER_FRAME, frameNextCheck);
	}
}
function framePrevCheck(e:Event):void {
	main_mc.prevFrame();
	if (main_mc.currentFrame<=frameKey) {
		main_mc.stop();
		stage.removeEventListener(Event.ENTER_FRAME, framePrevCheck);
	}
}

Im "main_mc" möchte ich mich also mit den Pfeiltasten durch meine extern geladenen "milka_mc" navigieren, bzw. einfach gotoAndPlay() am entsprechenden Frame ausführen. Ich habe jetzt versucht im zweiten Frame meines "main_mc" mit

milkaExt.milka_mc.gotoAndPlay(2)

die Animation zu starten, jedoch kommt da die Fehlermeldung

TypeError: Error #1009: Der Zugriff auf eine Eigenschaft oder eine Methode eines null-Objektverweises ist nicht möglich.
at test_fla::milka_anim_1/frame2()
at flash.display::MovieClip/nextFrame()
at test_fla::MainTimeline/frameNextCheck()

wie könnte man das beheben?
Vielen Dank!

Gruß
Fabian

[Martin Kraft]

• Mir fällt gerade auf, dass Du direkt nach Ladebeginn auf die Inhate zugreifst. Das funktioniert natürlich nicht, weil dann noch nicht geladen ist. Du solltest statt dessen einen Listener auf Event.COMPLETE oder Event.INIT registrieren.
  Code Beispiele dazu findest Du zu Hauf in der Referenz und über die Suchfunktion des Forums!
  
  

• Zitat von fr8za

  Jedoch möchte ich den extern geladenen "milka_mc" mit einem eingebetteten script steuern, das auf der Bühne von meiner .fla im ersten Frame liegt:

  Auf dem ersten Frame welcher FLA – der von milka_mc oder der, die diese nachlädt?
  
  
• Du greifst in Deinem Code mehrfach auf stage zu. Das führt zu der beschriebenen Fehlermeldung, da stage erst definiert ist, wenn das entsprechende objekt in der Anzeigeliste liegt (kann man über Event.ADDED_TO_STAGE abfangen) und ist meistens völlig unnötig (den Event.ENTER_FRAME-Listener könntest Du z.B. auch auf jedes andere Objekt legen)!
  
  
• Was genau soll dieser Code eigentlich bewirken? Das sieht mir irgendwie unnötig kompliziert aus?!

[fr8za]

Zitat von fr8za Beitrag anzeigen
Jedoch möchte ich den extern geladenen "milka_mc" mit einem eingebetteten script steuern, das auf der Bühne von meiner .fla im ersten Frame liegt:
Auf dem ersten Frame welcher FLA – der von milka_mc oder der, die diese nachlädt?

Der Code liegt in der .fla, in die die externe Datei geladen werden soll.
Damit kann ich mich mit PfeilLinks/PfeilRechts zwischen den im Script angegebenen Bildern (1,2,3,4) des "main_mc" hin und her bewegen.

Vll kanst du dir die test.fla und milka_anim.swf mal anschauen?
Das Ganze dient dazu gerenderte Bildsequenzen in eine Präsentations .fla zu laden und immer stückweise abzuspielen.

Es wäre wirklich sehr nett wenn du mir helfen könntest, über den Weg, die Bildsequenzen in meine .fla datei einzubinden, klappt es irgendwann nicht mehr, weil Flash sich aufgrund der Größe und Anzahl der Bilder aufhängt. Deswegen wollte ich versuchen alles extern zu beziehen und dennoch mit den Pfeiltasten steuern zu können.
Vielen Dank!

Fabian

[Martin Kraft]

Vorab:
Lies Dir bitte erstmal in der Referenz oder hier im Forum durch, wie man ein ASW nachlädt, ab wann man auf deren Inhalte zugreifen kann (Event.COMPLETE oder Event.INIT). Wie man sie dann auf MovieClip castet hab ich Dir ja oben gezeigt!

Zitat von fr8za

Damit kann ich mich mit PfeilLinks/PfeilRechts zwischen den im Script angegebenen Bildern (1,2,3,4) des "main_mc" hin und her bewegen.

Den Code in einem MovieClip auf Frames zu verteilen und dann darüber aufzurufen, ist Blödsinn. Wozu gibt es schließlich Funktionen und Arrays?!

Zitat von fr8za

Das Ganze dient dazu gerenderte Bildsequenzen in eine Präsentations .fla zu laden und immer stückweise abzuspielen.

Du willst also bei Tastendruck in der Nachgeladenen SWF einen bestimmten Frame anspringen und ab dort abspielen?! Soll das so eine Art Slideshow werden?

[fr8za]

Du willst also bei Tastendruck in der Nachgeladenen SWF einen bestimmten Frame anspringen und ab dort abspielen?! Soll das so eine Art Slideshow werden?

Ja so ist es gedacht. Das Array lege ich ja mit den Frames 1,2,3,4 im ersten Frame der .fla fest.

Event.COMPLETE habe ich mir angeschaut und eingebaut:

var request:URLRequest = new URLRequest("milKa_anim.swf"); 
var milka_loader:Loader = new Loader()
var milkaExt:MovieClip = milka_loader.content as MovieClip;
milka_loader.contentLoaderInfo.addEventListener(Event.COMPLETE, geladen);
milka_loader.load(request); 
addChild(milka_loader);

function geladen(evt:Event):void {
	trace("Externer Film wurde geladen!");
	trace(evt.target.content);
	milkaExt.milka_mc.gotoAndPlay(2);
}

Der Film wird volständig geladen, dennoch taucht der Fehler wieder auf:

TypeError: Error #1009: Der Zugriff auf eine Eigenschaft oder eine Methode eines null-Objektverweises ist nicht möglich.
at test_fla::milka_anim_1/geladen()



weiß nicht, was ich noch machen soll. Eigtl muss ich der geladenen .swf nur beibingen, dass ich den milka_mc ansprechen möchte...

[Martin Kraft]

Versuch's mal so rum:

import flash.display.Loader;
import flash.display.MovieClip;
import flash.events.Event;
import flash.net.URLRequest;
 
var milkaExt:MovieClip;
var milka_loader:Loader = new Loader()
milka_loader.contentLoaderInfo.addEventListener(Event.COMPLETE, geladen);
milka_loader.load(new URLRequest("milKa_anim.swf")); 
addChild(milka_loader);
 
function geladen(evt:Event):void {
    milkaExt = milka_loader.content as MovieClip;
    if(milkaExt) {
        if ("milka_mc" in milkaExt) {
            if(milkaExt.milka_mc is MovieClip) {
                milkaExt.milka_mc.gotoAndPlay(2);
            } else {
                trace("milka_mc ist kein MovieClip sondern ein "+milkaExt.milka_mc);
            }
        } else {
            trace("milka_mc konnte nicht gefunden werden");
        }
    } else {
        trace("swf ist kein MovieClip sondern ein "+milka_loader.content);
    }
} 

[fr8za]

Hi Martin,

vielen Dank für dein Bemühen!!
Das Script klappt, jedoch ist der trace "milka_mc konnte nicht gefunden werden". Das

gotoAndPlay()

möchte ich gerne über die versch KeyFrames ausführen, um in meiner Präsentation die Übersicht zu behalten.
Also würde es im "main_mc" erst im zweiten KeyFrame auftauchen, einfach

milkaExt.milka_mc.gotoAndPlay(2);

Leider klappt das auch nicht.
Woran kann es deiner Meinung nach liegen dass der externe MC nicht erkannt wird?

btw
Vielen vielen Dank für dein Verständnis, ich habe leider wenig Ahnung und wäre froh wenn wir das Problem lösen könnten!

Gruß
Fabian

[Martin Kraft]

Zitat von fr8za

Das Script klappt, jedoch ist der trace "milka_mc konnte nicht gefunden werden".

Dann klappts also nicht und Du solltest rausfinden warum!
Ist es tatsächlich die Hauptzeitleiste in der dieser MC liegt?
Ist der richtige Instanzname vergeben?
Liegt die Instanz tatsächlich auf Frame 1?

Zitat von fr8za

Das

gotoAndPlay()

möchte ich gerne über die versch KeyFrames ausführen, um in meiner Präsentation die Übersicht zu behalten.

Mit Übersicht hat so eine doppelte Verschachtelung (noch dazu in der Zeitleiste) IMHO nichts zutun. Von Preloadern abgesehen ist die Zeitleiste ist zum Animieren da und zu sonst nichts!

Wenn Du es gerne übersichtlich hast, arbeite mit einem Array!

Bis auf ganz wenige Ausnahmen sollte man AS auch nicht munter in der Zeitleiste verteilen, sondern im ersten Frame (oder besser noch einer Klasse) zusammenhalten.

Beschreib bitte man genau, was Du erreichen möchtest (und nicht wie Du es z.Z. umsetzen willst), dann mach ich Dir einen Vorschlag!

[fr8za]

Ist es tatsächlich die Hauptzeitleiste in der dieser MC liegt?
Ist der richtige Instanzname vergeben?
Liegt die Instanz tatsächlich auf Frame 1?

Habe alles überprüft und der "milka_mc" liegt in der "milka_anim.swf" in der Hauptzeitleiste auf Frame 1 und hat den Instanznamen "milka_mc".
Ich habe die Datei mit angehängt.

Ich möchte erreichen, dass in einer .fla Datei, welche sämtliche Inhalte meiner Präsentation enthält (Einzelbildsequenzen als auch animierte Vektorgrafiken), durch Drücken der Pfeiltasten Rechts/Links für Vor/Zurück meine Animation zum nächsten bzw. vorangegangenen Stoppunkt läuft. Mit dem geposteten Script klappt das auch alles wunderbar.
Nun sind die Einzelbildanimationen (JPEGS) zu groß und zu viele um sie weiter einfach in meine .fla Datei zu laden. Flash stürzt beim Import-/Kopierversuch ab. Deshalb möchte ich die JPEG Sequenzen, anstatt sie direkt in meiner .fla Bibliothek zu platzieren, extern hinzuladen. Die JPEG Sequenzen liegen als .swf Dateien vor, jeweils ein MC auf Frame 1 in der Hauptzeitleiste (wie in der angehängten milka_anim.fla). Die Sequenz ist in ihrem mc mit stop(); `s versehen, sodass der MC bei einem gotoAndPlay(); nur bis zum nächsten stop(); abgespielt wird.
Nun sollen an der richtigen Stelle in meiner main.fla im "main_mc" diese Sequenzen dazugeladen werden, sodass ich diese mit den Pfeiltasten steuern kann, immer von stop() zu stop().
Das Ursprungsproblem ist also, das Flash ab einer gewissen Menge an Bildern abstürzt. Alle bisherigen Versuche einer Konvertierung waren nicht erfolgreich.

Ich danke dir!

[Martin Kraft]

Zitat von fr8za

Die JPEG Sequenzen liegen als .swf Dateien vor, jeweils ein MC auf Frame 1 in der Hauptzeitleiste

Wieso legst Du sie niht direkt auf die Hauptzeitleiste dieser SWFs?! Dann hast Du das Unterzugriffsproblem nicht mehr!

Zitat von fr8za

Das Ursprungsproblem ist also, das Flash ab einer gewissen Menge an Bildern abstürzt. Alle bisherigen Versuche einer Konvertierung waren nicht erfolgreich.

Versuch's doch mal mit Videos Der Adobe MediaEncoder kann auch BildSequenzen konvertieren!

[fr8za]

Wieso legst Du sie niht direkt auf die Hauptzeitleiste dieser SWFs?! Dann hast Du das Unterzugriffsproblem nicht mehr!

Weil ich ursprünglich die ganzen mc`s direkt in meine Main.fla importieren wollte und sie dort auch in einem zusammenfassenden MC angeordnet sein sollten.

Inzwische klappt es aber alles so wie es soll, mit diesem (deinem) code:

stop();

    import flash.display.Loader;
    import flash.display.MovieClip;
    import flash.events.Event;
    import flash.net.URLRequest;
     
    var milkaExt:MovieClip;
    var milka_loader:Loader = new Loader()
    milka_loader.contentLoaderInfo.addEventListener(Event.COMPLETE, geladen);
    milka_loader.load(new URLRequest("milKa_anim.swf"));
    addChild(milka_loader);
     
    function geladen(evt:Event):void {
        milkaExt = milka_loader.content as MovieClip;
        if(milkaExt) {
            if ("milka_mc" in milkaExt) {
                if(milkaExt.milka_mc is MovieClip) {
                    milkaExt.milka_mc.visible=true;
					milkaExt.milka_mc.x=-600;
					milkaExt.milka_mc.y=-367.5;
					milkaExt.milka_mc.alpha=0;
		
                } else {
                    trace("milka_mc ist kein MovieClip sondern ein "+milkaExt.milka_mc);
                }
            } else {
                trace("milka_mc konnte nicht gefunden werden");
            }
        } else {
            trace("swf ist kein MovieClip sondern ein "+milka_loader.content);
        }
    }

Wenn ich die externe .swf wieder entladen möchte, reicht da ein

milka_loader.contentLoaderInfo.addEventListener(Event.COMPLETE, geladen);
addChild(milka_loader);

?

Vielen vielen Dank nochmal!!

[Martin Kraft]

Zitat von fr8za

Wenn ich die externe .swf wieder entladen möchte, reicht da ein

milka_loader.contentLoaderInfo.addEventListener(Event.COMPLETE, geladen);
addChild(milka_loader);

?

Nö, dieser Code hat mit Entladen nichts zu tun! Das sähe eher so aus:

if(milka_loader.parent) milka_loader.parent.removeChild(milka_loader);
milkaExt = null;
milka_loader.unloadAndStop();
milka_loader = null; 

[fr8za]

Beim einfügen des Scripts zum Entladen kommt folgende Medung:


Error: Error #2069: Die Loader-Klasse implementiert diese Methode nicht.
at Error$/throwError()
at flash.display::Loader/removeChild()
at Pr_fla::main_mc_1/frame367()
at flash.display::MovieClip/nextFrame()
at Pr_fla::MainTimeline/frameNextCheck()