[Flash CS5] as3 - remove movieclip

[palpalo]

ich möchte mit ein kleine funktion verschiedene anzahl von objekte erstellen, bzw. löschen, sobald ich die nicht mehr brauche.

PHP-Code:

//
var my_mc_array:Array = new Array();
var alteZahl:int;
//
function erstelle(evt:MouseEvent){
    //
    // ermittle bt id, um zugehörige anzahl von clip zu erstellen
    var id:uint = Number(evt.target.name.split("_")[1]);
    trace(id);
    //
    // anzahl der clip, die zu bt id gehören
    var AnZahlArray:Array = [5,10,15];
    var total = AnZahlArray[id-1];
    //
    trace("alte zahl am anfang: " + alteZahl);
    //
    var my_mc_array_alt:Array = new Array();
    my_mc_array = my_mc_array_alt;
    //
    /// lösche verherige clips
    for(var r:uint=0; r<alteZahl; r++){
        removeChild(my_mc_array[r]);
    }
    //
    //schleife zum erstellen von clips
    for(var i:uint = 0; i<total; i++){
        var my_mc:MovieClip = new MovieClip(); 
        addChild(my_mc);
        my_mc.buttonMode = true;
        
        var hg:Sprite = new Sprite();
        my_mc.addChild(hg);
        hg.graphics.beginFill(0x0000FF);
        hg.graphics.drawRect(0,0,50,50);
        hg.graphics.endFill();

        my_mc.y = (my_mc.height+5)*i;
        my_mc.x = stage.stageWidth/2-my_mc.width/2;
        my_mc.name = "mc_"+i;
        my_mc_array.push(my_mc);
    }
    //
    alteZahl = total;
    trace("alte zahl am ende: " + alteZahl);
}
//
//
bt_1.buttonMode = true;
bt_1.addEventListener(MouseEvent.CLICK,erstelle);
bt_2.buttonMode = true;
bt_2.addEventListener(MouseEvent.CLICK,erstelle);
bt_3.buttonMode = true;
bt_3.addEventListener(MouseEvent.CLICK,erstelle); 


löschen klappt aber nicht. was mache ich falsch.


fehler meldung dazu, nachdem klicken irgend einer bt(nach erstmalige swf aufruf), geht nicht mehr.

PHP-Code:

TypeError: Error #2007: Parameter child darf nicht 'null' sein.
    at flash.display::DisplayObjectContainer/removeChild()
    at rem_fla::MainTimeline/erstelle() 


[szylla]

hi,
ich hab mir das jetzt nicht näher angeschaut.
aber was kommt denn raus wenn du ein trace an der stelle hier einfügst?

PHP-Code:

/// lösche verherige clips
    for(var r:uint=0; r<alteZahl; r++){
        trace(my_mc_array[r]);
    } 


cu,
szylla

[Martin Kraft]

Zitat von palpalo

PHP-Code:

var my_mc_array_alt:Array = new Array();
my_mc_array = my_mc_array_alt; 


Nach diesen beiden Anweisungen ist my_mc_array immer leer. Und ein beliebiger Index eines leeren Arrays ist nunmal null.

[palpalo]

so klappt es

PHP-Code:

removeChild(getChildByName("mc_"+[r])); 


wenn aber der mc ein unter objekt ist klappt trotzdem mit der byName nicht mehr.

[palpalo]

Zitat von Martin Kraft

Nach diesen beiden Anweisungen ist my_mc_array immer leer. Und ein beliebiger Index eines leeren Arrays ist nunmal null.

wieso ist es null, an falscher stelle intializiert?
bzw. wie ist es richtig.

[Martin Kraft]

Zitat von palpalo

wieso ist es null, an falscher stelle intializiert?

Lies nochmal was ich geschrieben habe!

Zitat von palpalo

bzw. wie ist es richtig.

Versuch's mal so:

PHP-Code:

import flash.display.MovieClip;
import flash.display.Sprite;
import flash.events.MouseEvent;

var activeMcs:Array = [];

function erstelle(evt:MouseEvent):void {
    var mc:MovieClip;
    var hg:Sprite;
    
    // Alte MCs entfernen
    for each(mc in activeMcs) {
        if (mc.parent) mc.parent.removeChild(mc);
    }
    
    // Array zurücksetzen
    activeMcs = [];

    // ermittle bt id, um zugehörige anzahl von clip zu erstellen
    var id:uint = Number(evt.target.name.split("_")[1]);    
    // anzahl der clip, die zu bt id gehören
    var AnZahlArray:Array = [5,10,15];
    var total = AnZahlArray[id - 1];
    
    // Neue MCs erzeugen
    for(var i:uint = 0; i<total; i++){
        mc = new MovieClip(); 
        mc.buttonMode = true;
        
        hg = new Sprite();
        hg.graphics.beginFill(0x0000FF);
        hg.graphics.drawRect(0,0,50,50);
        hg.graphics.endFill();        
        mc.addChild(hg);

        mc.y = (mc.height + 5) * i;
        mc.x = stage.stageWidth / 2 - mc.width / 2;
        mc.name = "mc_" + i;
        
        addChild(mc);
        activeMcs.push(mc);
    }
}

bt_1.buttonMode = true;
bt_1.addEventListener(MouseEvent.CLICK,erstelle);
bt_2.buttonMode = true;
bt_2.addEventListener(MouseEvent.CLICK,erstelle);
bt_3.buttonMode = true;
bt_3.addEventListener(MouseEvent.CLICK,erstelle);