[Flash CS5] Erster versuch in AS3 / mit Combobox und Loader

[docma]

Hey

Wie oben beschrieben wagte ich mich Heute mal ans AS3.
Und habe schnell festgestellgt das loadMovie und unloadMovie nicht mehr Funtkioniert... hab das mal ein par Funktionen aus dem Forum zusammengeschnappt aber irgendwas Funktioniert noch nicht.

Oben sollte die Combobox diverse SWF laden und andre entladen. Hier der Coden und unten noch die Datei.

import flash.net.URLRequest;
import flash.display.Loader;
import flash.display.MovieClip;
import flash.events.MouseEvent;
import flash.net.URLLoader;

stop();
var Xpos:Number = 0;
var Ypos:Number = 180;
var swf:MovieClip;
var loader:Loader = new Loader();
loader.load(defaultSWF);
loader.x = Xpos;
loader.y = Ypos;

///////////////////////////////////////////////////////////////////////////////////////////
///////////////// Navigation ///////////////////////////////////////////////////
combobox.addItem( { label: "News" } );
combobox.addItem( { label: "Update" } );
combobox.addItem( { label: "Bilder" } );

combobox.addEventListener(Event.CHANGE, changeimage);

///////////////// Navigation Anweisungen ///////////////////////////////////////////////////

function changeimage (event:Event) : void{

		
	if(combobox.selectedItem.label == "News") 
		
	var defaultSWF:URLRequest = new URLRequest("load_swf/news_1024x600.swf");
	addChild(loader);
	
	
	if(combobox.selectedItem.label == "Update")
	
	var defaultSWF:URLRequest = new URLRequest("load_swf/test_1024x600.swf");
	
	if(combobox.selectedItem.label == "Bilder") gotoAndStop(4);
}

// Btns Universal function
function btnClick(event:MouseEvent):void {
	
	removeChild(loader);
	var newSWFRequest:URLRequest = new URLRequest("load_swf/" + event.target.name + ".swf");
	loader.load(newSWFRequest);
	loader.x = Xpos;
    loader.y = Ypos;
	addChild(loader);
}
// Btn listeners
News.addEventListener(MouseEvent.CLICK, btnClick);
Update.addEventListener(MouseEvent.CLICK, btnClick);
Bilder.addEventListener(MouseEvent.CLICK, btnClick);

[milchreis]

loader.load(defaultSWF);

an der stelle ist ja defaultSWF noch gar nicht definiert.

Und wenn du deinen Request änderst:
var defaultSWF:URLRequest = new URLRequest("load_swf/news_1024x600.swf");
oder hier:
var defaultSWF:URLRequest = new URLRequest("load_swf/test_1024x600.swf");

dann musst du die load() methode noch mal aufrufen.

es reicht aus, den loader ein mal (nachdem er erzeugt wurde (also new Loader()) der Anzeigeliste hinzuzufügen.

[speedjunkie]

stop();
var loader:Loader, container:Sprite;
 
function init():void
{
    addChildAt(container = new Sprite(), 0);
    loader = new Loader();
    loader.contentLoaderInfo.addEventListener(Event.INIT, initHandler);
    loader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, ioHandler);
    loader.contentLoaderInfo.addEventListener(ProgressEvent.PROGRESS, progressHandler);
    /*combobox Properties*/
    combobox.addItem( { label: "News" } );
    combobox.addItem( { label: "Update" } );
    combobox.addItem( { label: "Bilder" } );    
    /*combobox Listener*/
    combobox.addEventListener(Event.CHANGE, changeHandler); 
    return;
}
 
function changeHandler(e:Event):void
{
    /* nav */
    trace(e.currentTarget.selectedItem.label);
    
    switch(e.currentTarget.selectedItem.label)
    {
        case "News":
        
            loadSWF("load_swf/news_1024x600.swf");
        
        break;
        case "Update":
        
            loadSWF("load_swf/test_1024x600.swf");
        
        break;
        case "Bilder":
        
            loadSWF("load_swf/as3.swf");
        
        break;
    }
}
 
function loadSWF(path:String):void
{
    try
    {
        loader.load(new URLRequest(path));
    }
    catch(err:Error)
    {
        trace("err_msg: " + err.message);
    }
    return; 
}
 
function initHandler(e:Event):void
{
    eraseLastContent(container);
    
    if(e.target.actionScriptVersion == 3)
    {
        var movieAVM2:MovieClip = container.addChild(e.target.content) as MovieClip;
        movieAVM2.gotoAndStop(1);
    }
    else
    {
        container.addChild(loader);
    }
    trace("container Childs: " + container.numChildren);
    return;
    
}
 
function eraseLastContent(container:Sprite):void
{
    if (container.numChildren)
    {
        var lastContent:DisplayObject = container.removeChildAt(0);
        lastContent = null;
    }
    return;
}
 
function progressHandler(e:ProgressEvent):void
{
    trace("progressHandler: " + e.currentTarget.bytesLoaded / e.currentTarget.bytesTotal * 100);
    return;
}
 
function ioHandler(e:IOErrorEvent):void
{
    trace(e.text);
    return;
}
 
init(); 

[docma]

wow... echt Super Danke.
Muss gestehen das noch einiges Bahnhof ist... da muss ich noch hinter die Bücher. Gibt es irgendwo eine Seite mit neuen AS3 Befehlen und Info dazu?

