Matrix Scale Rotate ....

[Xeef]

einfachheits halber habe 2 MC die in einander verschachtelt sind (konten speter 100te verschachtelungen werden)

also Master
und Master.Slave

jetzt dreh ich den Master mit myMatrix.rotate(radians);

ergebnis Master und Slave sind verdreht
das ist OK

nun will ich den Slave Scalen undzwar horisontal
myMatrix.scale(2, 1);

PROBLEM !!!!

es Scalt zwar aber die scalierung ist verdreht da ja der Master verdreht ist

wie kan ich das umrechnen

heist ich habe ein clip mit

30º drehung
(a=0.866025403784439, b=0.5, c=-0.5, d=0.866025403784439, tx=0, ty=0)
in dem ein clip ist (der adaptiert diese drehung ebenfals was beabsichtigt ist)

(a=2, b=0, c=0, d=1, tx=0, ty=0)

das wurde den Slave auf 2*breite setzen (tuts auch)
das problem ist das es im coordinatensystem des Masters geschiet
und das will ich NET !


hat jemand ne antwort oder die adresse zu einem guten matamatik forum ???

danke im vorraus (sitze seit 2 wochen dran und kein vorwerts komen)

[pape]

erstellst du die mc's komplett per as, oder sind es rechtecke, die attacht/dubliziert werden?

beim zweiten sehe ich eher keine Lösung... weil du dabei aus nem rechteck nen parallelogramm machen müsstest und ich nicht wüsste, wie man aus nem rechteck per as nen parallelo gramm macht, wenn es ein gezeichnetes rechteck is

[Xeef]

_root.createEmptyMovieClip("Master", 0);
TM = new flash.geom.Transform(Master);
_bmp1 = new flash.display.BitmapData(150, 150, false, 0x00FF0000);
Master.attachBitmap(_bmp1, 0);
Master.createEmptyMovieClip("Slave", 1);
TS = new flash.geom.Transform(Master.Slave);
_bmp2 = new flash.display.BitmapData(50, 50, false, 0x000000FF);
Master.Slave.attachBitmap(_bmp2, 1);
//
M = new flash.geom.Matrix();
M.translate(100, 50);
TM.matrix = M;
//Rotate Master
M.identity();
M.rotate(45/180*Math.PI);
Tmp = TM.matrix.clone();
M.concat(Tmp);
TM.matrix = M;
//Scale Slave
M.identity();
M.scale(2, 1);
Tmp = TS.matrix.clone();
M.concat(Tmp);
TS.matrix = M;
////////////////////////////
//
//
//SO sols aussehen !!!!!!
//
_root.createEmptyMovieClip("Master1", 1);
TM1 = new flash.geom.Transform(Master1);
_bmp1 = new flash.display.BitmapData(150, 150, false, 0x00FF0000);
Master1.attachBitmap(_bmp1, 0);
_root.createEmptyMovieClip("Slave1", 2);
TS1 = new flash.geom.Transform(Slave1);
_bmp2 = new flash.display.BitmapData(50, 50, false, 0x000000FF);
Slave1.attachBitmap(_bmp2, 1);
//
M = new flash.geom.Matrix();
M.translate(350, 50);
TM1.matrix = M;
TS1.matrix = M;
//
M.identity();
M.rotate(45/180*Math.PI);
Tmp = TM1.matrix.clone();
M.concat(Tmp);
TM1.matrix = M;
M.identity();
M.rotate(45/180*Math.PI);
Tmp = TS1.matrix.clone();
M.concat(Tmp);
TS1.matrix = M;
//
M.identity();
Orgmatrix = TS1.matrix.clone();
M.a = 2;
M.d = 1;
//
M.tx = Orgmatrix.tx;
M.ty = Orgmatrix.ty;
//
Orgmatrix.tx = 0;
Orgmatrix.ty = 0;
Orgmatrix.concat(M);
TS1.matrix = Orgmatrix; 

[Xeef]

P.S

liege ich falsch wen ich sage das alle rechtecke paralelograme sind ???

[André Michelle]

Willst du eine isometrische Perspective ?

import flash.display.*;
import flash.geom.*;

var tile: BitmapData = new BitmapData( 64, 64, false, 0xffcc00 );

var clip: MovieClip = this.createEmptyMovieClip( 'clip', 0 );
clip.attachBitmap( tile, 0 );

var cm: Matrix = clip.transform.matrix;

cm.createBox( 2, 1, Math.PI/4, 128, 64 );

clip.transform.matrix = cm;

Für die Drehung kommt dann noch etwas Code dazu...

[pape]

Zitat von Xeef

liege ich falsch wen ich sage das alle rechtecke paralelograme sind ???

nein.

