AS Tween löschen

[Blax_ed]

Hi,

Script funktioniert soweit tadellos. Wenn ich mit der Maus allerdings "Schnell" über den MC fahre - und er somit dass onRollOut-Event startet wenn das onRollOver-Event noch nicht fertig gelaufen ist - poppt der Button später wieder auf..

PHP-Code:

import mx.transitions.Tween;
import mx.transitions.easing.*;
function wabber(target:MovieClip, xscale:Number, yscale:Number, duration:Number, seconds:Boolean, callback:Function):Void {
    var tweenX:mx.transitions.Tween = new mx.transitions.Tween(target, "_xscale", mx.transitions.easing.Elastic.easeOut, target._xscale, xscale, duration, seconds);
    var tweenY:mx.transitions.Tween = new mx.transitions.Tween(target, "_yscale", mx.transitions.easing.Elastic.easeOut, target._yscale, yscale, duration, seconds);
    tweenX.onMotionFinished = function():Void  {
        callback();
    };
}
mc.onRollOver = function() {
    delete tweenX;
    delete tweenY;
    wabber(this, 150, 150, 1.5, true);
};
mc.onRollOut = function() {
    delete tweenX;
    delete tweenY;
    wabber(this, 100, 100, .5, true);
}; 


Wie kann ich denn die Bewegung löschen ?

[SpecOps-12]

PHP-Code:

import mx.transitions.Tween;
import mx.transitions.easing.*;


function wabber(target:MovieClip, xscale:Number, yscale:Number, duration:Number, seconds:Boolean, callback:Function):Void {
    if (tweenX) {
        tweenX.stop();
    }
    if (tweenY) {
        tweenY.stop();
    }
    var tweenX:Tween = new Tween(target, "_xscale", Elastic.easeOut, target._xscale, xscale, duration, seconds);
    var tweenY:Tween = new Tween(target, "_yscale", Elastic.easeOut, target._yscale, yscale, duration, seconds);
    tweenX.onMotionFinished = function():Void  {
        callback();
    };
} 


Sollte gehn.
Wenn du die Tween-Klassen importierst, musst du ihre Pfade nicht jedes Mal nochmal vollständig angeben. Macht es etwas übersichtlicher (Außer, du arbeitest mit verschiedenen Tween-Klassen).

[Blax_ed]

Zitat von Weidler

Sollte gehn.
Wenn du die Tween-Klassen importierst, musst du ihre Pfade nicht jedes Mal nochmal vollständig angeben. Macht es etwas übersichtlicher (Außer, du arbeitest mit verschiedenen Tween-Klassen).

Er schon Weidler

mit dem mehrfachen importen haste recht..

gehen tuts leider trotzdem net.. habe auch mal versucht die tweenvariable zu löschen.. macht er auch nicht..

hier mal nen minibeispiel.. mit deinem script
wie gesagt einfach mal schnell über den button fahren...dann siehste was ich meine.

[SpecOps-12]

Ähh, ich hatte da auch grad nen Denkfehler. Moment.

PHP-Code:

import mx.transitions.Tween;
import mx.transitions.easing.*;

var tweenX:Tween;
var tweenY:Tween;

function wabber(target:MovieClip, xscale:Number, yscale:Number, duration:Number, seconds:Boolean, callback:Function):Void {
    if (tweenX) {
        tweenX.stop();
    }
    if (tweenY) {
        tweenY.stop();
    }
    tweenX = new mx.transitions.Tween(target, "_xscale", Elastic.easeOut, target._xscale, xscale, duration, seconds);
    tweenY = new mx.transitions.Tween(target, "_yscale", Elastic.easeOut, target._yscale, yscale, duration, seconds);
    tweenX.onMotionFinished = function():Void  {
        callback();
    };
} 


Und die Variablen löschen bringt nix. Das sind nur Referenzen, keine Instanzen.

[Blax_ed]

Willste bei mir anfangen?

In der schönen Schweiz^^

Danke Dir mal wieder

[Blax_ed]

hmm

nur mal ne verständnisfrage:

PHP-Code:

import mx.transitions.Tween;
import mx.transitions.easing.*;

var tweenX:Tween;
var tweenY:Tween;

