[Flash CS5] dynamische button mit text feld - positionieren hilfe

[palpalo]

wenn ich so wie unten einige dynamaschie bts mit textfeld erstelle und dies neben einander positionieren will klappt nicht so wie es sein soll.

textfeld von bts haben verschieden länge, so dass ich mc hg auf diese textfeld gr0ße anpassen will und neben einander platzieren, klappt aber nicht.

PHP-Code:

var my_txt_feld:TextField;
var my_format:TextFormat;
var ofsetXY = 2;
var breite:Number;
var hoehe:Number;
//
var my_texts:Array = new Array("Button 1", "Button 2 Klick", "Button 3 Andere Breite", "Und So Weiter");
//
//
for(var i:uint=0; i<my_texts.length; i++){
    // 
    // main mc erstellen
    var _mc:MovieClip = new MovieClip();
    addChild(_mc);
    //
    // definiere format
    my_format = new TextFormat;
    my_format.font = "Verdana";
    my_format.color = 0x000000;
    my_format.size = 12;
    //
    // text feld erstellen
    my_txt_feld= new TextField();
    my_txt_feld.autoSize = "center";
    my_txt_feld.text = my_texts[i];
    my_txt_feld.setTextFormat(my_format);
    my_txt_feld.selectable = false;
    my_txt_feld.x = ofsetXY;
    my_txt_feld.y = ofsetXY;
    breite = my_txt_feld.width + (ofsetXY*2);
    hoehe = my_txt_feld.height + (ofsetXY*2);
    //
    // hg erstellen
    var _hg:Sprite = new Sprite();
    _hg.graphics.beginFill(0xff6600);
    _hg.graphics.drawRect(0,0,breite,hoehe);
    _hg.graphics.endFill();
    //
    _mc.addChild(_hg);
    _mc.addChild(my_txt_feld);
    //
    // position
    _mc.x = (_mc.width+2)*i;
    _mc.y = 50;
} 


[palpalo]

hat denn niemand ein idee, wieso bts nicht rightig in x richtung positioniert?

[Little Boy II]

Das Problem liegt hier im Script in Verbindung mit dem "autoSize" wie es aussieht...

so würde er es richtig positionieren, aber leider schneidet er dann die TextFelder ab, weil das autoSize entfernt wurde und daher alle textFelder gleichgroß sind.

PHP-Code:

var my_txt_feld:TextField;
var my_format:TextFormat;
var ofsetXY = 2;
var breite:Number;
var hoehe:Number;
//
var my_texts:Array = new Array("Button 1", "Button 2 Klick", "Button 3 Andere Breite", "Und So Weiter");
//
//
for(var i:uint=0; i<my_texts.length; i++){
    // 
    // main mc erstellen
    var _mc:MovieClip = new MovieClip();
    addChild(_mc);
    //
    // definiere format
    my_format = new TextFormat;
    my_format.font = "Verdana";
    my_format.color = 0x000000;
    my_format.size = 12;
    //
    // text feld erstellen
    my_txt_feld= new TextField();
    //my_txt_feld.autoSize = "center";
    my_txt_feld.text = my_texts[i];
    my_txt_feld.height = 20;
    my_txt_feld.setTextFormat(my_format);
    my_txt_feld.selectable = false;
    my_txt_feld.x = ofsetXY;
    my_txt_feld.y = ofsetXY;
    breite = my_txt_feld.width + (ofsetXY*2);
    //hoehe = my_txt_feld.height + (ofsetXY*2);
    //
    // hg erstellen
    var _hg:Sprite = new Sprite();
    _hg.graphics.beginFill(0xff6600);
    _hg.graphics.drawRect(0,0,breite,my_txt_feld.height);
    _hg.graphics.endFill();
    //
    _mc.addChild(_hg);
    _mc.addChild(my_txt_feld);
    //
    // position
    _mc.x = (_mc.width+2)*i;
    _mc.y = 50;
} 


Sollte ich noch etwas herausfinden, werde ich es posten

[andrelehnert]

Du müsstest während der Erstellung der Buttons die jeweilige Größe checken.
Wenn die größte Breite ermittelt ist, alles mcs auf diese Breite bringen und dann positionieren.

LG André

[andrelehnert]

Hier mal ein Beispiel anhand Deiner Vorgabe.

PHP-Code:

var my_txt_feld:TextField;
var my_format:TextFormat;
var ofsetXY = 2;
var breite:Number;
var hoehe:Number;
var maxWidth:Number=0;
//
var my_texts:Array = new Array("Button 1", "Button 2 Klick", "Button 3 Andere Breite", "Und So Weiter");
var mcArray:Array=[];
//
//
function buildButtons():void{
    for(var i:uint=0; i<my_texts.length; i++){
        // 
        // main mc erstellen
        var _mc:MovieClip = new MovieClip();
        addChild(_mc);
        //
        // definiere format
        my_format = new TextFormat;
        my_format.font = "Verdana";
        my_format.color = 0x000000;
        my_format.size = 12;
        //
        // text feld erstellen
        my_txt_feld= new TextField();
        my_txt_feld.autoSize ="center";
        my_txt_feld.htmlText = my_texts[i];
        my_txt_feld.height = 20;
        my_txt_feld.setTextFormat(my_format);
        my_txt_feld.selectable = false;
        my_txt_feld.x = ofsetXY;
        my_txt_feld.y = ofsetXY;
        breite = my_txt_feld.width + (ofsetXY*2);
        //hoehe = my_txt_feld.height + (ofsetXY*2);
        //
        // hg erstellen
        var _hg:Sprite = new Sprite();
        _hg.graphics.beginFill(0xff6600);
        _hg.graphics.drawRect(0,0,breite,my_txt_feld.height);
        _hg.graphics.endFill();
        //
        _mc.addChild(_hg);
        _mc.addChild(my_txt_feld);
        mcArray.push(_mc);
        //
        
        if (_mc.width>maxWidth) maxWidth=_mc.width       
    } 
    setPositions();
};