Ich glaub ich kann dir hier nicht weiterhelfen, weil ich kein Flash8 besitze und scheinbar neue Funktionen dabei sind die du benutzt.. dachte es ginge ums verständnis...^^

Man könnte mit moveTo, LineTo usw. arbeiten um die sachen zu zeichnen und das könnte man vektoriell machen und dann über satz von pythagoras oder evtl. trigonometrie nach rotation manuell das scalen aufsplitten in die koordinaten der eckpunkte bzw. in die vektoren...

pape

[Xeef]

worum es geht

es soll eine art grapicheditor sein

du kanst drehen,scale,skew ....

UND

die objecte konen verschachtelt werden

z.B

BackGorund (das Mehr)
BackGorund.Schiff (ein schiff)

wen ich nunBackGorund drehe (45º) dreht sich das schiff mit (ist ja ein child von BackGorund)

jetzt wo ich nicht weiter komme
jetzt will ich das Schiff scalen (_xscale)
es solte breiter werden
was es aber tut ist das es breiter und hoher wird (es bleibt ein rechteck)
es solte aber eine raute werden

wen ihr den code laufen laesst seht ihr 2 * B(laues in rote rechteck)
das linke ist was ich kriege das rechte ist was ich brauche

[hgseib]

du willst das objekt ja nicht über seine x-/y- achse scalieren, sondern über seine diagonale. darum: drehen, scalieren, zurückdrehen.
mehrere transformationen können in einer matrix aufmultipliziert werden:

var cRad = Math.PI/180;
//
_root.createEmptyMovieClip("Master", 0);
TM = new flash.geom.Transform(Master);
_bmp1 = new flash.display.BitmapData(150, 150, false, 0x00FF0000);
Master.attachBitmap(_bmp1, 0);
Master.createEmptyMovieClip("Slave", 1);
TS = new flash.geom.Transform(Master.Slave);
_bmp2 = new flash.display.BitmapData(50, 50, false, 0x000000FF);
Master.Slave.attachBitmap(_bmp2, 1);
//
M = new flash.geom.Matrix();
M.rotate(45*cRad);
M.translate(100, 50);
TM.matrix = M;
//
M.identity();
M.rotate(45*cRad);
M.scale(2, 1);
M.rotate(-45*cRad);
TS.matrix = M; 

[Xeef]

hgseib dein beispiel als denk anstos hat mir gefelt danke !

das scheint jetzt zu funktionieren wer bok hat bitte testen
werds die tage in die anwendung einbauet und hofentlicht tut es wirklich
und es scheint mir nicht nur so

var cRad = Math.PI/180;
//
_root.createEmptyMovieClip("Master", 0);
Master.Matrix = new flash.geom.Transform(Master);
Master._bmp = new flash.display.BitmapData(150, 150, false, 0x00FF0000);
Master.attachBitmap(Master._bmp, 0);
Master.createEmptyMovieClip("Slave", 1);
Master.Slave.Matrix = new flash.geom.Transform(Master.Slave);
Master.Slave._bmp = new flash.display.BitmapData(50, 50, false, 0x000000FF);
Master.Slave.attachBitmap(Master.Slave._bmp, 1);
//
TempMatrix = new flash.geom.Matrix();
TempMatrix.rotate(45*cRad);
TempMatrix.translate(100, 50);
Master.Matrix.matrix = TempMatrix;
//
TempMatrix = new flash.geom.Matrix();
TempMatrix.scale(1, 2);
TempMatrix.rotate(-45*cRad);
TempMatrix.translate(80, 60);
Master.Slave.Matrix.matrix = TempMatrix;
//
//
//
//
//
//
//
Matrix_Apply = new flash.geom.Matrix();
Matrix_Apply.scale(1.5, 1);
Master.Slave.Matrix.matrix = MatrixWrap(Master.Matrix.matrix, Master.Slave.Matrix.matrix, Matrix_Apply);
//
function MatrixWrap(Matrix_Parent, Matrix_Self, Matrix_Apply) {
 var Matrix_Parent = Matrix_Parent.clone();
 var Matrix_Self = Matrix_Self.clone();
 var Matrix_Apply = Matrix_Apply.clone();
 var Matrix_Return = new flash.geom.Matrix();
 //
 
 var X = Matrix_Self.tx;
 Matrix_Self.tx = Matrix_Parent.tx =0;
 var Y = Matrix_Self.ty;
 Matrix_Self.ty = Matrix_Parent.ty = 0;
 //
 Matrix_Return.concat(Matrix_Self);
 Matrix_Return.concat(Matrix_Parent);
 Matrix_Return.concat(Matrix_Apply);
 Matrix_Parent.invert();
 Matrix_Parent.tx += X;
 Matrix_Parent.ty += Y;
 Matrix_Return.concat(Matrix_Parent);
 return Matrix_Return;
}