[Flash CS5] In Classe werden Keyboard eingaben nicht erkannt

[Opi3]

hallo,
ich wollte fragen warum in der Classe das ENTER_FRAME.Event ausgeführt wird, die KeyboardEvent's aber auf der strecke bleiben:

PHP-Code:

package 
{
    import flash.events.Event;
    import flash.events.TimerEvent;
    import flash.utils.Timer;
    import flash.events.KeyboardEvent;
    import flash.text.TextField;
    import flash.display.Sprite;

    public class FpsI extends Sprite
    {
        public var rate:Number = 0;
        private var anzahl:Number = 0;
        private var timer:Timer;
        private var WOIS:Number;
        private var textFeld:TextField = new TextField();

        public function FpsI(WieOftInSecunde:Number)
        {
            WOIS = WieOftInSecunde;
            addEventListener(Event.ENTER_FRAME,counter);
            timer = new Timer(1000 / WOIS,0);
            timer.addEventListener("timer", timerHandler);
            timer.start();
            addEventListener(KeyboardEvent.KEY_DOWN,zeigen);
        }

        private function timerHandler(event:TimerEvent):void
        {
            rate = anzahl;
            anzahl = 0;
            textFeld.text = "Fps: " + rate;
            trace("Fps: "+ rate);
        }

        private function counter(e:Event)
        {
            anzahl +=  WOIS;
        }

        private function zeigen(e:KeyboardEvent)
        {
            trace("zeigen");
            if (e.keyCode == 17)
            {
                addChild(textFeld);
                removeEventListener(KeyboardEvent.KEY_DOWN,zeigen);
                addEventListener(KeyboardEvent.KEY_UP,verstecken);
            }
        }

        private function verstecken(e:KeyboardEvent)
        {
            trace("verstecken");
            addEventListener(KeyboardEvent.KEY_DOWN,zeigen);
            removeEventListener(KeyboardEvent.KEY_UP,verstecken);
            removeChild(textFeld);
        }

    }
} 


anbei:
ich habe noch nicht so viel Erfahrung mit classen,
wenn ich also einen fatalen Fehler(im Aufbau, u.s.w) würde ich mich über Aufklärung freuen.

Viele Grüße Opi3
Wenn es wieder so ein "ÜbermüdungsFehler" ist tut es mir Leid das ich euch die Zeit gestohlen habe.

[andrelehnert]

Du mußt diesen Eventlistener bei der Stage registrieren...

Du könntest beispielsweise eine referenz der stage an diese Klasse übergeben
oder den Listener direkt in der Dokumentenklasse registrieren und durch dessen EventHandler dann in deiner Klasse FpsI eine public function ausführen...

LG ANdré

[shin10]

Nur so als Ergänzung: Das liegt am Focus. Wenn du den mc anklickst, dann sollten die KeyboardEvents auch funktionieren. Man will ja z. B. bei zwei Textfeldern nicht gleichzeitig in beide schreiben, sondern nur in das zuletzt gewählte.

Wenn das trotzdem immer sein soll, machst du das wie Andre sagte über die stage. Allerdings muss man dazu wissen, dass ein DisplayObject wie dein Sprite hier, die stage erst kennt, wenn du das Objekt mit addChild() auf die Bühne gesetzt hast (andernfallst hat es ja keine stage, genausowenig wie ein parent). Daher funktioniert das im Konstruktor noch nicht sondern erst später. Aber auch dafür gibt es Events.

Bsp. (wieder mal ungetestet):

PHP-Code:

package 
{
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.KeyboardEvent;

    public class EinBeispiel extends Sprite
    {
        public function EinBeispiel (){
            trace(stage);//kennt er noch nicht
            addEventListener(Event.ADDED_TO_STAGE, addedToStage, false, 0, true);
        }
        private function addedToStage(e:Event):void{
            removeEventListener(Event.ADDED_TO_STAGE, addedToStage);
            trace(stage);//jetzt kennt er seine stage
            stage.addEventListener(KeyboardEvent.KEY_DOWN, keyDownHandler, false, 0, true);
        }
        private function keyDownHandler(e:KeyboardEvent):void{
            trace(e.toString());
        }

    }
} 


mfg

sx

[Opi3]

Ich bedanke mich bei euch, vielleicht könnt ihr damit ja was anfangen:

PHP-Code:

package 
{

//by Opi3:

    import flash.events.Event;
    import flash.events.TimerEvent;
    import flash.utils.Timer;
    import flash.events.KeyboardEvent;
    import flash.text.TextField;
    import flash.display.Sprite;

    public class FpsI extends Sprite
    {
        public var rate:Number = 0;
        private var anzahl:Number = 0;
        private var timer:Timer;
        private var WOIS:Number;
        private var textFeld:TextField = new TextField();

        public function FpsI(WieOftInSecunde:Number)
        {

            WOIS = WieOftInSecunde;
            addEventListener(Event.ADDED_TO_STAGE, addedToStage);
        }

        private function addedToStage(e:Event):void
        {
            removeEventListener(Event.ADDED_TO_STAGE, addedToStage);
            stage.addEventListener(Event.ENTER_FRAME,counter);
            timer = new Timer(1000 / WOIS,0);
            timer.addEventListener("timer", timerHandler);
            timer.start();
            stage.addEventListener(KeyboardEvent.KEY_DOWN,zeigen);
        }

        private function timerHandler(event:TimerEvent):void
        {
            rate = anzahl;
            anzahl = 0;
            textFeld.text = "Fps: " + rate;
            textFeld.x = 10;
            textFeld.y = 10;
        }

        private function counter(e:Event)
        {
            anzahl +=  WOIS;
        }

        private function zeigen(e:KeyboardEvent)
        {
            if (e.keyCode == 17)
            {
                stage.addChild(textFeld);
                removeEventListener(KeyboardEvent.KEY_DOWN,zeigen);
                stage.addEventListener(KeyboardEvent.KEY_UP,verstecken);
            }
        }

        private function verstecken(e:KeyboardEvent)
        {
            if (e.keyCode == 17)
            {
                stage.addEventListener(KeyboardEvent.KEY_DOWN,zeigen);
                removeEventListener(KeyboardEvent.KEY_UP,verstecken);
                stage.removeChild(textFeld);
            }
        }

    }
} 


Auf jeden fall vielen Dank für die Hilfe.
Viele Grüße Opi3