Navigation anordnungs und zoom problem

[deak]

hi,

ich habe 6mc registrierpunkt ist in der mitte des mc´s.
alle mcs sollen in der ausgangssituation auf 25% skaliert sein und einen Abstand von 28 Pixeln haben. anhand der mouse position sollen sie sich zoomen der mc auf dem die mouse ist soll dann 100% sein die restlichen absteigend kleiner. ok das würde ich über nen gescripteten twee machen.
hab gerade nur das Problem das ich die Abstände nicht hinbekomme

for (i=0;i<7;i++){
	this.id = i;
	_root[i]._xscale = 25;
	_root[i]._yscale = 25;
	_root[i]._x = _root[i].width+28;

}

[Der Frager]

Zitat von deak

...hab gerade nur das Problem das ich die Abstände nicht hinbekomme...

Da fehlt ja auch ein Underline vor _width. Außerdem musst du den "Vorgänger" als Ausgagnspunkt nehmen:

PHP-Code:

_root[i]._x = _root[i-1]._x+_root[i-1]._width+28||0; 


[deak]

ok danke. andere frage was ich da gerade baue bzw. nachbauen muss heisst wohl tsunami menü hast du vielleicht irgendeinen link zu einem horizontalem menü

[Der Frager]

Kennst du google?

http://www.tutorialized.com/view/tut...nami-Menu/7484

Nur mal als ein Beispiel.

[Alpha.ONE]

Ich hab hier eine alte fla gefunden bei der ich ein tsunami menü benutze.

Vielleicht hilft dir das ein bischen weiter.
Die fla ist im Anhang

Und hier das Script:

PHP-Code:

function tsunami(mc:MovieClip, distanceMin:Number, minScale:Number, minAlpha:Number, activeLeftX:Number, activeRightX:Number, ratio:Number):Void
{
    distanceY = Math.abs(mc._y - _root._ymouse);
    if (distanceY < distanceMin && _root._xmouse > activeLeftX && _root._xmouse < activeRightX)
    {
        targetScale = 100 - distanceY;
        targetAlpha = 100 - distanceY;
    }
    else
    {
        targetScale = minScale;
        targetAlpha = minAlpha;
    }
    addScale = (targetScale - mc._xscale);
    addAlpha = (targetAlpha - mc._alpha);
    mc._xscale += addScale * ratio;
    mc._yscale = mc._xscale;
    mc._alpha += addAlpha * ratio;
    buttonPos();
}


function buttonPos():Void
{
    dis = 10;
    
    me1._y = 124;
    me2._y = me1._y + me1._height + dis;
    me3._y = me2._y + me2._height + dis;
    me4._y = me3._y + me3._height + dis;
    me5._y = me4._y + me4._height + dis;
    me6._y = me5._y + me5._height + dis;
    me7._y = me6._y + me6._height + dis;
}


for (var i = 1; i <= 7; i++)
{
    this["me" + i].i = i;
    this["me" + i].onEnterFrame = function()
    {
        tsunami(this, 40, 20, 15, this._x - 50, this._x + this._width + 50, .4);
    };
} 


MfG Alpha



EDIT: Wie gesagt es ist ein altes Script. Heute würde ich das ganze ein bischen übersichtlicher Programmieren. Also bitte nich hauen
EDIT2: Hab grad gelesen das du ein horizontales tsunami menü suchst. Das ist leider vertikal. Evtl kann ich das später für dich abändern aber das könnte noch etwas dauern

[Alpha.ONE]

Ich hatte jetzt lust das auf horizontal umzubauen und ein wenig zu modifizieren.
Die fla ist im Anhang.

Und das ist das Script:

PHP-Code:

var clipArray:Array = new Array ("clip1", "clip2", "clip3", "clip4", "clip5", "clip6");


function tsunami (target:MovieClip, distanceMin:Number):Void
{
    var minScale:Number = 25; 
    var ratio:Number = 0.4;
    
    var distanceX:Number = Math.abs(target._x - _root._xmouse);
    var activeTopY:Number = target._y - (target._width/2)
    var activeBottomY:Number = target._y + (target._width/2)
    
    if (distanceX < distanceMin && _root._ymouse > activeTopY && _root._ymouse < activeBottomY)
    {
        targetScale = 100 - distanceX;
    }
    else
    {
        targetScale = minScale;
    }
    
    var addScale:Number = (targetScale - target._yscale);

    target._yscale += addScale * ratio;
    target._xscale = target._yscale;
    clipPosition ()


}

function clipPosition ():Void
{
    for (i = 0; i < clipArray.length; i++ )
    {
        var dis:Number = 10;
        
        this[clipArray[i]]._x = this[clipArray[i-1]]._x + this[clipArray[i-1]]._width + dis
    }
}

for (i = 0; i < clipArray.length; i++ )
{
    this[clipArray[i]].i = i;
    this[clipArray[i]].onEnterFrame = function()
    {
        tsunami(this, 60);
    };
} 


Was mich stört ist, dass das onEnterFrame ständig läuft auch wenn es nicht gebraucht wird. Evtl findet jemand eine Möglichkeit es abzuschalten.


MfG Alpha

[deak]

das ist ja der wahnsinn super sache. war gerade schon am verzweifeln.

danke danke danke

[Alpha.ONE]

