Starker Regen

[Herzenslicht]

Hi Leute,
benötige für eine Animation starken Regen.
Habe keinen Plan, wie ich dieses anstellen könnte.

Hat jemand eine Idee oder ein Beispiel ?

Arbeite mit Flash Pro 8 und (noch) mit As2

[shin10]

Hmm, beim FP8/AS2 musste man ja schon etwas sparen was Effekte angeht. Weiß ja jetzt nicht was da sonst noch kommt, aber ich glaub da würd ich mal ganz oldschool 4 Bilder machen mit ... Strichen? Wie man es in Zeichentrickfilmen auch sieht. Ansonsten gibt es natürlich auch die Möglichkeit das mit Bitmaps zu machen (hab sogar schon Photoshoptuts für sowas gesehen)

Aber wenn du das rein durch code lösen möchtest gib Bescheid. Da hilft dir sicher jemand anders
AS2 mag ich einfach nich mehr.

mfg

sx

[marc]

Anschauungsbeispiele findest du zum Beipiel hier im Forum:

- Regenanmiation mit FLA
- Diskussion zu Regen und Links zu Beispielen

Ansonsten bitte auch einmal nach "Schnee" hie im Forum suchen. Da findest du mehr Skripte als wenn du nach Regen suchst und letztendlich muss du da nur ein paar Parameter ändern und die Grafik ändern und du hast aus Schnee den Regen gemacht

/marc

[andrelehnert]

hi,
hatte grad mal wieder Bock auf AS2...
Schnellschuss:

PHP-Code:

var cont:MovieClip = _root.createEmptyMovieClip("container",0);
var numDrops:Number  = 1000;
var dropSize:Number = 3;
var dropArray:Array=[];
var rainSpeed:Number=5;//Pixel per Frame
var windDir:Number=1; 
var windChangeInterval:Number = 100 //frames
var stageHeight:Number = Stage.height;
var stageWidth:Number = Stage.width;
var frameCount:Number = 0;

function iniDrops(){
    for (var i:Number=0;i<numDrops;i++){
        var drop:MovieClip = cont.createEmptyMovieClip("drop"+i,cont.getNextHighestDepth());
        makeDrop(drop);
        dropArray.push(drop);
    };
};
function makeDrop(drop:MovieClip){
    var pseudoZ:Number = Math.random()*rainSpeed+rainSpeed;
    
    drop.lineStyle(preudoZ+dropSize,0xCCCCCC,Math.random()*100);
    drop.moveTo(0,0);
    drop.lineTo(0,dropSize+pseudoZ);
    drop.speed = pseudoZ * rainSpeed+rainSpeed;
    drop._x = drop._x = -stageWidth+Math.random() * 2*stageWidth;
    drop._y = Math.random() * -stageHeight;        
}
iniDrops();
    
this.onEnterFrame =function(){
    frameCount++;
    if (frameCount>100){
        windDir = -1+Math.random()*2;
        frameCount=0;
        
    };
    for (var i:Number = numDrops-1;i>0;--i){
        var drop:MovieClip = dropArray[i];
        drop._y += drop.speed;
        drop._x += windDir*drop.speed;
        if (drop._y > stageHeight){
            makeDrop(drop);
        };
    };
} 


LG ANdré

[andrelehnert]

Ach is det schön :=)
hier noch mit smoothem Windrichtungswechsel und entsprechender rotation.

PHP-Code:

var cont:MovieClip = _root.createEmptyMovieClip("container",0);
var numDrops:Number  = 2000;
var dropSize:Number = 4;
var dropArray:Array=[];
var rainSpeed:Number=10;//Pixel per Frame
var windDir:Number=1; //-1<windDir<1
var windDirTarget:Number=.5;
var windChangeInterval:Number = 200 //frames
var stageHeight:Number = Stage.height;
var stageWidth:Number = Stage.width;
var frameCount:Number = 0;

function iniDrops(){
    for (var i:Number=0;i<numDrops;i++){
        var drop:MovieClip = cont.createEmptyMovieClip("drop"+i,cont.getNextHighestDepth());
        makeDrop(drop);
        dropArray.push(drop);
    };
};
function makeDrop(drop:MovieClip){
    var pseudoZ:Number = Math.random()*dropSize;
drop.clear();    
drop.beginFill(0xCCCCCC,50);
    var size:Number = dropSize*pseudoZ;
    drop.lineStyle(pseudoZ,0xCCCCCC,Math.random()*100);
    drop.moveTo(0,0);
    drop.lineTo(0,size);
    drop.speed = pseudoZ * rainSpeed+rainSpeed;
    drop._x = -2*stageWidth+Math.random() * 4*stageWidth;
    drop._y = Math.random() * -stageHeight;        
}
iniDrops();
    
this.onEnterFrame =function(){
    frameCount++;
    if (frameCount>windChangeInterval){
        windDirTarget = -1+Math.random()*2;
        frameCount=0;        
    } else {
        windDir += (windDirTarget-windDir)/windChangeInterval
    }
    for (var i:Number = numDrops-1;i>0;--i){
        var drop:MovieClip = dropArray[i];
        drop._y += drop.speed;
        drop._x += windDir*drop.speed;
        drop._rotation = 180-windDir*180/Math.PI
        if (drop._y > stageHeight){
            makeDrop(drop);
        };
    };
} 


LG ANdré