Verzögerung beim Aufbau

[vince1969]

Hallo Leute,

grrr, will eigentlich mal wieder was ganz banales machen.

eine fläche mit mc´s nacheinander bestücken (jeder bekommt dann nen namen). auf einer fläche von 800 x 200.

11 mc´s inna reihe, 4 reihen = 44 Stück. Geht super ... habe dafür diese einfache for-schleife benutzt ...

bposx = 4;
bposy = 4;
anzahl = 0;
for (var i:Number = 1; i<=4; i++) {
	for (var ii:Number = 1; ii<=11; ii++) {
		anzahl += 1;
                this.attachMovie("maske", "maske", anzahl, {_x:bposx, _y:bposy});		
		bposx += 72;
		maske._width = 72;
		maske._height = 48;
	}
	bposx = 4;
	bposy += 48;
}

funktiniert auch so wie ichs brauche.

FRAGE: Jetzt möchte ich gerne das er die MC´s nacheinander (zeile für Zeile) in unterschiedlicher geschwindigkeit aufbaut. Erst mit einer leichten Verzögerung und dann GANZ Schnell ... später wollte ich da noch nen effekt reinbauen. da weiss ich aber wieder weiter ...

habe versucht das mit Set Interval zu machen ...

mittendrin so ähnlich:

var v = setInterval(function () {
clearInterval(v);
		this.attachMovie("maske", "maske", anzahl, {_x:bposx, _y:bposy});
}, t);

... aber klappte nicht so richtig. aaargggh.

über nen wink mit dem zaunpfahl würde ich mich freuen ...

gruß vince

[b.asile]

Weiss jetzt nicht genau wie du das mit dem Aubauen meintest, aber wenns animiert sein sollte, dann rate ich dir zum FuseKit.

[vince1969]

hi b.asile,

aufbauen:

zeile für zeile ... ein mc nach dem anderen ... von links nach rechts ... wenn die zeile voll ist .. wieder die nächste ...

wenn ich die for schleife ... anschalte ... macht es "pling" und es kommt einen so vor als wenn alle mc´s auf einmal da sind. --- weil die for schleife so schnell ist ...


ich will es aber dass sie optisch nacheinander angezeigt werden .. so das man den aufbau beobachten kann ...


hoffe ich habe es etwas verständlicher beschrieben ...


beste grüße andreas

[mychiara]

hi,

also ich würds so machen:

ein array erstellen, in einer for-schleife die koordinaten der flächen ins array rein pushen und wenn die for schleife fertig ist ein interval aufrufen welches die flächen dann zeitversetzt tweent.

also so:

PHP-Code:

import com.mosesSupposes.fuse.*;
ZigoEngine.register (FuseItem, PennerEasing);

var koords_arr:Array = [];  // hier werden die koordinaten abgelegt und der dazugehörige mc abglegt [box, x, y];
var count:Number = 0;  // counter fürs interval
var move_SID:Number; // id des intervals;
var time:Number = 200; // 200 milisekunden

function init () :Void {
    
    var box:MovieClip;  // referenz für den entsprechenden mc
    
    var anz:Number = 40;  // anzahl der boxen
    var ier:Number = 10;  // anzahl der boxen in einer reihe
    
    for (var i:Number = 0; i < anz; i++) {
       box = this.attachMovie ("deinMc", "flaeche" + i, i);
       box._x = 0;
       box._y = Stage.height;
              
       koords_arr[i] = [];
       
       koords_arr[i].push ( box );
       koords_arr[i].push ( (i % ier) * (box._width)  );
       koords_arr[i].push ( Math.floor (i / ier) * (box._height) );
    }
    
    move_SID = setInterval (moveTheBox, time)
    
}
   
function moveTheBox () :Void {
    
    ZigoEngine.doTween ({target: koords_arr[count][0], x: koords_arr[count][1], y: koords_arr[count][2], time: .5, ease:"easeOutBack"});
    count++;
    
    
    if (count >= koords_arr.length) {
        clearInterval (move_SID);
        // do Something else
    }
    
}

init ();