Gern geschehen. Man hilft wo man kann.

Beachte aber das das ganze sicherlich noch einer Optimierung bedarf. So wie es jetzt ist würde ich es nicht benutzen da ständig das onEnterFrame läuft.


MfG Alpha

[deak]

ok jetzt hätte ich doch noch zwei fragen.
wenn die MC klein werden soll sich der _alpha verändern.

ist die mouse 200 Pixel über oder unter den Mc´s sollen sie sich komplett ausblenden und wieder einblenden wenn die mouse unter 200Pixel ist.

Kannst mir dabei bitte nochmal helfen oder einen tip geben wie ich das realisiere. danke

deak

p.s. wie kann man den die geschwindigkeit anpassen?

[Alpha.ONE]

So folgendes ist passiert:

• Alphatween wurde eingebaut
• Clips haben ein RollOver und ein RollOut
• onEnterFrame läuft nicht mehr andauernd

Die fla ist im Anhang
Hier das Script:

PHP-Code:

var clipArray:Array = new Array("clip1", "clip2", "clip3", "clip4", "clip5", "clip6");


function tsunami(target:MovieClip):Void
{
    trace(target);
    target.onEnterFrame = function()
    {
        var distanceMin:Number = 60; // benötigter x Abstand der Maus zum Clip für eine Animation
        var minScale:Number = 25; // kleinstmöglich Scalierung (hier 25%)
        var minAlpha:Number = 10; // kleinstmöglicher alpha Wert (hier 10)
        var speed:Number = 0.2; // Geschwindigkeit (kleinerer Wert = langsamere Animation)
        
        var distanceX:Number = Math.abs(target._x - _root._xmouse);
        
        var activeTopY:Number = target._y - 150; // Grenze oberhalb der Clipmitte (hier 150 vom Mittelpunkt der Clips)
        var activeBottomY:Number = target._y + 150; // Grenze unterhalb der Clipmitte (hier 150 vom Mittelpunkt der Clips)
        
        if (_root._ymouse > activeTopY && _root._ymouse < activeBottomY)
        {
            if(distanceX < distanceMin)
            {
                targetScale = 100 - distanceX;
                targetAlpha = 100 - distanceX;            
            }
            else
            {
                targetScale = minScale;
                targetAlpha = minAlpha;
            }
        }
        else
        {
            targetScale = minScale;
            targetAlpha = minAlpha;
            if(target._yscale <= minScale+1)
            {
                delete target.onEnterFrame;
                target._yscale = target._xscale = 25

            }
        }
        
        var addScale:Number = (targetScale - target._yscale);
        var addAlpha:Number = (targetAlpha - target._alpha);
        
        target._yscale += addScale * speed;
        target._xscale = target._yscale;
        target._alpha += addAlpha * speed;
        
        clipPosition();
    };
}


function clipPosition():Void
{
    for (p = 0; p < clipArray.length; p++)
    {
        var dis:Number = 5;
        this[clipArray[p]]._x = this[clipArray[p - 1]]._x + (this[clipArray[p-1]]._width/2) + (this[clipArray[p]]._width/2) + dis;
    }
}

activator_mc.onRollOver = function ()
{
    for (i = 0; i < clipArray.length; i++)
    {
        tsunami(_root[clipArray[i]]);
    }
}

for (i = 0; i < clipArray.length; i++)
{
    this[clipArray[i]]._xscale = this[clipArray[i]]._yscale = 25;
    this[clipArray[i]]._alpha = 10;
    clipPosition()
    
    this[clipArray[i]].onRollOver = function ()
    {
        var colorRollOver:Color = new Color(this);
        colorRollOver.setRGB(0x000000);

    }
    this[clipArray[i]].onRollOut = function ()
    {
        var colorRollOut:Color = new Color(this);
        colorRollOut.setRGB(0xFF0030);

    }
} 


Das ist fast schon für den Stuff Bereich geeignet


MfG Alpha

[deak]

ja cool, läuft perfekt, wenn ich es in deinem film teste. wenn ich es in meinen film einbauen will dieser ist 1280x800 und es soll in der unteren rechten ecke sitzen, läuft es nicht mehr. ich hab halt bilder im mc aber das müsste ja egal sein. also rollover klappt nur der rest nicht, an was kann das liegen???

[Alpha.ONE]

Kannst du mir evtl deine fla schicken? Ich kann das so nicht beurteilen.
Is leider komplizierter geworden als ich wollte.
Kann an vielem liegen. Hast du die ganzen variablen überprüft?
Ist der MC activator_mc an der richtigen stelle usw...

Wie gesagt ist schwer zu sagen warum es nicht geht

MfG Alpha

[deak]

kann ich machen..hast du email oder skype?

[Alpha.ONE]

eMail: ulrichraab[at]t-online.de

[Pixeljockey]

Hallo Alpha.ONE,

erst mal einen dicken Daumen hoch für deine Arbeit. Eine Frage zu deinem Script hätte ich noch:

Wie könnte man es anstellen, dass die Skalierung nicht vom linken oberen Registerpunkt, sondern von der Mitte der MC's ausgeht? Ich probier hier schon 'ne halbe Ewigkeit und komme einfach nicht drauf...

Gruß, Pixeljockey

P.S.: Vielen Dank im Voraus