Problem mit OOP Funktionsaufrufinnerhalb einer function

[|Xne.3]

Hallo Leute,

ich habe ein ärgerliches Problem. Und zwar habe ich folgenden Beispielcode:

import mx.utils.Delegate;
import mx.transitions.Tween;
import mx.transitions.easing.*;

class Carousel extends MovieClip {
	public function Carousel (){
		trace("construktor");
	}
	public function begin(){
	t.icon.onRelease = Delegate.create(t,released);
	}
	private var released:Function = function() {
		trace("released");
		var t:MovieClip = this;
		var tw:Tween = new Tween(t,"_xscale",Strong.easeOut, t._xscale,100,1,true );
		trace("onMotionStopped");
		tw.onMotionStopped = Delegate.create(t, unReleased); 
		};
	private var unReleased:Function = function() {
		trace("unReleased");
		};
}

Mein Problem dabei ist jetzt, dass folgende Zeile ohne Auswirkung bleibt:
tw.onMotionStopped = Delegate.create(t, unReleased);

Kann es sein, dass man innerhalb einer Funktion nicht noch einmal eine Funktion aufrufen kann?? wenn ich hingegen folgendes schreibe funktioniert es:

import mx.utils.Delegate;
import mx.transitions.Tween;
import mx.transitions.easing.*;

class Carousel extends MovieClip {
	public function Carousel (){
		trace("construktor");
	}
	public function begin(){
	t.icon.onRelease = Delegate.create(t,released);
	}
	private var released:Function = function() {
		trace("released");
		var t:MovieClip = this;
		var tw:Tween = new Tween(t,"_xscale",Strong.easeOut, t._xscale,100,1,true );
		trace("onMotionStopped");
		var unReleased:Function = function() {
			trace("unReleased");
		};
		tw.onMotionStopped = Delegate.create(t, unReleased); 
		};

}

Hat jemand einen guten Link(Tutorials ) für mich bzw. eine Info nach was ich suchen muss -> damit ich weiter komme?

Vielen Dank im Voraus

[SpecOps-12]

PHP-Code:

public function begin () {
        t.icon.onRelease = Delegate.create (t, released);
    } 


Laut deinem Script ist t an dieser Stelle nicht bekannt.
Das wäre das erste.

Dann leg mal die functions mit den Standard-Syntax an (wie auch die public function), nicht mit diesem Variablen-Syntax var soundso:Function = function():Void {} . Ich wusst gar nicht, dass der überhaupt noch zulässig ist in AS2-Klassen.

[Janoscharlipp]

was ist bitte ein OOP Funktionsaufruf

Vielleicht solltest du Funktionen auf die übliche Weise definieren:
Nicht

PHP-Code:

private var released:Function = function() { 


sondern

PHP-Code:

private function released():void{ 


Verschachtelt definieren solltest du die Funktionen nicht, das macht man nur, wenn man wirklich eine anonyme Funktion haben möchte.


EDIT: oh, das stand ja schon da

[|Xne.3]

funktioniert das auch nicht. ich habe jetzt folgendes probiert:

PHP-Code:

import mx.utils.Delegate;
import mx.transitions.Tween;
import mx.transitions.easing.*;

class Classtest extends MovieClip {
    private var home:MovieClip;
    private var luky:String;
    public function Classtest (s:String) {
        trace ("constr: " + s);
        home = this;
        luky = "Lucky";
        trace (luky);
    }
    
    public function begin () {
    trace ("begin");
    var t:MovieClip = _root.attachMovie("icon","icon",100);
    t.onRelease = Delegate.create(t,released);
    trace (home);
    }
    private function unReleased():Void {
         trace("unReleased");
        
         
    }
    private function released():Void {
        trace("released");
        var t:MovieClip = this;
        var tw:Tween = new Tween(t,"_x",Strong.easeOut, t._x,t._x + 20,1,true );
        
        tw.onMotionStopped = Delegate.create(t, unReleased); 
    }


} 


ich rufe die Funktion begin auf. die wiederum attached ein attached ein ICON, wenn ich jetzt auf das icon klicke, wird die function released aufgerufen, nur wenn das Tween fertig ist, wird leider unReleased nicht aufgerufen. kann das sein, dass man inerhalb einer mit Delegate.create aufgerufenen funktion nicht mehr auf die private functions der Klasse zugreifen kann?? wenn ja, wie kann ich trotzdem drauf zugreifen?

thx for you help,
greez xne

[SpecOps-12]

der Scope des Tweens liegt auf dem icon, das auf der _root erzeugt wird, nicht auf der Instanz deiner Klasse.
Denn du deligierst den Scope der onRelease-Listener-Function ebenfalls auf das icon, nicht auf die Klasseninstanz "home".

Nachfolgend ne Lösung.
Wobei ich die Klasse dann eher direkt an das Bibliotheken-Objekt anhängen würde und mit attachMovieClip statt "new Classtest()" initiieren würde.
Ist in AS2 halt leider alles etwas seltsam mit MovieClip-Erben.

PHP-Code:

import mx.utils.Delegate;
import mx.transitions.Tween;
import mx.transitions.easing.*;
class Classtest extends MovieClip {
    private var home:MovieClip;
    private var t:MovieClip;
    private var luky:String;
    public function Classtest (s:String) {
        trace ("constr: " + s);
        home = this;
        luky = "Lucky";
        trace (luky);
    }
    public function begin () {
        trace ("begin");
        t = _root.attachMovie ("icon", "icon", 100);
        t.onRelease = Delegate.create (home, released);
    }
    private function unReleased ():Void {
        trace ("unReleased");
    }
    private function released ():Void {
        trace ("released");
        var tw:Tween = new Tween (t, "_x", Strong.easeOut, t._x, t._x + 20, 1, true);
        tw.onMotionStopped = Delegate.create (home, unReleased);
    }
} 


[|Xne.3]

super, danke für die rasche info! das mit dem scope war mir leider gar nicht so bekannt -> jetzt funktionierts! nochmals, THANKS!!