Actionscript 3 - Von DocumentClass eine weitere Class laden

[Patasss]

Moin moin zusammen,

ich habe ein kleines Problem und zwar habe ich eine DocumentClass, in der ich einen Preloader implementiert habe. Der Preloader soll auch die zweite Class vorladen und sobald er fertig ist in der zweiten Class loadStage() ausführen. Nur funktioniert das nicht. Was mache ich falsch?

DocumentClass:

PHP-Code:

package {
        
    import flash.display.MovieClip;
    import flash.events.Event;
    import flash.events.ProgressEvent;
    import flash.net.*;
    import flash.text.*;
    
    public class ShowTeam extends MovieClip
    {
        // Textfeld für % Angabe
        private var _preloaderVar : TextField;
        // Textfeld für "Loading:" Text
        private var _preloaderText : TextField;
public function ShowTeam()
        {
            // Stop in Szene 1, Bild 1
            stop();
            // loaderInfo für Preloader - während Datei geladen wird
            loaderInfo.addEventListener(ProgressEvent.PROGRESS, isLoading);
            // loaderInfo für Preloader - Wenn Event fertig geladen
            loaderInfo.addEventListener(Event.COMPLETE, isCompleted);
            // loaderInfo für Preloader - Wenn Event initialisiert wird
            loaderInfo.addEventListener(Event.INIT, Init);
        }
        
        private function Init(event : Event) : void
        {
            // Textfelder initialisieren
            _preloaderVar = new TextField();
            _preloaderText = new TextField();
            // Textfarbe der Texte auf Weiß
            _preloaderVar.textColor = 0x000000;
            _preloaderText.textColor = 0x000000;
            // Position der % Angabe
            _preloaderVar.x = 280;
            _preloaderVar.y = 205;
            // Position des "Loading:" Text
            _preloaderText.x = 247;
            _preloaderText.y = 205;
            // AutoSize der Textfelder auf CENTER
            _preloaderVar.autoSize = TextFieldAutoSize.CENTER;
            _preloaderText.autoSize = TextFieldAutoSize.CENTER;
            // Anfangswerte der Textfelder
            _preloaderVar.text = "0 %";
            _preloaderText.text = "Loading: ";
            // Textfelder einbinden
            addChild(_preloaderText);
            addChild(_preloaderVar);
        }
        
        private function isCompleted(event : Event) : void
        {
            // Textfelder löschen
            removeChild(_preloaderText);
            removeChild(_preloaderVar);
            // Weiter zum nächsten Bild
            loadStage();
        }
        
        private function isLoading(progressEvent : ProgressEvent) : void
        {
            // Berechnung der % Angabe durch Momentan Geladene Bytes * 100 / Alle Bytes
            var percent:Number = Math.floor(progressEvent.bytesLoaded*100/progressEvent.bytesTotal);
            // Berechnete % Angabe in Typ String umwandeln und dem Textfeld der % Angabe zuweisen
            _preloaderVar.text = percent.toString() + " %";        
        }
    }
} 


Zweite Class:

PHP-Code:

package
{
    import flash.display.MovieClip;
    import flash.net.*;
    import flash.text.*;
    
    public class LoadAplication extends MovieClip
    {
        // Textunterschrift
        public var subscribe : TextField;
        // Bild
        public var picture : BitmapLoader;
        //Detailbg
        public var detailbg : BitmapLoader;
        //
        public var mname : TextField;
        public var position : TextField;
        public var schwerpunkte : TextField;
        public var schwerpunkte_txt : TextField;
        public var interessen : TextField;
        public var interessen_txt : TextField;
        public var vision : TextField;
        public var vision_txt : TextField;
        public var kontakt : TextField;
        public var kontakt_txt : TextField;
        
        public function LoadAplication()
        {
            loadStage();
        }
        
        public function loadStage() : void
        {
            var headerbg : BitmapLoader = new BitmapLoader("images/headerbg.jpg");
            var footerbg : BitmapLoader = new BitmapLoader("images/footerbg.jpg");
            headerbg.x = 0;
            headerbg.y = 0;
            footerbg.x = 0;
            footerbg.y = 375;
            addChild(headerbg);
            addChild(footerbg);
            loadMembers();
        }
        
        public function loadMembers() : void
        {
            var anzahl : uint = 0;
            var member1_img : BitmapLoader = new BitmapLoader("images/member1.jpg");
            var member2_img : BitmapLoader = new BitmapLoader("images/member2.jpg");
            var member1 : MovieClip = new MovieClip();
            member1.addChild(member1_img);
            var member2 : MovieClip = new MovieClip();
            member2.addChild(member2_img);
            member1.x = 0;
            member2.x = 50;
            var memberContainer : MovieClip = new MovieClip();
            memberContainer.addChild(member1);
            memberContainer.addChild(member2);
            memberContainer.y = 6;
            memberContainer.x = 5;
            addChild(memberContainer);            
        }
        
        public function loadSubScribe(subscribe_txt : String) : void
        {
            subscribe = new TextField()
            subscribe.autoSize = TextFieldAutoSize.LEFT;
            subscribe.text = subscribe_txt;
            var normal : TextFormat = new TextFormat();
            normal.font = "Verdana";
            normal.size = 16;
            normal.color = 0x454545;
            normal.bold = true;
            subscribe.setTextFormat(normal);
            subscribe.x = 205;
            subscribe.y = 380;
            addChild(subscribe);
        }
        
        public function removeSubScribe() : void
        {
            removeChild(subscribe);
        }
        
        public function loadPicture(imgurl : String) : void
        {
            picture = new BitmapLoader(imgurl);
            picture.x = 51;
            picture.y = 89;
            addChild(picture);
        }
        
        public function removePicture() : void
        {
            removeChild(picture);
        }
        
        public function loadDetails(memname : String) : void
        {
            (...)

            // Selection
            if (memname === "fd")
            {
                mname.text = "fd";
                position.text = "fd";
                schwerpunkte_txt.text = "fd";
                interessen_txt.text = "fd";
                vision_txt.text = "fd";
                kontakt_txt.text = "fd";
            }    
            mname.setTextFormat(h1);
            position.setTextFormat(pposition);
            schwerpunkte_txt.setTextFormat(pposition);
            interessen_txt.setTextFormat(pposition);
            vision_txt.setTextFormat(pposition);
            kontakt_txt.setTextFormat(pposition);
            addChild(mname);
            addChild(position);
            addChild(schwerpunkte_txt);
            addChild(interessen_txt);
            addChild(vision_txt);
            addChild(kontakt_txt);    
        }
        
        public function removeDetails() : void
        {
            removeChild(mname);
            removeChild(position);
            removeChild(schwerpunkte_txt);
            removeChild(interessen_txt);
            removeChild(vision_txt);
            removeChild(kontakt_txt);
            removeChild(schwerpunkte);
            removeChild(interessen);
            removeChild(vision);
            removeChild(kontakt);
            removeChild(detailbg);
        }
    }
} 


Könnt Ihr mir sagen wie ich die zweite Class anspreche und Methoden ausführe, wie Ihr sehen könnt hat es bei mir noch nicht wirklich geklappt.

Vielen Dank im Voraus
Viele Grüße
Patasss

[rendner[i]]

Du musst eine Instanz der Klasse erzeugen:

PHP-Code:

private function isCompleted(event : Event) : void
        {
            // Textfelder löschen
            removeChild(_preloaderText);
            removeChild(_preloaderVar);
            // Weiter zum nächsten Bild
           
            addChild( new LoadAplication() );
        } 


[Patasss]

Super ! Hat funktioniert Danke.