bitmap-Bild -> Pixelfelder tauschen

[holozän]

Hallo zusammen!

Habt Ihr eine Ahnung, ob ich ein bitap Bild (1024/768) auf der Bühne per script aniieren kann... dh. ich möchte, dass sich Bereiche von (sagen wir) 8x8 Pixeln per Script gegenseitig (und per Zufall) vertauschen.

Derart, dass das Bild suksessive "durcheinandergewirbelt", auseinandergenomen wird.

Geht das? Und ...mmh... wie?

Grüße Euch,
der Holozän

[Der Frager]

Hallo,

da ich mich bisher sowieso sehr wenig mit der BitmapData-Klasse auseinandergesetzt habe, dachte ich mir, ich spiele damit mal etwas rum. Rausgekommen ist dann Folgendes:

PHP-Code:

import flash.display.BitmapData;
import mx.transitions.Tween;
import mx.transitions.easing.*;
//
this.createEmptyMovieClip("bild", 1);
var ml = {};
ml.onLoadInit = function() {
    startIt();
};
var mcl = new MovieClipLoader();
mcl.addListener(ml);
mcl.loadClip("http://nemiroff2005.stsland.ru/famous/angelina_jolie.jpg", bild);
//
function startIt() {
    bd = new BitmapData(1024, 768, false);
    var m1 = this.createEmptyMovieClip("m1", 2);
    m1.attachBitmap(bd, 1);
    bd.draw(bild);
    removeMovieClip(bild);
    moveSquares();
}
//
function moveSquares() {
    for (var c = 0; c<2; c++) {
        var bd1 = new BitmapData(8, 8, false);
        var mc = this.createEmptyMovieClip("square"+c, c+3);
        mc.attachBitmap(bd1, 1);
        mc._x = random(1016/8)*8;
        mc._y = random(760/8)*8;
        mc.arr = [];
        for (var j = 0; j<64; j++) {
            var p = bd.getPixel(mc._x+Math.floor(j/8), mc._y+(j%8));
            bd.setPixel(mc._x+Math.floor(j/8), mc._y+(j%8), 0xffffff);
            bd1.setPixel(Math.floor(j/8), j%8, p);
            mc.arr.push(p);
        }
    }
    var nt = new Tween(mc, "_x", Strong.easeOut, mc._x, square0._x, 1, true);
    new Tween(mc, "_y", Strong.easeOut, mc._y, square0._y, 1, true);
    var nt1 = new Tween(square0, "_x", Strong.easeOut, square0._x, mc._x, 1, true);
    new Tween(square0, "_y", Strong.easeOut, square0._y, mc._y, 1, true);
    nt.onMotionFinished = nt1.onMotionFinished=function () {
        this.obj._x = Math.round(this.obj._x);
        this.obj._y = Math.round(this.obj._y);
        for (var j = 0; j<64; j++) {
            bd.setPixel(this.obj._x+Math.floor(j/8), this.obj._y+(j%8), this.obj.arr[j]);
        }
        if (this.obj._name == "square0") {
            moveSquares();
        }
    };
} 


[holozän]

Hallo Frage!

Das sieht klasse aus! Du hast so ziemlich den Punkt getroffen!

Jetzt aber noch zwei Fragen von mir... :-)

… in dem Moment wo sich zwei Elemente vertauschen blitzt der weiße Hintergrund auf... wie könnte man das vermeiden???
Z.B. dass dieser Hintergrund "schwarz" ist (unauffälliger)
Z.B. dass bis zum Moment wo das neue Element sich über die "Leerstelle" schiebt, dort eine Kopie des ursprünglichen Bildes verbleibt.

Und: wo/wie im script könnte ich auf die Tauschgeschwindigkeit Einfluss nehmen? Es geht a bisserl flott alles???

Beste Grüße + Danke schonmal!!!
Holozän

[Der Frager]

PHP-Code:

bd.setPixel(mc._x+Math.floor(j/8), mc._y+(j%8), 0xffffff); 


Die Zeile löscht den Bereich des Bildes bzw. macht ihn weiß. Kannst du auch rauschmeißen (dann bleibt das Bild) oder nur "0" für schwarz setzen.
Die Geschwindigkeit ist hier jeweils die letzte 1 vor dem true und steht für eine Sekunde:

PHP-Code:

var nt = new Tween(mc, "_x", Strong.easeOut, mc._x, square0._x, 1, true); 


[holozän]

Hallo zusammen,

hier in dem script funktioniert alles reibungslos.
Doch gerne würde ich die Tauschgeschwindigkeit vervielfachen.
Also ganz ganz schnell einstellen.

Die Frage ist, welche Einstellungen ich hier vornehmen muss, um
dies beispielsweise auf 1/10 - 1/100 Sekunde zu steigern???

var nt = new Tween(mc, "_x", Strong.easeOut, mc._x, square0._x, 1, true);


Grüße an Euch,
Holozän