Im Pattern-Raster bestimme Muster einfärben

[tenada]

Hallo zusammen,

ich lassen mir mit einer For-Schleife ein Patternraster erstellen (jedes Pattern ist dabei ein eigenes Sprite).
Jetzt sollen eine variable Anzahl von Pattern eingefärbt werden, aber nicht von oben links nach rechts, Zeile für Zeile, sondern von der Mitte aus.

Wie gehe ich das am besten an? Beim erstellen der Pattern sollte ich mir wahrscheinlich zu jedem Element schon einmal die "Spalte" und "Zeile" merken, vermute ich mal...

Und richtig schwierig wirds dann wahrscheinlich, wenn ich die Optik noch etwas "zufällig" aussehen lassen möchte (siehe Anhang ...random.jpg)


Habt ihr da eine Idee?


Beste Grüße
tenada

[tenada]

och keiner eine Idee...

[thomas_E]

habs mal auf die Schnelle mit Graphics gebaut, das sollte ein mögliches Prinzip verdeutlichen

const DEFAULT_COLOR:uint = 0x0080FF;
const HIGHLIGHT_COLOR:uint = 0xFF8000;
var tiles:Array;
 
//init
createTiles(9, 7);
 
//alle zwei Sekunden, highlightTiles(13, 1.5) ausführen
setInterval(highlightTiles, 2000, 13, 1.5);
 
 
 
function createTiles(cols:uint, rows:uint):void
{
    var center:Point = new Point((cols-1)*.5, (rows-1)*.5);
    tiles = [];
    
    //current Position
    var cp:Point = new Point(0,0);
    
    for(cp.y=0; cp.y<rows; ++cp.y){
        
        for(cp.x=0; cp.x<cols; ++cp.x){
            
            tiles.push({
                x: cp.x*52+20,
                y: cp.y*52+20,
                w: 50,
                h: 50,
                d: Point.distance(center, cp),
                v: 0
            });
        }
    }
    highlightTiles(0);
}
 
function highlightTiles(numColoredTiles:uint=0, randomize:Number=0):void
{
    var g:Graphics = this.graphics;
    var tile:Object;
    //"Zufall" hinzufügen
    for each(tile in tiles){
        tile.v = tile.d - (randomize? Math.random()*randomize: 0);
//    tile.v = tile.d*tile.d - (randomize? Math.random()*randomize: 0);
    }
    tiles.sortOn('v', Array.NUMERIC);
    
    g.clear();
    for(var i:uint = tiles.length; i--; ){
        tile = tiles[i];
        var col:uint = i<numColoredTiles? HIGHLIGHT_COLOR: DEFAULT_COLOR;
    
        g.beginFill(col);
        g.drawRect(tile.x, tile.y, tile.w, tile.h);
        g.endFill();
    }
} 

[tenada]

du bist ein Tier!! Wahnsinn, dankeschön! ...das versuch ich jetzt mal bei mir einzubauen