Tween-Klasse in for-Schleife

[Tjark]

Hallo

ich habe ein kleines Problem mit einer for-Schleife.
Ich habe mehrere MC´s die ich mit der Tween Klasse Unendlich Bewegen lasse. Das klappt auch alles, nur leider bekomme ich es nicht hin das in for-Schleife zu bauen. Und jeden MC wollte ich nicht Manuel ansprechen, so wie es im Beispiel ist.

var stripeTween0:Tween = new Tween(stripe_mc.f0, "_x", mx.transitions.easing.None.easeNone, stripe_mc.f0._x, Stage.width, randomRange(2, 15), true);
stripeTween0.onMotionFinished = function() {
	stripeTween0.yoyo();
};
var stripeTween1:Tween = new Tween(stripe_mc.f1, "_x", mx.transitions.easing.None.easeNone, stripe_mc.f1._x, Stage.width, randomRange(2, 15), true);
stripeTween1.onMotionFinished = function() {
	stripeTween1.yoyo();
};
var stripeTween2:Tween = new Tween(stripe_mc.f2, "_x", mx.transitions.easing.None.easeNone, stripe_mc.f2._x, Stage.width, randomRange(2, 15), true);
stripeTween2.onMotionFinished = function() {
	stripeTween2.yoyo();
};
...

Versucht habe ich es bis jetzt so...
Nur komme ich leider nicht weiter

for(var i:Number=0; i<9; i++){
	var _level0["stripeTween"+i]:Tween = new Tween(stripe_mc.f[i], "_x", mx.transitions.easing.None.easeNone, 0, Stage.width, randomRange(2, 15), true);
	_level0["stripeTween"+i].onMotionFinished = function() {
		_level0["stripeTween"+i].yoyo();
	};
}

Vielen Dank...

[gaspode]

Vielleicht so?

PHP-Code:

_level0["stripeTween"+i].onMotionFinished = function() {
    this.yoyo();
}; 


gruß, gaspode

[Orbiter]

Doch besser so:

PHP-Code:

for( var i:Number=0; i<9; i++ )
{
    var tw:Tween = new Tween( stripe_mc["f"+i], "_x", mx.transitions.easing.None.easeNone, 0, Stage.width, randomRange(2, 15), true );
    tw.onMotionFinished = function() 
    {
        this.yoyo();
    };
} 


[Tjark]

Danke euch beiden

Super Hilfe...

Gruß,
Tjark

[Tjark]

Zitat von Orbiter

Doch besser so:

PHP-Code:

for( var i:Number=0; i<9; i++ )
{
    var tw:Tween = new Tween( stripe_mc["f"+i], "_x", mx.transitions.easing.None.easeNone, 0, Stage.width, randomRange(2, 15), true );
    tw.onMotionFinished = function() 
    {
        this.yoyo();
    };
} 


Jetzt habe ich doch noch eine Sache die ich nicht hin bekomme
Die MC´s sollen beim ersten durchlauf an einer Zufälligen Position der X-Achse Starten. Nach "onMotionFinished" sollen diese MC´s dann kommplet von 0 bis Stage.width immer durchlaufen.

Vielen Dank noch mal,
Tjark

[Orbiter]

Falls Du es noch nicht selber herausgefunden hast:

PHP-Code:

for( var i:Number=0; i<9; i++ )
{
    var tw:Tween = new Tween( stripe_mc["f"+i], "_x", mx.transitions.easing.None.easeNone, 0+Math.random()*(Stage.width-stripe_mc["f"+i]._width), Stage.width, randomRange(2, 15), true );
    tw.onMotionFinished = function() 
    {
        delete this;
        var tw:Tween = new Tween( stripe_mc["f"+i], "_x", mx.transitions.easing.None.easeNone, 0, Stage.width, randomRange(2, 15), true );
        tw.onMotionFinished = function()
        {
            this.yoyo();
        };
    };
} 


Schönen Tag!

[Tjark]

Hallo Orbiter,

so hatte ich es auch Probiert.
Allerdings laufen die MC´s dann nach dem ersten "onMotionFinished" nicht mehr korrekt weiter. Sie Springen dann Direkt auf die Linke (0px) Seite ohen einen Tween gemacht zu haben.
Dachte auch schon das das Problem der "begin" und "finish" Punkt ist. Da er ja schon einen weg gelaufen ist, muss er ja bei "Stage.width" anfangen und zu 0 laufen. Das geht leider aber auch nicht.

Zur besseren Übersicht Poste ich mal das ganze Script.

