onLoadInit und Variablenübergabe

[Oneside]

Hallo,

ich lade innerhalb einer einfachen Schleife Bilder aus einem Array in duplizierte Movieclips. Wenn ein Bild geladen ist, ermittle ich die Breite des Bildes (ist ja erst möglich, wenn das Bild geladen ist) und will diese in das Array mit den Bilddaten eintragen.

Jetzt habe ich das Problem, dass die Funktion onLoadInit ja erst ausgeführt wird, wenn das Bild geladen wurde. Während dem Laden des Bildes läuft die for-schleife ja bereits weiter. Wenn ich dann auf meine Zählervariable "i" zurückgreifen will wenn das Bild endlich geladen ist, hat "i" ja bereits schon einen veränderten bzw höheren Wert.

Wie kann ich der onLoadInit-Function beim Aufruf denn die den Wert von "i" übergeben, damit ich nach dem Laden weiß, bei welchem Array-Index ich die Breite zuweisen muss?

Ich hoffe ich habs "einigermaßen" verständlich ausgedrückt

Das ganze sieht so aus:

PHP-Code:

var a_art_data:Array = new Array();

a_art_data[0] = new Array('pd1.png');
a_art_data[1] = new Array('pd2.png');

for(i=0;i<a_art_data.length;i++){     

    // Artikel Movieclip duplizieren
    duplicateMovieClip(_root.i_artikel.i_artikelset, "i_artikelset_"+i,i+1);    
  
    // Aktueller Movieclip
    mc = _root.i_artikel["i_artikelset_"+i];

    var mcl = new MovieClipLoader();  
    var ml = new Object();  
    ml.onLoadInit = function(obj) {  

    // Breite des Bildes in Array eintragen
        // Hier müsste ich wissen, welchen Wert "i" denn hatte (also welcher Array-Index zu diesem Bild gehört) und welchem Array-Index ich die Breite zuweisen muss:           
    a_art_data[i][1] =  obj._width;


    };  
    mcl.addListener(ml);  
    mcl.loadClip(a_art_data[i][0],mc.i_artikelbild);       
 
} 


Nimm keine for-Schleife, sondern lade hintereinander...

[Oneside]

Hallo agedoubleju,

Das Problem ist, dass ich nicht weiß, wie viele Einträge in meinem Array sind, bzw wieviele Bilder ich laden muss. Die Daten werden per Laufzeit übergeben.
Das müsste also dynamisch bleiben.

Jemand ein Idee?
Kann ich der onLoadInit-Funktion denn beim Aufruf keine Daten übergeben?

Gruß
Oneside

Das müsste also dynamisch bleiben.

Bleibt es doch auch wenn hintereinander geladen wird, statt gleichzeitig. Du kannst natürlich auch versuchen, im onLoadInit das übergebene Objekt auszuwerten.

[readme.txt]

das kannst du doch einfach über den MC-Namen regeln ...

PHP-Code:

var arr:Array = new Array();
var mcl:MovieClipLoader = new MovieClipLoader();  
var ml:Object = new Object();   

mcl.addListener(ml);

ml.onLoadInit = function(mc:MovieClip):Void {
  var _id:Number = parseInt(mc._name.split("mc").join(""));

  arr[i] = new Array("blabla",mc._width);
}

for(var i:Number=0; i<10; i++) {
  var mc:MovieClip = this.createEmptyMovieClip("mc"+i,i);

  mcl.loadClip("bild"+i+".jpg",mc);
} 


PS: Du brauchst auch nicht in jedem Schleifendurchlauf eine neue Instanz der MovieClipLoader-Klasse und einen neuen Listener erstellen. Das ist Ressourcenverschwendung.

[Oneside]

Gute Idee mit dem Namen, aber leider bekomme ich die Bilder übergeben und hab keine Möglichkeit den Dateinamen der Bilder extern anzupassen

[Oneside]

Zitat von agedoubleju

Bleibt es doch auch wenn hintereinander geladen wird, statt gleichzeitig. Du kannst natürlich auch versuchen, im onLoadInit das übergebene Objekt auszuwerten.

Wenn ich die Bilder hintereinander lade, dann müsste ich ja dem Script irgendwie sagen "warte bis Datei geladen und lade dann die nächste Grafik".
Welche Möglichkeit hab ich das Script solange anzuhalten, bis eine Grafik geladen ist, um dann wieder anzustossen um die nächste zu laden?
Timer/Timeout oder sowas?

Wenn ich die Bilder hintereinander lade, dann müsste ich ja dem Script irgendwie sagen "warte bis Datei geladen und lade dann die nächste Grafik".
Welche Möglichkeit hab ich das Script solange anzuhalten, bis eine Grafik geladen ist

Du hast doch den onLoadInit... Einfach hier einen Zähler solange hochzählen, bis alle Bilder geladen sind. Nach dem Zähler mit loadClip das nächste Bild laden etc. Hier mal ein Ansatz:

PHP-Code:

//Zähler
var index:Number = 0;

//Liste der Bilder
var urls:Array = new Array("bild1.jpg", "bild2.jpg","bild3.jpg");

//Liste der MCs
var mcs:Array = new Array();
var len:Number = urls.length;

//leere MCs erzeugen
for(var i=1;i<=len;i++){
   this.mcs.push(this.createEmptyMovieClip("con"+i,i));
   this["con"+i]._x = (i*100);//evtl. positionieren
}

//erstes Bild laden
var mclListener:Object = new Object();
var mcLoader:MovieClipLoader = new MovieClipLoader();
mcLoader.addListener(mclListener);
mcLoader.loadClip(urls[index], mcs[index]);


//während des Ladens bspw. um Ladebalken o.ä. zu aktualisieren
mclListener.onLoadProgress = function(target:MovieClip, bytesLoaded:Number, bytesTotal:Number):Void {
    trace(target + ".onLoadProgress with " + bytesLoaded + " bytes of " + bytesTotal);
    var prozent = bytesLoaded*100/bytesTotal;
   _root.meineTextfeldinstanz.text = ""+prozent+" %"; 
}


//fertiggeladen
mclListener.onLoadInit = function(mc:MovieClip) {
    trace("fertig, mc="+mc);
   index++;
   if (index < len) {//sind noch weitere zu laden?
       mcLoader.loadClip(urls[index], mcs[index]);
   }
}

this.stop(); 


[readme.txt]

Zitat von Oneside

Gute Idee mit dem Namen, aber leider bekomme ich die Bilder übergeben und hab keine Möglichkeit den Dateinamen der Bilder extern anzupassen

musst du ja auch nicht, ich hab das nur in meinem Beispiel so gemacht. Das funktioniert auch bei deiner Variante, musst das nur entsprechend anpassen.