Cue points

[sunsetpictures]

Hallo flasher,
Ich habe für meine präsentation ein Intro mit premiere pro erstellt und habe dieses in Flash eingebunden. Als erstes habe ich es in meine Zeitleiste eingebettet aber da war die Qualität von Audio und Bild sehr schlicht.
Also lasse ich es nun progressiv herunterladen und die qualität ist gleich viel besser!

Doch nun zu meinem Problem ich möchte das nach dem Intro automatisch das nächste Bild in Flash kommt.
Also wenn das Video abgespielt wurde soll in der Zeitleiste zum nächsten Bild gesprungen werden.

Leider weiß ich nicht wie ich das realisieren kann warscheinlich mit Cue Points? Ich habe mir die hilfe über cuepoints in Flash angeschaut habe aber keine Lösung gefunden!

Bitte Helft mir!
Vielen Dank

Also lasse ich es nun progressiv herunterladen

Womit? Mit der FLVPlayback-Komponente oder der NetStream-Klasse?

Es gibt zwei verschiedene Typen von Cuepoint: die einen werden gleich beim Konvertieren in das FLV eingefügt. Die anderen kannst du per Software setzen. Der erstere Typ funzt genauer, weil er genau auf den Video-Keyframes aufsetzt.

Den zweiteren Typ kannst du bspw. folgendermaßen per Script erzeugen:

PHP-Code:

import mx.video.*;

var cuePt:Object = new Object(); // Cue-Point-Objekt erstellen.
cuePt.time = 2.02;
cuePt.name = "ASpt1";
cuePt.type = "actionscript";
my_FLVPlybk.addASCuePoint(cuePt);  //AS-Cue-Point hinzufügen.

// 2. AS-Cue-Point mit den Parametern time und name hinzufügen.
my_FLVPlybk.addASCuePoint(5, "ASpt2"); 


Wobei my_FLVPlybk der Instanzname einer FLVPlayback-Komponente ist.

Und um Cuepoints abzufangen, kannst du bspw. Listener setzen:

PHP-Code:

var listenerObject:Object = new Object();

listenerObject.cuePoint = function(eventObject:Object):Void {
        trace("Elapsed time in seconds: " + my_FLVPlybk.playheadTime);
        trace("Cue point name is: " + eventObject.info.name);
        trace("Cue point type is: " + eventObject.info.type);
}

//alle cuePoint-Ereignisse abfangen:
my_FLVPlybk.addEventListener("cuePoint", listenerObject); 


Das Schlüsselbild würde ich aber nicht wechseln bei einem Cuepoint, das könnte sonst zu Problemen mit der Komponente führen. Dann besser mit createEmptyMovieClip und attachMovie oder loadMovie ein neues Bild oder einen MC oder Film nachladen, bspw.:

PHP-Code:


var listenerObject:Object = new Object();

listenerObject.cuePoint = function(eventObject:Object):Void {
   trace("Elapsed time in seconds: " + my_FLVPlybk.playheadTime);
   trace("Cue point name is: " + eventObject.info.name);
   trace("Cue point type is: " + eventObject.info.type);
   switch (eventObject.info.name){
      case "ASpt1"://erster Cuepoint erreicht
         _level0.createEmptyMovieClip("con",1);
         _level0.con.loadMovie("meinBild.jpg");
         break;
   }

}

//alle cuePoint-Ereignisse abfangen:
my_FLVPlybk.addEventListener("cuePoint", listenerObject); 


[sunsetpictures]

Vielen vielen dank für deine sehr ausführliche Antwort!!!!!!
Es funktioniert ich habe es hinbekommen!!!