function wabber(target:MovieClip, xscale:Number, yscale:Number, duration:Number, seconds:Boolean, callback:Function):Void {
    if (tweenX) {
        tweenX.stop();
    }
    if (tweenY) {
        tweenY.stop();
    }
    tweenX = new mx.transitions.Tween(target, "_xscale", Elastic.easeOut, target._xscale, xscale, duration, seconds);
    tweenY = new mx.transitions.Tween(target, "_yscale", Elastic.easeOut, target._yscale, yscale, duration, seconds);
    tweenX.onMotionFinished = function():Void  {
        callback();
    };
}
mc.onRollOver = function() {
    wabber(this, 150, 150, 1.5, true);
};
mc.onRollOut = function() {
    wabber(this, 100, 100, 1, true);
};
mc2.onRollOver = function() {
    wabber(this, 150, 150, 1.5, true);
};
mc2.onRollOut = function() {
    wabber(this, 100, 100, 1, true);
};
mc3.onRollOver = function() {
    wabber(this, 150, 150, 1.5, true);
};
mc3.onRollOut = function() {
    wabber(this, 100, 100, 1, true);
};
mc4.onRollOver = function() {
    wabber(this, 150, 150, 1.5, true);
};
mc4.onRollOut = function() {
    wabber(this, 100, 100, 1, true);
};
mc5.onRollOver = function() {
    wabber(this, 150, 150, 1.5, true);
};
mc5.onRollOut = function() {
    wabber(this, 100, 100, 1, true);
}; 


wenn ich das gleiche auf mehrere mc anwenden will .. funzt das nicht.. weil ich ja sozusagen nur "ein" tweenobjekt habe.. richtig ?

was muss ich machen um mehrere gleichzeitg zum laufen zu bringen

[SpecOps-12]

Tja, da ist guter Rat teuer.

Mir fallen drei Sachen ein:
Für jeden Button eigene Referenz-Variablen erstellen und die in den Parametern mitreichen, was natürlich furchtbar ist.

Eine Klasse für deine Buttons erstellen, so dass jeder Buttons als Klassen-Instanz angelegt wird (Dann hat jeder Button von vornherein seine eigenen Variablen).

Ne Tween-Klasse benutzen, die für komplexe Tweens besser geeignet ist (Tweener, Fuse).

PS: Übrigens hab ich festgestellt, dass meine if-Abfrage unsinn ist. Wenn, müsste es if (tweenX.isPlaying) heißen.

PPS: So gehts auch. Ich finds aber ebenfalls unschön:

PHP-Code:

import mx.transitions.Tween;
import mx.transitions.easing.*;
var home:MovieClip = this;

function wabber(target:MovieClip, xscale:Number, yscale:Number, duration:Number, seconds:Boolean, callback:Function):Void {
    if (target.tweenX.isPlaying) {
        target.tweenX.stop();
    }
    if (target.tweenY.isPlaying) {
        target.tweenY.stop();
    }
    target.tweenX = new mx.transitions.Tween(target, "_xscale", Elastic.easeOut, target._xscale, xscale, duration, seconds);
    target.tweenY = new mx.transitions.Tween(target, "_yscale", Elastic.easeOut, target._yscale, yscale, duration, seconds);
    target.tweenX.onMotionFinished = function():Void  {
        callback();
    };
}
mc1.onRollOver = function() {
    wabber(this,150,150,1.5,true);
};
mc1.onRollOut = function() {
    wabber(this,100,100,1,true);
};
mc2.onRollOver = function() {
    wabber(this,150,150,1.5,true);
};
mc2.onRollOut = function() {
    wabber(this,100,100,1,true);
}; 


[Blax_ed]

Zitat von Weidler

Eine Klasse für deine Buttons erstellen, so dass jeder Buttons als Klassen-Instanz angelegt wird (Dann hat jeder Button von vornherein seine eigenen Variablen).

Jaaaaaah genau... Ich als Designer..

nagut.. sowas dachte ich mir schon fast.. ich glaube ich mache es dann der Zeit wegen auf de unschöne Art...

Danke Dir vielmals!

[pacman.hgw]

Huhu ich muss mich da mal kurz miteinklinken weil das so ähnlich aussieht wie das was ich da gerade mache. Ich habe da nur eine kleine Frage:

Wo kommt denn das "isPlaying" her?

[SpecOps-12]

Das kommt aus der Instanz der Twenn-Klasse und kann über deren Referenz-Variable abgerufen werden.
Aber nur über die.
Ne statische Funktion, die man befragen kann, ob gerade "irgendwas" tweent, gibts meiner Meinung nach in der flash-Tweenklasse nicht.