Externer Sound on/off

[vlenz]

Hi... habe ne kleine Frage!
und zwar lade ich in eine SWF ( extra nur für den SOUND ) eine MP3.
funktioniert wunderbar!!! kein problem.
in dem mov. will ich jetzt noch eine simple animation haben (ist schon fretig) die beim streamen des sounds abgespielt wird. beim drauf klicken auf die animation soll der sound stoppen, am besten ausfaden!!! wie mache ich das? und wenn man wieder drauf klickt, soll der sound wieder anspringen.

quellcode timeline:

meinSound = new Sound();
meinSound.loadSound("nininodepre.mp3", true);
meinSound.onSoundComplete = function() {
    meinSound.start(0, 1);
    delete this;
};

quellcode on_off(animation)

frame 1

stop();

frame 2 (bis frame 17 eine animation "tween")

play();

frame 17

gotoAndPlay(2);

Frage... wie und wo muss ich nun im timeline code DEN code unterbringen, der aus dem MC on_off das erfüllt wie oben beschrieben!?

bitte kurz um hilfe.


EDIT:

habs nun soweit.....

_root.on_off.gotoAndPlay(2);
 
_root.on_off.onPress = function () {
	stopAllSounds();
	_root.on_off.gotoAndStop(1);
}

wie mach ich es jetzt aber, dass wenn ich wieder auf das mov, klicke er zum frame 2 springt und wieder den sound abspielt!?

[vlenz]

keiner der mir helfen kann?!

[vlenz]

?????

Du solltest diese wilde Springerei besser vergessen, das macht nur Probleme mit den Variablen-Scopes. Es reicht auch aus, alles auf Frame 1 zu setzen, über Funktionen zu lösen und dann bei Bedarf einen Animations-MC zu attachen. Mal als (ungetesteter) Ansatz:

PHP-Code:

//vorausgesetzt wird ein Animations-MC in der Bibliothek, der den Verknüpfungsbezeichner meineAnimation hat
//und das Script liegt nur auf Schlüsselbild 1

this.createEmptyMovieClip("con",1);//leeren MC erstellen
this.con.klick = -1;//Startwert für einen Wechselschalter
this.con.attachMovie("meineAnimation","onOff",1);//verknüpften Animations-MC aus der Bibliothek auf die Bühne holen

this.con.onRelease = function(){
   this.klick *= -1;//zwischen -1 und 1 hin- und herschalten
   if(this.klick == 1){//Sound starten 
      _level0.volume = 100;
      meinSound = new Sound();
      meinSound.loadSound("nininodepre.mp3", true);
      meinSound.setVolume(_level0.volume);
      meinSound.onSoundComplete = function() {
          meinSound.start(0, 1);
      };
   }
   else{//Sound stoppen
      //ausfaden
      this.onEnterFrame = function(){//...kontinuierlich...
         if(_level0.volume == 0){// ...wenn ausgeblendet...
            delete this.onEnterFrame;//...Event löschen
            meinSound.stop();
         }
         else{//...wenn noch nicht ganz ausgeblendet...
            _level0.volume --;
            meinSound.setVolume(_level0.volume);//...Lautstärke runterpegeln
         }
      }     
   }
} 


[vlenz]

hey holger,
danke erstmal für die antwort.
bisher läd er bei mir das MC aus der Bib, allerdings läuft die animation dort nicht ab, sondern springt dort drinnen von 1 auf 2 und zurück.
beim klick auf die animation wird diese weder gestopt oder neu gestartet.
der sound ansich spielt sich auhc nicht direkt ab, ob diese beim klick auf die animation aufhören würde zu spielen und umgekreht wieder laufen würde kann ich gerade nicht sagen.

kannst du da evtl nochma drüber gucken?
habs einfachmal in form der .*fla angehängt.

beste grüße
vlenz

ps: die sounddatei ist nun nicht mit dabei! zu groß...

[vlenz]

einer der mit biddööööö nochma hilft??!?

[vlenz]

huhu... habs nach nen paar mal rumprobieren nun immer noch nicht gecheckt.
habe es jetzt zum laufne gebracht.... allerdings nicht so wie es eigentlich sein sollte... (siehe anhang)
wäre echt toll wenn mir das jemand nochmal auf die professionelle art und weise zeigen könnte mit attachMovie und der ansteuerung des MCs via AS.

bitte bitte bitte!!!

[Der Frager]

Hallo,

was du jetzt mit "attachMovie" willst verstehe ich nicht ganz. Aber dein faden kannste so hier z.B. machen:

PHP-Code:

var tl = this;
var meinSound = new Sound(tl);
meinSound.loadSound("nininodepre.mp3", true);
meinSound.onSoundComplete = function() {
    this.start(0, 1);
};
tl.onOff.onRelease = function() {
    this.inOut = !this.inOut;
    if (this.inOut) {
        this.onEnterFrame = function() {
            if (tl.meinSound.getVolume()>0) {
                tl.meinSound.setVolume(tl.meinSound.getVolume()-5);
            } else {
                delete this.onEnterFrame;
                this.pos = tl.meinSound.position;
                tl.meinSound.stop();
                this.gotoAndStop(2);
            }
        };
    } else {
        if (this._currentframe == 2) {
            this.gotoAndStop(1);
            tl.meinSound.start(this.pos/1000, 1);
        }
        this.onEnterFrame = function() {
            if (tl.meinSound.getVolume()<100) {
                tl.meinSound.setVolume(tl.meinSound.getVolume()+5);
            } else {
                delete this.onEnterFrame;
            }
        };
    }
}; 


Wobei dir das HW ja nun auch schon erklärt hatte...

[vlenz]

mit attach meinte ich das so, dass ich keinen MC auf der bühne liegen habe.. sondern das via export aus der bib mache.
ich teste mal das was du mir geschrieben hast!
danke schonmal

[Der Frager]

Aha - aber ob du den MC nun attached oder schon auf der Bühne hast macht doch fürs restliche Script keinen Unterschied?

[vlenz]

hmm naja stimmt eigentlich =)
sah halt einfach etwas "schöner" aus =) und mit attach hab ich noch nie was gemacht, daher wärs für mich gleich direkt noch was neues gewesen.
aber soweit vielen dank!!
freut mich ja, dass ich es generell erstmal so mit ner IF bedingung geschafft hab das selber zu regeln =)