[Flash CS3] AS2 Movieclip anhalten

[tillibilli]

Hallo an Alle! Dies ist meine erste Frage im Forum: Ich habe ein Skript in AS2, das Schneefall erzeugt. Klappt prima. Wie kann ich jetzt ein Standbild erzeugen? Oder besser gesagt, was muss ich im Code eingeben, dass das Skript nach 5 Sek oder 120 Bildern stoppt ? Geht das überhaupt?
Skript lautet:
amount = 100;
mWidth = 550;
mHeight = 400;
for (var i = 0; i<amount; i++) {

thisFlake = this.attachMovie("mc_flake", "mc_flake"+i, i);

with (thisFlake) {
_x = Math.random()*mWidth;
_y = Math.random()*mHeight;
_xscale = _yscale=_alpha=40+Math.random()*60;
}
thisFlake.yspeed = Math.random()*2+.2;
thisFlake.increment = -0.025+Math.random()*0.05;
thisFlake.radian = 0;
thisFlake.onEnterFrame = function() {
this.radians += this.increment;
//trace(this.radians);
this._x += Math.sin(this.radians);
this._y += this.yspeed;
if (this._y>=mHeight) {
this._y = -10;
this._x = -10+Math.random()*mWidth;
}
if (this._x>=mWidth || this._x<=0) {
this._y = -10;
this._x = -10+Math.random()*mWidth;
}
};
}

[salazar]

hi und willkommen im flashforum,
schreib einfach folgenden code unter deinen:

PHP-Code:

var container = this;

setTimeout( stopAll, 5000 );//5000 = 5 sekunden

function stopAll() {
    
    for ( var i = 0; i < amount; i++ )
        delete container[ "mc_flake" + i ].onEnterFrame;

} 


AS2 Movieclip anhalten

das ist allerdings kein AS2, sondern AS1

cheers,
sal

[RustyCake]

Bisschen mehr in Richtung AS2

PHP-Code:

var amount:Number = 100;
var mWidth:Number = 550;
var mHeight:Number = 400;
var flakeStopp:Boolean = false;
this.createEmptyMovieClip("holder", this.getNextHighestDepth());
for (var i = 0; i < amount; i++)
{
    var thisFlake:MovieClip = holder.attachMovie ("mc_flake", "mc_flake" + i, holder.getNextHighestDepth());
    with (thisFlake)
    {
        _x = Math.random () * mWidth;
        _y = Math.random () * mHeight;
        _xscale = _yscale = _alpha = 40 + Math.random () * 60;
    }
    thisFlake.yspeed = Math.random () * 2 + .2;
    thisFlake.increment = -0.025 + Math.random () * 0.05;
    thisFlake.radian = 0;
    thisFlake.onEnterFrame = function ()
    {
        if (!flakeStopp)
        {
            this.radians += this.increment;
            //trace(this.radians);
            this._x += Math.sin (this.radians);
            this._y += this.yspeed;
            if (this._y >= mHeight)
            {
                this._y = -10;
                this._x = -10 + Math.random () * mWidth;
            }
            if (this._x >= mWidth || this._x <= 0)
            {
                this._y = -10;
                this._x = -10 + Math.random () * mWidth;
            }
        }
    };
}
setTimeout (timer,5000);
function timer ()
{
    flakeStopp = true;
    //removeMovieClip(holder);
} 


Die Komentare vor remove weg machen, dann verschwindet alles

Oopps der sal war schon da

[tillibilli]

Danke für die schnelle Antwort. der Code für AS1 von salazar klappt prima. Beim 2. Code für AS 2 schneit es überhaupt nicht mehr . Trotzdem Danke an RustyCake. Mein Problem ist damit gelöst.

[tillibilli]

So. Der Schnee stoppt jetzt wie gewünscht in Szene 1. Mit einem Button kommt man zu Szene 2. Klappt auch. Leider sind die Schneeflocken aus der 1. Szene noch in Szene 2 zu sehen. Wie bekomme ich die weg? Mit removeMovie() oder unloadMovie() verschwindet alles. Vielleicht wisst ihr noch so einen guten Tipp.

[RustyCake]

Möchte ja nicht kleinlich sein, aber das was ich gepostet hab, funktioniert.
Ich mache keine ungetesteten Uploads

[tillibilli]

Ja es funktioniert. Ich hatte AS1 eingestellt statt AS2. Nochmals Danke