Pfadproblem - merkwürdiger Effekt - Unterschied zwischen jpg und flv

[Marcellus]

Hallo Forum,

habe gerade 2 Stunden damit verbracht ein Problem zu lösen, dass ich mir nicht erklären kann.
Vielleicht hat ja Jemand eine Erklärung für mich

Die Struktur meiner Webseite ist folgende:
Auf root liegen index.html und drei Ordner: [media], [swf] und [variablen].
Der Ordner [media] hat zwei Unterordner: [flv] und [jpg].
Index.html ruft Flashfilm auf, der in [swf] liegt.
Der Flashfilm importiert vars.xml aus [variablen] und lädt dann Bilder aus [jpg] oder streamed Flashvideo aus [flv].

Beispiel der vars.xml:

PHP-Code:

<?xml version="1.0" encoding="ISO-8859-1"?>
<slideshow>
<container0>
<media url="media/jpg/Strangfuehrungsrollen.jpg" mime="jpg" time="4" />
</container0>
<container1>
<media url="media/jpg/Schleifmaschine-TOS.jpg" mime="jpg" time="4" />
<media url="media/jpg/Scheibenrollen.jpg" mime="jpg" time="4" />
</container1>
<container2>
<media url="../media/flv/revolverTemp.flv" mime="flv" time="" puffer="5" loop="ja" />
</container2>
<container3>
<media url="media/jpg/P1230013.jpg" mime="jpg" time="4" />
<media url="media/jpg/P1310015.jpg" mime="jpg" time="4" />
</container3>
</slideshow>

Wenn ich beim Pfad zum Flashvideo (media url in container2) ../ weglassen würde, findet Flash den Film nicht mehr.
Ich denke, das es mit dem Streamen zu tun haben muss.
Aber warum wird ein Stream anders gehändelt als das Laden von jpg´s

[madflanderz]

frag nicht nach logik

habe auch vor 2 monaten 3 h verbracht um das herauszufinden.
links sind immer relativ zum hauptelement. in der IDE ist es zwar der flashfilm direkt, später aber die html-datei.

komischerweise wird diese regel nicht für netstreams benutzt, da wird komischerweise direkt der film als basis genommen.

ist irgendwie total bescheuert aber läßt sich nich ändern.


gruß mad

[Marcellus]

ja prima!?
Warum hab ich das nirgendwo gelesen?
Wird das irgendwo beschrieben oder ist das jetzt ein Bug?

[madflanderz]

nö is halt so, kann man nicht unbedingt als bug bezeichnen.

aber hier hab ich noch was für dich:

PHP-Code:


/**
 * @author         madflanderz <info@madflanderz.de>
 * @version     $Id$
 * 
 * @description
 *                 Get the absolute Path of the directory of a URL. If "url" is not specified, getPath() returns the directory of the swf.
 * 
 * @parameter
 *                 url:String - default is the path of the swf
 *                 depth:Number - reverse depth of the directory of the swf
 * 
 * @usage        
 *                 Example: swf with this location - http://www.domain.com/dir1/dir2/dir3/movie.swf
 *                 
 *                 PathUtils.getDir();        // http://www.domain.com/dir1/dir2/dir3/
 *                 PathUtils.getDir(1);    // http://www.domain.com/dir1/dir2/
 *                 PathUtils.getDir(2);    // http://www.domain.com/dir1/
 *                 PathUtils.getDomain();    // http://www.domain.com/
 * 
 *                 PathUtils.getDir("http://www.domain.com/blaaa/blupp/file.txt");    // http://www.domain.com/blaaa/blupp/
 *                 PathUtils.getDomain("http://www.domain.com/blaaa/blupp/file.txt");    // http://www.domain.com/
 *                 
 * 
 * 
 */
class PathUtils 
{
    

    //- returns the absolute path of the URL
    public static function getDir(url:String , depth:Number):String
    {
        if (url == undefined){
            url = _url;
        }
        if (depth == undefined){
            depth = 1;
        }
        else depth += 1

        var u = url;

        var searchFrom = 0;
        for (var i = 0; i < depth; i++)
        {

            var pos = u.lastIndexOf('/');
            if (pos != -1)
            {

                u = u.substr(0,pos);
            }
        }

        return u + "/";
    }
    
    //- returns the domain of the URL
    public static function getDomain(url:String):String
    {
        if (url == undefined)
        {
            url = _url;
        }
        
        var pos = url.indexOf('/', 7);
        
        if (pos != -1)
        {

            url = url.substr(0,pos+1);
        }
        
        return url;
    }



} 


anstatt relative benutzt du nun absolute pfade, hier mal ein beispiel:

PHP-Code:

var pathToSwf:String = PathUtils.getDir(this._url);
mc.loadMovie( pathToSwf + "media/jpg/Scheibenrollen.jpg" );
ns.play( pathToSwf + "media/flv/revolverTemp.flv"); 


"pathToSwf" ist jetzt immer der pfad zu deiner haupt-swf, jetzt ist es sogar egal wie der film eingebettet wird, die pfade bleiben immer korrekt.

gruß mad

[Marcellus]

Danke, das ist ja eine schöne Idee.
Werde ich mir mal genauer angucken.