[Flash CS5] Eventbubbling bei Buttonliste

[Xebian]

Hallo liebes Forum,

ich habe eine Liste aus Buttons (EqButton-Instanzen), die beim Auftreten eines Click-Events dieses bis zur Main hinaufbubblen lassen.

Daraufhin soll die Main, abhängig davon, welcher Button das Event geschickt hat, eine Instanz einer Klasse Bike erzeugen, mit unterschiedlichen Eigenschaften. Dabei wäre es schön, wenn Main die EqButton-Instanzen dazu nicht kennen muss.




Zur Veranschaulichung habe ich eine Grafik erstellt:




Codemäßig sieht es momentan so aus:

package as3.EquipList {
	
	import flash.display.MovieClip;
	import flash.events.MouseEvent;
	import flash.events.Event;
	import flash.display.Bitmap;
	
	
	public class EqButton extends MovieClip {
		
		// Wird beim Click-Event zur Main geschickt
		public static var eventString:String;
		
		private var color:String;
		private var gears:int;
		private var tireSize:Number;
		private var brand:String;
		private var image:Bitmap;
		
		public function EqButton(image:Bitmap, brand:String, color:String, gears:int, tireSize:Number) {
			this.image = image;
			this.brand = brand;
			this.color= color;
			this.gears= gears;
			this.tireSize = tireSize;

			// Eigenschaften in String verpacken, um es in Main wieder aufzuteilen
			eventString = brand+","+color+","+gears+","+tireSize;

			addEventListener(MouseEvent.CLICK, launchEvent);
		}

		private function launchEvent(e:MouseEvent):void{
			var newEvent:Event = new Event(eventString, true, true);
			dispatchEvent(newEvent);
		}
}
}

Hier wird das Event in Main aufgefangen:

addEventListener(EqButton.eventString, onEvent);
function onEvent(e:Event):void{
        // Hier Instanzen von Bike erzeugen
	trace("EVENT: "+e);
}

Da bekomme ich jedoch folgenden Fehler:

ArgumentError: Error #1063: Argument count mismatch on as3.EquipList::EqButton(). Expected 5, got 0.
at flash.display::Sprite/constructChildren()
at flash.display::Sprite()
at flash.display::MovieClip()
at as3.EquipList::List()
at flash.display::Sprite/constructChildren()
at flash.display::Sprite()
at flash.display::MovieClip()
at as3.EquipList::EquipList()
at flash.display::Sprite/constructChildren()
at flash.display::Sprite()
at flash.display::MovieClip()
at simulator_fla::MainTimeline()

Also scheinbar kann er die statische Variable eventString nicht ansprechen, da er die Instanz nicht kennt...
Könnt ihr mir bitte sagen, wie man es hinbekommt, dass die individuellen Daten aus eventString ohne Instanz übermittelt werden können?
Oder muss ich von der Main aus doch die Instanzen ansprechen und einzelnd auf Click-Events abfragen?

Danke schonmal für eure Hilfe. Wenn euch noch Angaben fehlen, so sagt bescheid und ich reiche sie natürlich nach.

Grüße,
Sven

[cytrics]

Hy,

bin mir alles andere als sicher, aber müßtest du nicht so schreiben:

addEventListener(EqButton.eventString, onEvent);

function onEvent(e:EqButton):void
{
        // Hier Instanzen von Bike erzeugen
	trace("EVENT: "+e);
}

[Xebian]

Hi,

schreibe ich es so, kommt leider auch der gleiche Fehler

[thomas_E]

Ein Button ist nunmal kein Event-Objekt.

die Struktur ist schlecht, das mit dem String zusammensetzen und wieder zerlegen.

bau dir ne eigene DatenKlasse für die FarradKonfiguration
bau dir eine eigene Event-Klasse, die erwartet, dass man Ihr Daten mitgibt. und lass alle Elemente so dumm wie möglich.
der Button muss die genaue Konfiguration nicht kennen, keine Farbe, Rad-Grösse, oder sonstwas.

wenn du jetzt noch was an der Konfiguration erweiterst, musst du das nur in der DatenKlasse tun, und an den Stellen, die auch wirklich auf die neuen Daten zugreifen müssen, alle anderen Objekte die mit den FahrradDaten in Berührung kommen merken von der Änderung nichts.

DatenKlasse

PHP-Code:

