MC als Button, Listener Problem

[deejayy]

Hallo Leute,

ich versuche mich momentan auf AS3.0 umzustellen und habe gerade ein dummes Problem.

Ich habe einen MC mit einem Tweening innen von Frame 19 - 33.
Ich möchte nun diesen MC als "Button" nutzen und einen Mouseover und MouseOut Effekt erzeugen.

Früher in AS2 wars kein Problem.
Wenn ich aber das Ganze auf AS3 versuche umzuschreiben, funktioniert es nur teilweise.

Hier mal mein Code:

btStart.addEventListener(MouseEvent.MOUSE_OVER, startEffekt, false, 0, true);
btStart.addEventListener(MouseEvent.MOUSE_OUT, startEffektout, false, 0, true);
 
function startEffekt(evt:MouseEvent):void {
    btStart.addEventListener(Event.ENTER_FRAME, nextFrameFunction, false, 0, true);
}
function nextFrameFunction(evt:Event):void {
    btStart.nextFrame();
    if(btStart.currentFrame == btStart.totalFrames) {
        btStart.removeEventListener(Event.ENTER_FRAME, nextFrameFunction);
    }
}
 
function startEffektout(evt:MouseEvent):void {
    btStart.addEventListener(Event.ENTER_FRAME, prevFrameFunction, false, 0, true);
}
function prevFrameFunction(evt:Event):void {
    btStart.prevFrame();
    if(btStart.currentFrame == 19) {
        btStart.removeEventListener(Event.ENTER_FRAME, prevFrameFunction);
    }
} 

Das Ganze funktioniert auch, wenn man das gesamte Tweening abwartet. Wenn man aber die Mouse vor Bild 33 wieder wegfährt, macht das Skript seltsame sachen.

Was ist an meinem COde falsch???

Grüße dj

[mildesign]

eine Funktion innerhalb einer Funktion zu deklarieren ist kein guter Stil. Entzerre das mal.

[deejayy]

okay, ich hab die funktionen nun "entwirrt".
Problem ist aber weiterhin das selbe.

Es funktioniert, wenn die Animation im MC komplett abgespielt wird.
Sobald man aber früher (druch ein MouseOut Event) unterbricht, bleibt der Button stehen und läuft nicht wieder zurück.

[deejayy]

zur Einfachheit habe ich nun den Button vereinfacht und er hat nur noch eine Animation von Frame 1 bis 10 (also keine Animation vorher).

Das Script ist somit allgemeiner geworden. Das Problem ist aber immer noch das gleiche.

****EDIT****

ICh habe das Problem gelöst. nun das Script, welches funktioniert!

btStartButton.addEventListener(MouseEvent.MOUSE_OVER, startEffekt, false, 0, true);
btStartButton.addEventListener(MouseEvent.MOUSE_OUT, startEffektout, false, 0, true);
btStartButton.addEventListener(MouseEvent.CLICK, startClick, false, 0, true);
 
function startEffekt(evt:MouseEvent):void {
    btStartButton.removeEventListener(Event.ENTER_FRAME, prevFrameFunction);
    btStartButton.addEventListener(Event.ENTER_FRAME, nextFrameFunction, false, 0, true);
}
function nextFrameFunction(evt:Event):void {
    btStartButton.nextFrame();
    if(btStartButton.currentFrame == btStartButton.totalFrames) {
        btStartButton.removeEventListener(Event.ENTER_FRAME, nextFrameFunction);
    }
}
 
function startEffektout(evt:MouseEvent):void {
    btStartButton.removeEventListener(Event.ENTER_FRAME, nextFrameFunction);
    btStartButton.addEventListener(Event.ENTER_FRAME, prevFrameFunction, false, 0, true);
}
function prevFrameFunction(evt:Event):void {
    btStartButton.prevFrame();
    if(btStartButton.currentFrame == 1) {
        btStartButton.removeEventListener(Event.ENTER_FRAME, prevFrameFunction);
    }
}
 
function startClick(evt:Event):void {
    /*Anweisung für was bei Mausklick*/
}