onMetaData in OOP

[Asvari]

Hallo zusammen!

Ich versuche gerade, einen Klasse für die Steuerung von Videos zu schreiben. Dabei soll eine Fortschrittsanzeige eingebaut sein, für die ich natürlich die Gesamtdauer des Videos haben muss. Dies kann man mit netstream.onMetaData auslesen, so viel weiss ich. Jetzt stellt mich das in der Klasse vor einige Probleme...ich kann die Metadaten zwar auslesen, aber nicht abspeichern:

class classes.VideoController
{
	var videoObj:Video;
	var netConnection:NetConnection;
	var netStream:NetStream;
	var videoDuration:Number;
	
	function VideoController(videoObject:Video){
		videoObj = videoObject;
		netConnection = new NetConnection();
		netConnection.connect(null);
		netStream = new NetStream(netConnection);
	
		netStream.onMetaData = function(infoObj:Object){
			videoDuration = infoObj["duration"];
			trace("Gesamtdauer: "+videoDuration);
		}		
		
		videoObj.attachVideo(netStream);
		netStream.setBufferTime(5);		
	}

videoDuration ist zwar da, wo ich es trace, bekannt, ausserhalb der Funktion aber undefined. Hat mir jemand einen Tipp, wie ich die Dauer abspeichern kann?

[salazar]

hi,
wo steht denn dein anderes trace das undefined ausgibt?
hört sich ein bissal nach einem timing prob an... evtl fragst du die var ab bevor onMetaData die var überhaupt setzen konnte?!

cheers, sal

[Asvari]

hier noch die gesamte Klasse bisher...

class classes.VideoController{

	var videoObj:Video;
	var netConnection:NetConnection;
	var netStream:NetStream;
	var videoDuration:Number;
	
	function VideoController(videoObject:Video){

		videoObj = videoObject;
		netConnection = new NetConnection();
		netConnection.connect(null);
		netStream = new NetStream(netConnection);
	
		netStream.onMetaData = function(infoObj:Object){
			videoDuration = infoObj["duration"];
			trace("Gesamtdauer: "+videoDuration);
		}
		statusAbfrage();

		videoObj.attachVideo(netStream);
		netStream.setBufferTime(5);		
	}
	
	public function playVideo(videoPath:String){
		trace("videoPath: "+videoPath);
		netStream.play(videoPath);
	}
	
	private function statusAbfrage(){
		trace("Gesamtdauer ausserhalb: "+videoDuration);
		
	}
}

Stimmt, das könnte das Problem sein... das trace in der statusAbfrage-Funktion kommt in der Ausgabe vor dem trace im Konstruktor. Wie kann ich sicherstellen, dass die MetaDaten schon vorhanden sind? Sind die vorhanden, sobald ich angefangen habe, ein Video abzuspielen?

[salazar]

pack doch playVideo() und statusAbfrage() mit in die onMetaData function rein...
also die function aufrufe, nicht die functions/methoden selbst
cheers, sal

[Asvari]

Das geht leider nicht wirklich...Weil 1. die Funktion dort nicht bekannt ist und 2. muss ich playVideo immer wieder von aussen aufrufen können, um das Video zu wechseln.

[salazar]

Zitat von Asvari

Das geht leider nicht wirklich...Weil 1. die Funktion dort nicht bekannt ist

mist. grad erst gesehen. ist ja as2
dann kannste das aber umgehen indem du den scope in einer var abspeicherst. dann kennt der auch deine functions

Zitat von Asvari

und 2. muss ich playVideo immer wieder von aussen aufrufen können, um das Video zu wechseln.

aber wenn du das video wechseln willst... ist dann da eh nicht ein kleiner denkfehler bei dir in der klasse?! wenn du jetzt ein anderes video abspielen willst hat das neue video doch auch eine andere duration?! von demher mußte dir ja eh bei jedem neuen video auch eine neue duration holen?!

cheers, sal

[Asvari]

Damit habe ich noch so meine Probleme...wie kann ich den Scope in einer Variable abspeichern? Für solche Probleme habe ich bisher Delegate verwendet, aber das hilft leider nicht überall weiter...

Das mit dem Denkfehler ist richtig, primär gings mir erstmal darum die duration zu bekommen, aber natürlech darf das dann nicht im Kontruktor sein...ich hab das jetzt in die playVideo Funktion verschoben.

[salazar]

so sollte das klappen mit dem scope.
als bsp.:

PHP-Code:

function VideoController(videoObject:Video){
    
    var scope = this;

    videoObj = videoObject;
    netConnection = new NetConnection();
    netConnection.connect(null);
    netStream = new NetStream(netConnection);

    netStream.onMetaData = function(infoObj:Object){
        scope.videoDuration = infoObj["duration"];
        scope.statusAbfrage();
    }

    videoObj.attachVideo(netStream);
    netStream.setBufferTime(5);        
    
} 


cheers, sal

[Asvari]

das will nicht so recht...

class classes.VideoController
{
	var videoObj:Video;
	var netConnection:NetConnection;
	var netStream:NetStream;
	var videoDuration:Number;
	var scope:Object;
	
	function VideoController(videoObject:Video)
	{
		trace(this);
		scope = this;
		videoObj = videoObject;
		netConnection = new NetConnection();
		netConnection.connect(null);
		netStream = new NetStream(netConnection);
		
		videoObj.attachVideo(netStream);
		netStream.setBufferTime(5);		
	}
	
	public function playVideo(videoPath:String){
		trace("videoPath: "+videoPath);
		netStream.play(videoPath);
		netStream.onMetaData = function(infoObj:Object){
			scope.videoDuration = infoObj["duration"];
			
			trace("videoduration: "+scope.videoDuration);
			scope.statusAbfrage(infoObj["duration"]);
			//trace("Gesamtdauer: "+videoDuration);
			
		}
	}
	
	private function statusAbfrage(duration:Number){
		trace("Gesamtdauer ausserhalb: "+duration);
		
	}
}

Die Funktion statusAbfrage wird nicht ausgelöst und die Zuweisung zu scope.videoDuration funtkioniert auch nicht...

[salazar]

ja nee. jetzt ist das ganze nach deinem umbau auch an der falschen stelle!

PHP-Code:

public function playVideo(videoPath:String){
    var scope = this;
    trace("videoPath: "+videoPath);
    netStream.play(videoPath);
    netStream.onMetaData = function(infoObj:Object){
        scope.videoDuration = infoObj["duration"];
        trace("videoduration: "+scope.videoDuration);
        scope.statusAbfrage(infoObj["duration"]);
        //trace("Gesamtdauer: "+videoDuration);
    }
} 


cheers, sal

[Asvari]

ah so war das gemeint tausend Dank, endlich klappts

[salazar]

na bitte, geht doch
viel spaß noch,
cheers, sal