package data
{
//dürfte ich vorschlagen, hier ein BitmapData anzugeben statt eines Bitmaps.
//ein Bitmap kann immer nur an einer Stelle sein, aber du kannst endlos viele 
//Bitmaps mit dem selben BitmapData-Objekt erstellen und anzeigen
//    import flash.display.Bitmap;
    import flash.display.BitmapData;
    
    public class BikeConfiguration
    {
        public var color:String;
        public var gears:int;
        public var tireSize:Number;
        public var brand:String;
        public var image:BitmapData;    //brauchst du das Bild hier wirklich?
        
        public function BikeConfiguration(image:BitmapData, brand:String, color:String, gears:int, tireSize:Number) {
            this.image = image;
            this.brand = brand;
            this.color = color;
            this.gears = gears;
            this.tireSize = tireSize;
        }
        
        public function clone():BikeConfiguration
        {
            return new BikeConfiguration(image, brand, color, gears, tireSize);
        }
        
        public function toString():String
        {
            return brand+","+color+","+gears+","+tireSize;
        }
    }
} 


Event

PHP-Code:

package events
{
    import data.BikeConfiguration;
    import flash.events.Event;
    
    public class BikeEvent extends Event
    {
        //Event-Typen
        public static const CREATE:String = "createBike";
        public static const SHOW:String = "showBike";
        public static const DESTROY:String = "destroyBike";
        public static const CONQUER:String = "conquerTheWorldOnABike";
        
    
        public var data:BikeConfiguration;
        
        public function BikeEvent(type:String, data:BikeConfiguration, bubbles:Boolean=true, cancelable:Boolean=false)
        {
            this.data = data;
            super(type, bubbles, cancelable);
        }
        
        override public function clone():Event
        {
            return new BikeEvent(type, data.clone(), bubbles, cancelable);
        }
    }
} 


//und der eigentliche Button

PHP-Code:

package as3.EquipList
{
    import flash.display.Sprite;
    import flash.events.MouseEvent;
    import flash.display.Bitmap;
    
    import data.BikeConfiguration;
    import events.BikeEvent;
    
    public class EqButton extends Sprite
    {
        private var bikeData:BikeConfiguration;
        
        public function EqButton(bikeData:BikeConfiguration) {
            this.bikeData = bikeData;
            addEventListener(MouseEvent.CLICK, launchEvent);
        }

        private function launchEvent(e:MouseEvent):void
        {
            dispatchEvent(new BikeEvent(BikeEvent.CREATE, bikeData, true));
        }
    }
} 


Edith: hatte den problematischen Teil vergessen einzubinden

PHP-Code:

import data.BikeConfiguration;
import events.BikeEvent
//...

addEventListener(BikeEvent.CREATE, onCreateBike);
function onCreateBike(e:BikeEvent):void
{
    // Hier Instanzen von Bike erzeugen
    trace("EVENT:", e.type, e.data.toString());
} 


edit2:
die privaten Eigenschaften in BikeConfiguration public gemacht.
brauchst du das Bild in der DatenKlasse, oder war das nur für den Button? dann solltest du es wieder da rein tun.
und du kannst die Daten ggf weiter verschachteln, bspw eine weitere Klasse für die Räder, und deren Spezifikation, oder für die Schaltung, sofern benötigt.
du musst jetzt nicht alle Informationen in eine Klasse quetschen

[Xebian]

Hey Thomas, danke für deinen ausführlichen Beitrag.

Ich werde ihn genauer durchgehen und versuchen, umzusetzen. Melde mich dann später wieder.


Zum Bild: Das ist nur für den Button gedacht.

[thomas_E]

Zum Bild: Das ist nur für den Button gedacht.

ok,
ich würde aber trotzdem nur ein BitmapData übergeben, und den Button entscheiden lassen, wie er den verwendet,
oder du nutzt eine factory-Klasse, die die Buttons erstellt und zusammenbaut, und dann geht es auch den Button nichts mehr an, was oder ob er er ein Bild erhält/enthält.

edit eine änderung noch:

PHP-Code:

dispatchEvent(new BikeEvent(BikeEvent.CREATE, bikeData.clone(), true)); 


hier nbicht das Original-Objekt, sondern eine Kopie von bikeData übergeben, weil sonst änderungen die du an dem Objekt machst, dass du aus dem Event-erhältst, auch im Button selber geändert würden.

[Xebian]

So, ich hab's jetzt so umgesetzt bekommen und den Code soweit verstanden.

Danke nochmal für die Hilfe!