z-achsen rotation eines mc (sinus)

[deejayy]

So, ich zerbrech mir seit mehreren Stunden den Kopf wegen folgendem Effekt:

ich möchte eine "stehende Welle" über AS programmieren.
Eine "stehende Welle" ist eine Sinuskurve, die sich im Prinzip um die z-Achse dreht (so ungefähr kann man den visuellen Effekt beschreiben).

nun habe ich über AS eine Sinuskurve erstellt:

var xWert :Number = 0;
var yWert :Number = 0;
var pi = Math.PI;
var amp :Number = -49;

function sinus(amplitude) {
	for (i=0; i<=720; i++) {
	xWert = i * 2.68
	yWert = 100 +(amplitude * (Math.sin(pi*2/360*i)));
	sinus_mc.lineTo(xWert, yWert);
	}
}
		
this.createEmptyMovieClip("sinus_mc", 1);
sinus_mc.lineStyle(2, 0xFF00FF, 100);
sinus_mc.moveTo(0, 100);

sinus (amp);

Die Sinuskurve wird auch ausgegeben einwandfrei :-)

Nun meine Frage: hat jemand einen Ansatz, wie ich den MC mit der Sinuskurve "um die z-Achse rotieren" kann?
Die Rotationsbewegung könnte man wieder über den Sinus berechnen.

Aber wie kann ich die Pixel eines MC´s ansteuern und ihnen sagen, wo hin sie sich bewegen sollen.

Jemand eine Idee?

[hgseib]

http://www.seibsprogrammladen.de/fra...ispiele/flash6
-> Zeichnen
... Sinuswelle

[deejayy]

danke seib

habs aber doch noch selbst hinbekommen mit der stehenden Welle

hier mal mein Script : (für verbesserungsvorschläge an dem Script bin ich gerne dankbar... )

function sinus(amplitude, deph, nr) {
    var xWert :Number = 0;
    var yWert :Number = 0;
    var pi = Math.PI;
    this.createEmptyMovieClip("sinus_mc" + nr, deph);
    this["sinus_mc"+nr].lineStyle(2, 0xFF00FF, 100);
    this["sinus_mc"+nr].moveTo(0, 100);
    for (i=0; i<=720; i++) {
        xWert = i * 2.68
        yWert = 100 +(amplitude * (Math.sin(pi*2/360*i)));
        this["sinus_mc"+nr].lineTo(xWert, yWert);
    }
}
 
var countersinus :Number = 1;
var counteramp :Number = -50;
sinus (counteramp, 1, countersinus);
//sinus_mc1.removeMovieClip();
 
var amparray = new Array();
for (i=0 ; i<= 20; i++) {
    amparray[i] = -50 + 5*i;
}
var z :Number = 0;
var test :Boolean = true;
this.onEnterFrame = function() {
    this["sinus_mc"+countersinus].removeMovieClip();
    countersinus = countersinus + 1;
    counteramp = amparray[z];
    if (test == true) {
        z = z +1;
    }
    if (test == false) {
        z = z -1;
    }
    if (z == 20) {
        test = false;
    }
    if (z == 0) {
        test = true;
    }
            
    sinus (counteramp, 1, countersinus)
} 

[deejayy]

nochmals eine Verbesserung in meinem Script.

Jetzt "dreht" sich welle richtig um die x_Achse in z-Richtung :-)

//Sinuskurve Funktion
function sinus(amplitude, deph, nr) {
    var xWert :Number = 0;
    var yWert :Number = 0;
    var pi = Math.PI;
    this.createEmptyMovieClip("sinus_mc" + nr, deph);
    this["sinus_mc"+nr].lineStyle(2, 0xFF00FF, 100);
    this["sinus_mc"+nr].moveTo(0, 100);
    for (i=0; i<=720; i++) {
        xWert = i * 2.68
        yWert = 100 +(amplitude * (Math.sin(pi*2/360*i)));
        this["sinus_mc"+nr].lineTo(xWert, yWert);
    }
}
 
//Ampliutenberechnung für fiktive Drehung um Z-Achse:
var PI = Math.PI;
var bogen :Number = 1*PI/60; 
var gesamtbogen :Number = 1*PI;
var amparray = new Array();
for (i=0 ; i<= 60; i++) {
    amparray[i] = -50 * Math.sin(gesamtbogen + i*bogen)
}
for (j=0 ; j<= 60; j++) {
    amparray[j+61] = 50 * Math.sin(gesamtbogen + j*bogen)
}
 
//Grafische Darstellung
var countersinus :Number = 1;
var counteramp :Number = -50;
sinus (counteramp, 1, countersinus);
 
var z :Number = 0;
var test :Boolean = true;
this.onEnterFrame = function() {
    this["sinus_mc"+countersinus].removeMovieClip();
    countersinus = countersinus + 1;
    counteramp = amparray[z];
    if (test == true) {
        z = z +1;
    }
    if (test == false) {
        z = 0;
    }
    if (z == 120) {
        test = false;
    }
    if (z == 0) {
        test = true;
    }
            
    sinus (counteramp, 1, countersinus)
} 

[deejayy]

also mein wissen ist nun erschöpft