PHP-Code:

import mx.transitions.Tween;
import mx.transitions.easing.*;

function drawQuadrat(_mc, breite, color) {
    var b = breite/2;
    with (_mc) {
        beginFill(color, randomRange(10, 100));
        randomWidth = randomRange(2, 100);
        moveTo(-randomWidth, -b);
        lineTo(-randomWidth, b);
        lineTo(randomWidth, b);
        lineTo(randomWidth, -b);
        endFill();
    }
} // end func drawQuadrat

function stripe(stripe_mc, anzX, anzY, quadratSize, color) {
    var i = 0;
    for (var y = 0; y<anzY; y++) {
        for (var x = 0; x<anzX; x++) {
            var _mc = stripe_mc.createEmptyMovieClip('f'+i, i);
            drawQuadrat(_mc, quadratSize, color);
            _mc._x = randomRange(0, Stage.width);
            _mc._y = (y-anzY/2)*quadratSize;
            _mc.x = x;
            _mc.y = y;
            i++;
        }
    }
} // end func stripe

function randomRange(min, max) {
    var randomNum = Math.floor(Math.random()*(max-min+1))+min;
    return randomNum;
} // end func randomRange

_root.createEmptyMovieClip('stripe_mc', 1);
stripe_mc._x = 0;
stripe_mc._y = 100;
stripe(stripe_mc, 9, 1, 50, 0x0000ff);

for( var i:Number=0; i<9; i++ )
{
    var tw:Tween = new Tween( stripe_mc["f"+i], "_x", mx.transitions.easing.None.easeNone, 0+Math.random()*(Stage.width-stripe_mc["f"+i]._width), Stage.width, randomRange(2, 15), true );
    tw.onMotionFinished = function() 
    {
        delete this;
        var tw:Tween = new Tween( stripe_mc["f"+i], "_x", mx.transitions.easing.None.easeNone, 0, Stage.width, randomRange(2, 15), true );
        tw.onMotionFinished = function()
        {
            this.yoyo();
        };
    };
} 


Vielen Dank,
Tjark

[Orbiter]

Mein Vorschlag ohne Tween Klasse:

PHP-Code:

for( var i:Number=0; i<9; i++ )
{
    var speed = randomRange(2, 15);
    var temp:MovieClip = stripe_mc["f"+i];
    temp._x = Math.random()*( Stage.width - temp._width );
    temp.onEnterFrame = function():Void
    {
        if ( this._x < 0 || this._x > ( Stage.width - this._width ) )
        {
            speed = randomRange(2, 15);
            speed *= -1;
        }
        this._x += speed;
    };
} 


[Tjark]

Hast du das bei dir getestet?
Bei laufen die einfach in eine Richtung von der Bühne?

trotzdem danke schon mal für deine Mühe...

Tjark

[Orbiter]

Habe ich nicht getestet sollte aber funktionieren.
Du kannst mal versuchen:

PHP-Code:

for( var i:Number=0; i<9; i++ )
{
    var temp:MovieClip = stripe_mc["f"+i];
    temp._x = Math.random()*( Stage.width - temp._width );
    temp.speed = randomRange(2, 15);
    temp.onEnterFrame = function():Void
    {
        if ( this._x < 0 || this._x > ( Stage.width - this._width ) )
        {
            this.speed = randomRange(2, 15);
            // Bewegung umgekehren
            this.speed *= -1;
        }
        this._x += this.speed;
    };
} 


[Tjark]

Schon ein mal einen Schritt weiter
Den ersten weg bis Stage.width laufen die Mc`s. Danach laufen Sie leider von der Bühne bei 0px weg.

gruß,
Tjark

[Orbiter]

Das liegt an der Neuzuweisung von speed.
Habe es gerade getestet. Lässt man speed wies ist dann gehts.
Dieser Vorschlag funktioniert:

PHP-Code:

for( var i:Number=0; i<9; i++ )
{
    var temp:MovieClip = stripe_mc["f"+i];
    temp._x = Math.random()*( Stage.width - temp._width );
    temp.speed = randomRange(2, 15);
    temp.onEnterFrame = function():Void
    {
        // das lässt sich bestimmt noch eleganter lösen
        if ( this._x < 10 ) this.speed = randomRange(2, 15);
        if ( this._x < 0 || this._x > ( Stage.width - this._width ) )
        {
            // Bewegung umgekehren
            this.speed *= -1;
        }
        this._x += this.speed;
    };
} 


[Tjark]

Super...

So geht es 100 %.

Vielen Dank,
Tjark