[Flash CS4] Eigenschaft aus anderer Variable

[cosmoses]

Hallo Zusammen,
ist es möglich die Eigenschaften aus einer anderen Variable zu übernemen?
Ein Beispiel:

var heading:TextField = new TextField();
heading.autoSize = TextFieldAutoSize.LEFT;
heading.antiAliasType = AntiAliasType.ADVANCED;
heading.defaultTextFormat = menuFormat;
heading.selectable = false;
heading.mouseEnabled = false;

var menuHeading:heading = new heading;
	menuHeading.text = "hallo";

Benutze öfter Textfelder und würde mir gerne die ganzen Eigenschafts-Blöcke ersparen.

Danke

[thomas_E]

wilkommen in der wunderbaren Welt der Klassen
bau dir eine Klasse Heading mit den Eigenschaften, die du brauchst:

PHP-Code:

//Heading.as
package  
{
    import flash.text.AntiAliasType;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.text.TextFormat;

    public class Heading extends TextField
    {
        public function Heading(defaultTextFormat:TextFormat=null, text:String="") 
        {
            autoSize = TextFieldAutoSize.LEFT;
            antiAliasType = AntiAliasType.ADVANCED;
            selectable = false;
            mouseEnabled = false;
            
            if (defaultTextFormat) this.defaultTextFormat = defaultTextFormat;
            if (text) this.text = text;
        }
    }
} 


PHP-Code:

//menuFormat wird ja auf der Bühne definiert, und ist somit in der Klasse nicht bekannt
//deshalb übergeb ich es
//sowohl das Format, als auch der Text sind optional
var menuHeading:TextField = new Heading(menuFormat, "hallo"); 


oder du schreibst dir ne Funktion, die dir das Textfeld so zusammenbaut, wie du es brauchst:

PHP-Code:

function createHeading(defaultTextFormat:TextFormat=null, text:String=""):TextField
{
    var tf:TextField = new TextField();
        tf.autoSize = TextFieldAutoSize.LEFT;
        tf.antiAliasType = AntiAliasType.ADVANCED;
        tf.selectable = false;
        tf.mouseEnabled = false;
    
    if (defaultTextFormat) tf.defaultTextFormat = defaultTextFormat;
    if (text) tf.text = text;
    
    return tf;
}

var menuHeading:TextField = createHeading(menuFormat, "hallo"); 


[Martin Kraft]

Zitat von cosmoses

ist es möglich die Eigenschaften aus einer anderen Variable zu übernemen?

Ja, für genau sowas hat man Klassen erfunden.
Dafür brauchst Du eine Datei namens Heading.as im selben Verzeichnis mit folgendem Inhalt:

package {
    import flash.text.AntiAliasType;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.text.TextFormat;
    
    public class Heading extends TextField {
        
        static public const DEFAULT_FORMAT:TextFormat = new TextFormat();
        
        public function Heading( text:String = null ) {
            autoSize = TextFieldAutoSize.LEFT;
            antiAliasType = AntiAliasType.ADVANCED;
            defaultTextFormat = DEFAULT_FORMAT;
            selectable = false;
            mouseEnabled = false;
        }
    }
    
} 

Und diesen Code für die Instanziierung:

var menuHeading:Heading = new Heading("hallo");
addChild(menuHeading); 

[~pyropete~]

Bau Dir ein Objekt mit den Werten, welches Du dann per for...in-Loop an Dein Textfeld übergibst:

PHP-Code:


var myTextInits:Object = {autoSize:TextFieldAutoSize.LEFT, antiAliasType:AntiAliasType.ADVANCED, defaultTextFormat:menuFormat, selectable:false, mouseEnabled:true}

for(var i in myTextInits) {

   heading[i] = myTextInits[i];

} 


[cosmoses]

Super danke