Die Welle funktioniert zwar einwandfrei, aber die Rechenleistung ist einfach zu derb (ab 3 Wellen geht mein Rechner in die Knie...)

folgende ähnliche Wellenanimation möchte ich erstellen:
http://www.flashintro.de/templates2.html?flash_intro
(4te Reite mitte -> aufs image klicken und dann das preview anschauen)

mit meiner Variante habe ich einfach viel zu viele Rechenoperationen.
30 Funktionsaufrufe pro Sekunde / pro Funktion 1x Movieclip erstllen / alten löschen / 720 sinus-berechnungen + if-abfragen
macht circa 22000 Operationen pro Sekunde pro Welle...

das ist einfach nicht wirklich gut programmiert. Hat jemand eine Idee, wie ich das noch lösen könnte???

[hgseib]

Zitat von deejayy

aber die Rechenleistung ist einfach zu derb (ab 3 Wellen geht mein Rechner in die Knie...)

- nicht jeden punkt berechnen! anstatt
for (i=0; i<=720; i++) { <== 720 linien
for (i=0; i<=720; i+=10) { <== 72 linien
langt. da ist kaum ein qualitätsunterschied zu erkennen; aber 90% gespahrt!

- nicht jedesmal ein neues mc erzeugen, sondern die grafik mit clear löschen und neu zeichnen.

- zwei wellen lang zeichnen und dann nur noch das mc hin- und her bewegen; anstatt das immer wieder neu zu berechnen.

[deejayy]

Also habe das Script nun umgeändert auf jeden 10ten Punkt und mit Clear.
Du hast Recht, man sieht Qualitativ keinen Unterschied und wirklich 90% Einsparung rechnerisch...

Auf die Idee bin ich nicht gekommen

Hier mein geändertes Script:

//Sinuskurve Funktion
function sinus(amplitude) {
    var xWert :Number = 0;
    var yWert :Number = 0;
    var pi = Math.PI;
    this.sinus_mc.lineStyle(2, 0xCCCCCC, 100);
    this.sinus_mc.moveTo(0, 100);
    for (i=0; i<=720; i+=10) {
        xWert = i * 2.68
        yWert = 100 +(amplitude * (Math.sin(pi*2/360*i)));
        this.sinus_mc.lineTo(xWert, yWert);
    }
}
 
//Ampliutenberechnung für fiktive Drehung um Z-Achse:
var amp :Number = 50;
 
var PI = Math.PI;
var bogen :Number = 1*PI/60; 
var gesamtbogen :Number = 1*PI;
var amparray = new Array();
for (i=0 ; i<= 60; i++) {
    amparray[i] = -1* amp * Math.sin(gesamtbogen + i*bogen)
}
for (j=0 ; j<= 60; j++) {
    amparray[j+61] = amp * Math.sin(gesamtbogen + j*bogen)
}
 
//Grafische Darstellung
var counteramp :Number = -1 * amp;
 
this.createEmptyMovieClip("sinus_mc", 1);
 
sinus (counteramp);
 
var z :Number = 0;
var test :Boolean = true;
this.onEnterFrame = function() {
    this.sinus_mc.clear();
    counteramp = amparray[z];
    if (test == true) {
        z = z +1;
    }
    if (test == false) {
        z = 0;
    }
    if (z == 120) {
        test = false;
    }
    if (z == 0) {
        test = true;
    }
            
    sinus (counteramp)
} 

- zwei wellen lang zeichnen und dann nur noch das mc hin- und her bewegen; anstatt das immer wieder neu zu berechnen.

Das habe ich nicht so ganz verstanden, was du damit meinst.
Ich zeichne die Kurve ja 2 Wellen lang mit 720 (1 Welle =360); Danach stopfe ich den MC in einen neuen MC und tweene den.
Aber was meinst du damit, dass nicht immer wieder neu zu berechnen?

[hgseib]

Zitat von deejayy

was meinst du damit, dass nicht immer wieder neu zu berechnen?

die welle wellt ;-)
zeichne die welle einmal doppelt so lange (das was du jetzt hast nochmal hinten drann hängen) und dann das mc nur noch in x-richtung bewegen. das wellt genauso.
wenn du das mc um eine ganze welle weit geschoben hast, dann um die komplette welle zurück und wieder langsam vorschieben.

[deejayy]

ja, das ist mir klar

mach ich ja momentan eigentlich auch schon da ich die welle für 1900 Pixel länge berechne (2 Wellen) und nur 950 Pixel breite habe... somit kann ichs verschieben und die welle wellt

Aber ich verändere ja neben der Bewegung in x-Richtung (durch den Tween) auch nocht die Amplitude entsprechend, um eine "optische" Drehung um die x-Achse in Z-Richtung zu erzeugen.
Und diese "Drehung" wird ja durch das Script erzeugt (jeweils neu zeichen). Somit muss ich ja gezwungenermaßen bei jedem Frame die Welle neu zeichnen lassen.

Alternativ könnte ich einmal 120 MC´S erzeugen (je ein Wellenzustand) und diese MC´s pro Frame der reihe nach auf visible schalten (die anderen alle unsichtbar), dann hätte ich das selbe ergebniss... aber ich glaube nicht, dass das recht sinnvoll wäre