[Flash CS3] bilder auf bühne mittig plazieren

[solschenizyn]

wie kann ich meine galeriebilder auf der bühnenmitte anzeigen lassen?

[Opi3]

Kann die Fla momentan nicht öffnen (anderer Computer) aber der Link dürfte dir helfen.
Forum interner Link
Viele Grü?e

[solschenizyn]

sorry, kann die fla auf deinem link auch nicht öffnen... wat nu?

[RustyCake]

Ich glaube Ihr redet von zwei verschiedenen Dingen!
im ctr.onEnterFrame findest Du das Script.

PHP-Code:

var pictureBase:Array = [];
var textBase:Array = [];
var containerBase:Array = [];
var memoContainer:MovieClip;
var count:Number = 0;
var bilderGesamt:Number =0;
l_btn._visible = false;
// -- >
var xmlData:XML = new XML ();
xmlData.ignoreWhite = true;
xmlData.onLoad = function (aloha:Boolean) {
    if (aloha) {
        bilderGesamt = this.firstChild.firstChild.childNodes.length;
        for (var i:Number = 0; i < this.firstChild.firstChild.childNodes.length; i++) {
            pictureBase[i] = this.firstChild.firstChild.childNodes[i].attributes.bild;
            textBase[i] = this.firstChild.firstChild.childNodes[i].attributes.begleittext;
        }
    }
    buildGalerie ();
};
// -- >
var ctr:MovieClip = this.createEmptyMovieClip("loadControl", this.getNextHighestDepth());
function buildGalerie () {
    for (var i:Number = 0; i < pictureBase.length; i++) {
        var con:MovieClip = this.createEmptyMovieClip ("con", this.getNextHighestDepth ());
        con._x=5;
        con._y =2;
        containerBase[i] = con;
    }
    var cB:MovieClip = containerBase[count];
    cB.loadMovie (pictureBase[count]);
    ctr.onEnterFrame = function(){
        if((cB.getBytesLoaded()>=cB.getBytesTotal())&&cB.getBytesLoaded()>4){
            cB._x = (Stage.width/2)-(cB._width/2);
            cB._y= (Stage.height/2)-(cB._height/2);
            delete this.onEnterFrame;
        }
    }
    bilderanzahl.text = (count+1)+" von "+bilderGesamt;
    begleit_txt.text = textBase[count];
    memoContainer = containerBase[count];
}
// -- >
r_btn.onPress = function () {
    if (count < containerBase.length - 1) count++; btnCheck();
};
// -- >
l_btn.onPress = function () {
    if (count > 0) count--; btnCheck();
};
// -- >
function btnCheck(){
    memoContainer.unloadMovie ();
    containerBase[count].loadMovie (pictureBase[count]);
    bilderanzahl.text = (count+1)+" von "+bilderGesamt;
    begleit_txt.text = textBase[count];
    count >= containerBase.length - 1?r_btn._visible = false:r_btn._visible = true;
    count <=0?l_btn._visible = false:l_btn._visible = true;
}
// -- >
xmlData.load ("image_galerie.xml");
// -- >
/*
<?xml version="1.0" encoding="iso-8859-1"?>
<images>
  <gallery id="1" titel="Nasa-Bild-Set-1">
    <image bild="bilder/Nasa_1.jpg" begleittext="Nasa_1.jpg"/>
    <image bild="bilder/Nasa_2.jpg" begleittext="Nasa_2.jpg"/>
    <image bild="bilder/Nasa_3.jpg" begleittext="Nasa_3.jpg"/>
    <image bild="bilder/Nasa_4.jpg" begleittext="Nasa_4.jpg"/>
  </gallery>
</images>
*/