function setPositions():void{
    for(var i:uint=0; i<mcArray.length; i++){
        var _mc:MovieClip = mcArray[i]
        _mc.width = maxWidth;
        _mc.x = (_mc.width+2)*i;
        _mc.y = 50;
    }
} 


LG ANdré

[palpalo]

funktioniert leider immer noch nicht so wie es sein soll.

jeder bt hat verschieden länge text.
hintergrund sprite von bts, die erstellt werden, sollen in breite wie der text feld breite haben.
dann soll diese bts neben einander platziert werden.

[andrelehnert]

Du musst Dich einfach klarer ausdrücken, was das Ziel der Veranstaltung ist.
Daß der Text unterschiedlich lang ist, ist ja klar.
Werden die Buttons dadurch unterschiedlich groß?
Oder sollen sie eine Größe haben?

LG ANdré

[palpalo]

Zitat von andrelehnert

Werden die Buttons dadurch unterschiedlich groß?
LG ANdré

genau

[andrelehnert]

dann so:

PHP-Code:

var my_txt_feld:TextField;
var my_format:TextFormat;
var ofsetXY = 2;
var breite:Number;
var hoehe:Number;

//
var my_texts:Array = new Array("Button 1","Button 2 Klick","Button 3 Andere Breite","Und So Weiter");
var mcArray:Array = [];
//
//
function buildButtons():void
{
    for (var i:uint=0; i<my_texts.length; i++)
    {
        // 
        // main mc erstellen
        var _mc:MovieClip = new MovieClip();
        addChild(_mc);
        //
        // definiere format
        my_format = new TextFormat  ;
        my_format.font = "Verdana";
        my_format.color = 0x000000;
        my_format.size = 12;
        //
        // text feld erstellen
        my_txt_feld= new TextField();
        my_txt_feld.autoSize = "left";
        my_txt_feld.htmlText = my_texts[i];
        my_txt_feld.setTextFormat(my_format);
        my_txt_feld.selectable = false;
        my_txt_feld.x = ofsetXY;
        my_txt_feld.y = ofsetXY;

        // hg erstellen
        var _hg:Sprite = new Sprite();
        _hg.graphics.beginFill(0xff6600);
        _hg.graphics.drawRect(-ofsetXY, -ofsetXY, my_txt_feld.width + ofsetXY * 2, my_txt_feld.height + ofsetXY * 2);
        _hg.graphics.endFill();
        //;
        _mc.addChild(_hg);
        _mc.addChild(my_txt_feld);
        mcArray.push(_mc);
    }
    setPositions();
}

function setPositions():void
{
    var lastX:Number = 0;
    for (var i:uint=0; i<mcArray.length; i++)
    {
        var _mc:MovieClip = mcArray[i];
        _mc.x = lastX;
        lastX +=  _mc.width + 2;
    }
}
buildButtons(); 


LG André

[thomas_E]

PHP-Code:

var buttonLabels:Array = ["Button 1", "Button 2 Klick", "Button 3 Andere Breite", "Und So Weiter"];
buildButtons(buttonLabels, 2);

function buildButtons(labels:Array, offsetXY:Number=0):void
{
    //Startposition für x
    var px:int = 0;
    
    for each(var label:String in labels){
        // definiere format
        var format:TextFormat = new TextFormat();
            format.font = "Verdana";
            format.color = 0x000000;
            format.size = 12;

        // text feld erstellen
        var tf:TextField = new TextField();
            tf.autoSize = "center";
            tf.htmlText = label;
            tf.height = 20;
            tf.setTextFormat(format);
            tf.selectable = false;
            tf.x = offsetXY;
            tf.y = offsetXY;
            
        //halbe Pixel sind uncool
        var w:int = Math.ceil(tf.width + offsetXY*2);
        var h:int = Math.ceil(tf.height);
        //var h:int = Math.ceil(tf.height + offsetXY*2);
        
        // main mc erstellen
        // hg erstellen
        var mc:Sprite = new Sprite();
            mc.graphics.beginFill(0xff6600);
            mc.graphics.drawRect( 0, 0, w, h);
            mc.graphics.endFill();
            mc.addChild(tf);
            mc.x = px;
            mc.y = 50;
        addChild(mc);
        
        px += w;
    }
} 


versuch bitte auf my_ in Variablennamen zu verzichten, und nicht alle Varialen global zu definieren.

[palpalo]

andrelehnert & thomas_E

danke euch beide.
funktioniert beide versionen