webcam snapshot

[Flashnism]

hm.. fortgeschritten oder anfänger...!? keine ahnung.
zumindest nicht gaaanz üblich..

kurz und knapp:
kennt jemand den befehl/das vorgehen um einen snapshot mit der wegcam zu schießen? dieser soll dann natürlich auch noch auf der bühne platziert werden.

die webcam ansprechen und so weiter kann ich ohne probleme. müsste eben nur wissen, wie ich den snapshot mache. hat da jemand einen hinweis für mich?
danke

[andrelehnert]

Hier - macht ein snapshot bei Klick aufs Video.
snapshots kann man dann drag´n´droppen.

PHP-Code:

import flash.display.Bitmap;
import flash.display.BitmapData;
//______________________________________________________________Camera
var cam0:Camera = Camera.getCamera("0");
cam0.setMode(640,480,15);
//______________________________________________________________Video
var vid0:Video = new Video();
vid0.attachCamera(cam0);
//______________________________________________________________VideoContainer
var videoCont0=new Sprite();
videoCont0.addChild(vid0);
videoCont0.addEventListener(MouseEvent.CLICK,videoClickHandler)
addChild(videoCont0);
//______________________________________________________________videoClickHandler
function videoClickHandler(e:MouseEvent){    
    makeSnapShot(e.target)
};    
//______________________________________________________________snapShot
function makeSnapShot(src){
    var myBitmapData:BitmapData = new BitmapData(src.width, src.height);
    var bmp:Bitmap = new Bitmap(myBitmapData);
    myBitmapData.draw(src);
    var spr=new Sprite();
    spr.addChild(bmp);
    addChild(spr);
    spr.x=src.width;    
    spr.addEventListener(MouseEvent.MOUSE_DOWN,bmpDragStart);
    spr.addEventListener(MouseEvent.MOUSE_UP,bmpDragStop);        
};
//______________________________________________________________dragFunctions
function bmpDragStart(e){
    e.target.startDrag();
};
function bmpDragStop(e){
    e.target.stopDrag();
}; 


LG ANdré

[Flashnism]

hey danke.
hab es jetzt hinbekommen, dass der snapshot gemacht und platziert wird.

um einen effekt der zeitversetzung zu erzeugen wollte ich nun bei jedem enterFrame einen snapshot machen und den von 10 snapshot vorher aber in genau diesem moment anzeigen lassen (soweit klar?).

das klappt auch. allerding bekomme ich ab ca snapshot nr 700 folgende fehlermeldung:
ArgumentError: Error #2015: Ungültiges BitmapData.
at flash.display::BitmapData()
at Lochkamera4_fla::MainTimeline/takephoto()

vorneweg funktionierts ja aber noch.

hast du vielleicht oder irgendjemand eine idee, warum die BitmapData auf einmal ungültig sein soll? hat doch bis 700 auch geklappt.

kann flash nicht mehr als 700 Bitmaps aufnehmen?

PHP-Code:


stage.addEventListener(Event.ENTER_FRAME, takephoto); 

function takephoto(e:Event):void { 
 
i++;
trace(i) // bei 703 kommt der fehler

this['screenS'+i] = new BitmapData(video.width, video.height); 
this['screenS_image'+i] = new Bitmap(this['screenS'+i]);
this['screenS'+i].draw(video) ;
addChild(this['screenS_image'+(i-10)]) ;

removeChild(this['screenS_image'+(i-(11))]);





} 


[Flashnism]

ok... wenn ich die auflösung von snapshot deutlich runterdrehe schafft er viel mehr. muss also wirklich am freigebenen speicher o.Ä. liegen...
hm... kann man das irgendwie noch weiter künstlich hochschrauben oder die sache ganz umgehen?

[andrelehnert]

Du kannst den Speicher der bereits aus der Displaylist entfernten Bitmaps wieder freigeben mit:

PHP-Code:

deinBMP.dispose(); 


Wenn Du es nämlich nur von der Stage removest, bleibt das BMP ansich ja trotzdem erhalten.
Alternativ könntest Du auch so arbeiten, das 11.BMP wieder zu überschreiben

LG ANdré

[shin10]

hi,

wozu erstellst du denn auch immer ein neues bitmap? du brauchst doch nur das bitmapdata neu zeichnen lassen. z. b. so

PHP-Code:

import flash.display.Bitmap;
import flash.display.BitmapData;

var cache:Array = new Array();
const DELAY:uint = 10;
for(var bild:uint = 0; bild < DELAY-1; bild++){
    cache.push(new BitmapData(video.width,video.height));
}
var bmp:Bitmap = new Bitmap(new BitmapData(video.width,video.height));
addChild(bmp);

stage.addEventListener(Event.ENTER_FRAME, takephoto);

var i:uint = 0;
function takephoto(e:Event):void
{
    i++;
    trace(i);
    cache.push(bmp.bitmapData);//bild in den cacheArray schieben
    bmp.bitmapData = cache.shift();//erstes bild aus dem cache holen
    cache[cache.length-1].draw(video);//letztes bild im cache aktualisieren
} 


ich hoffe mal, das löst dein problem

mfg

sx

edit://ah ja, war ich wieder zu langsam

[Flashnism]

dispose();
scheint 1a zu funktionieren. super! 'kannt ich noch nicht.
danke vielmals!

[Flashnism]

@shin:

deine variante funktioniert allerdings auch tatellos.
wer die ewahl hat hat die qual.

aber dann werd ichs jetzt tatsächlich wohl so umbauen, dass ich mit dem array arbeite. ist dann auch sauberer. danke, danke, danke.