Noch eine Grundlegende fragen...
Ich habe noch SWF Daten die in AS2 geschrieben sind und wollte diese hier mit einbinden. Das Funktioniert wunderbar beim ersten mal wo das SFW geladen wird, sprich die AS2 Button usw. funktionieren...
wechsle ich jetzt Combobox und kehre zurück ins selbe SWF funktionieren die Buttons nichtmehr...

Ist das allgemein ein Problem bei AS3 >load>AS2.swf oder hatt das mit dem Code zu tun?

[Martin Kraft]

Zitat von docma

Gibt es irgendwo eine Seite mit neuen AS3 Befehlen und Info dazu?

Die mit Abstand wichtigste Ressource ist die ActionScript3-Referenz, in der alle Klassen und Funktionen der FlashPlayer-API dokumentiert sind. Weiter Informationslinks findest Du in meiner Signatur oder unserer Linksammlung.

[docma]

super Danke

Zitat von docma

Noch eine Grundlegende fragen...
Ich habe noch SWF Daten die in AS2 geschrieben sind und wollte diese hier mit einbinden. Das Funktioniert wunderbar beim ersten mal wo das SFW geladen wird, sprich die AS2 Button usw. funktionieren...
wechsle ich jetzt Combobox und kehre zurück ins selbe SWF funktionieren die Buttons nichtmehr...

Ist das allgemein ein Problem bei AS3 >load>AS2.swf oder hatt das mit dem Code zu tun?

Als nach einer recherche müsste es kein Problem sein AS2codes.swf in einem AS3 abzuspielen... es sei man möchte da diese miteinander Kommunizieren aber dies ist bei mir eigentlich nicht der fall.

Habt ihr Erfahrungen damit?

Gruss

[Martin Kraft]

Wie sieht den der Code der AS2.swf aus?

[docma]

Hauptsächlich sind es Tweens die auf Buttons liegen.

z.B.

PHP-Code:

on (release) {
    /*Bilder*/
    X = new mx.transitions.Tween(S0101, "_x", mx.transitions.easing.Regular.easeOut, S0101._x, 407.9, 1, true);
    X = new mx.transitions.Tween(SS0101, "_x", mx.transitions.easing.Regular.easeOut, SS0101._x, 407.9, 1, true); 


Ich befürchte das es etwas mit dem Container zu tun hat. In dem die SWF geladen wird. Da die erste SWF korrekt abgespielt wird bis ich den in der Navigation ein neuer Menüpunkt lade -> ab dann werden sie nur noch angezeigt aber die Buttons Funktionieren nichtmehr.

[Martin Kraft]

Versuch's mal hiermit:

import flash.display.Loader;
import flash.display.Sprite;
import flash.events.Event;
import flash.events.IOErrorEvent;
import flash.events.ProgressEvent;
import flash.net.URLRequest;
 
stop();
 
var loader:Loader;
 
var pathsByLabel:Object = {
    "News": "load_swf/news_1024x600.swf",
    "Update":"load_swf/test_1024x600.swf",
    "Bilder":"load_swf/as3.swf"
}
 
function init():void {
    addChildAt(container = new Sprite(), 0);
    for (var label:String in pathsByLabel) combobox.addItem( { label: label } );
    combobox.addEventListener(Event.CHANGE, changeHandler);
}
 
function changeHandler(e:Event):void {
    var label:String = e.currentTarget.selectedItem.label;
    if (label in pathsByLabel) loadSWF(pathsByLabel[label]);
}
 
function loadSWF(path:String):void {
    
    if (loader) {
        loader.unloadAndStop();
        loader.contentLoaderInfo.removeEventListener(Event.INIT, initHandler);
        loader.contentLoaderInfo.removeEventListener(IOErrorEvent.IO_ERROR, ioHandler);
        loader.contentLoaderInfo.removeEventListener(ProgressEvent.PROGRESS, progressHandler);
        if (loader.parent) loader.parent.removeChild(loader);
    }
    
    loader = new Loader();
    loader.contentLoaderInfo.addEventListener(Event.INIT, initHandler);
    loader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, ioHandler);
    loader.contentLoaderInfo.addEventListener(ProgressEvent.PROGRESS, progressHandler);
    
    try {
        loader.load(new URLRequest(path));
    } catch (err:Error) {
        trace("err_msg: " + err.message);
    }
}
 
function initHandler(e:Event):void {
    // Was auch immer Du bei Init tun willst
}
 
function progressHandler(e:ProgressEvent):void {
    trace("progressHandler: " + e.currentTarget.bytesLoaded / e.currentTarget.bytesTotal * 100);
}
 
function ioHandler(e:IOErrorEvent):void {
    trace(e.text);
}
 
init(); 

[speedjunkie]

Ich dachte es liegt an Tweenengine und hab mit Tweenlite probiert da gibt’s zumindest eine Meldung.

"256 levels of recursion were exceeded in one action list.
This is probably an infinite loop.
Further execution of actions has been disabled in this movie."

Der Hauseigene Tween wird auch gekillt. Mag Flash das nicht, wenn AVM1Movie’s irgendetwas anstellen?!

Hätte auch gerne mal den ProLoader ausprobiert. Hab aber kein CS5.5

[docma]

Hey. Habe am WE auch noch einiges ausprobiert...
Bei einer normalen Einbindung klapt es problemlos, sobald ich aber if anweisungen dazugebe funktioniert es plötzlich nicht mehr...

Ich werden die alten SWF Daten in AS3 umschreiben, dann lerne ich wenigstens was...

THX für eure Hilfe.

[speedjunkie]

Zitat von docma

Ich werden die alten SWF Daten in AS3 umschreiben, dann lerne ich wenigstens was...

Das ist denke ich der beste Ansatz.