[Flash CS5] Drei Arrays vergleichen

[FlashQualle]

Ich möchte es gerne schaffen drei Arrays in denen sich variable zahlen befinden zu vergleichen und herausfinden, welche der Zahlen in allen drei Arrays vorkommt.

Weiß vielleicht einer eine Lösung.

[thomas_E]

PHP-Code:

var arr1:Array = [2, 3, 4, 5, 6, 7, 8, 9, 10];
var arr2:Array = [1, 3, 5, 7];
var arr3:Array = [1, 2, 3, 5, 7, 11, 13];
var arr4:Array = [2, 4, 6, 8];

function compareArrays(...arrays:Array):Array
{
    var out:Array = [];
    if(arrays.length > 1){
        arrays.sortOn('length', Array.NUMERIC);
        
        for each(var v:* in arrays.shift()){
            var c:Boolean = false;
            for each(var arr:Array in arrays){
                
                if(arr.indexOf(v) == -1){
                    c = true;
                    break;
                }
            }
            if(c) continue;
            
            out.push(v);
        }
    }else if(arrays.length == 1){
        return arrays[0].slice();
    }
    return out;
}


trace('->', compareArrays(arr1, arr2, arr3));
trace('->', compareArrays(arr1, arr4));
trace('->', compareArrays(arr4, arr1, arr3));
trace('->', compareArrays());
trace('->', compareArrays(arr3, arr1, arr4, arr2));
trace('->', compareArrays(arr2)); 


[Omega Psi]

Eine andere Variante.

function getDoubles(array:Array /* of Arrays of uint, int or Number */):Array /* of uint, int or Number */
{
	if (!array || array.length <= 1) return [];

	array.forEach(function(element:Array, index:int, arr:Array):Boolean {
				return element.sortOn('length', Array.NUMERIC)})

	var max:int = 0;

	for each(var harry:Array in array)
		if (harry[harry.length - 1] > max)
			max = harry[harry.length - 1];

	const ret:Array = [];

	for (var i:int; i <= max; i++)
		if (array.every(function(element:Array, index:int, arr:Array):Boolean {
				return element.indexOf(i) > -1;}))
			ret[ret.length] = i;

	return ret;
}

[thomas_E]

hast mich auf eine Idee gebracht. mal ein sinvoller Einsatz für Closures

PHP-Code:

function compareArrays(arrays:Array):Array
{
    if(!arrays || arrays.length < 1) return [];
    
    arrays.sortOn('length', Array.NUMERIC);
    return arrays.shift().filter(function(v:*, index:int, array:Array):Boolean {
        return arrays.every(function(arr:Array, index:int, array:Array):Boolean { return arr.indexOf(v) > -1; });
//  }).sort(Array.NUMERIC);        //entweder
    });                            //oder
} 


[szylla]

wtf?! sehr krass!

--> "Closures"?! infos bitte...

[Omega Psi]

Closures speichern die Informationen des Scopes, in denen eine Funktion aufgerufen wird. So hat haben die anonymen Funktionen, die in Array.every und Array.filter definiert werden, Zugang auf Variablen, die in der umgebenden Funktion definiert sind.

[milchreis]

Zitat von szylla

--> "Closures"?! infos bitte...

Array (ActionScript 3.0)

Für diese Methode muss der zweite Parameter (thisObject) den Wert null haben, wenn der erste Parameter (callback) ein Methodenabschluss ist.

Das machen Omega und Thomas indem sie den zweiten Parameter weg lassen, der hat den defaultwert null. (siehe Link)

Closure, Methode, Funktion, Prozedur, Routine...Informatik, Wissenschaft der vielen schicken Namen für sehr ähnliche Dinge. (Polymorphie ist wirklich überall )

[Omega Psi]

Closure != Methode.

[milchreis]

Zitat von Omega Psi

Closure != Methode.

Das Gegenteil hat niemand behauptet.

[Omega Psi]

Hab mich geirrt. Hatte eine Formulierung falsch im Hinterkopf

[JoH]

Closures speichern die Informationen des Scopes, in denen eine Funktion aufgerufen wird. So hat haben die anonymen Funktionen, die in Array.every und Array.filter definiert werden, Zugang auf Variablen, die in der umgebenden Funktion definiert sind.

Und genau deswegen sind closures ein sehr mächtiges Instrument und es ist erfreulich das es in as3 möglich ist.
In Java z.B. ist das derzeit nicht möglich.