Eigene Objekte + EncryptedLocalStore ?

[Nico B.]

Hallo zusammen,

ich versuche gerade eine Variable vom Typ "Point" in den EncryptedLocalStore zu schreiben.

Das Schreiben funktioniert auch ohne Probleme. Will ich mir das Ergebnis tracen lassen, kommt allerdings immer ein String heraus. (Egal wie ich caste)


Wie stelle ich es an, dass ich einen "Point" zurückbekomme ?

Meine "read" Methode sieht zB. so aus:

public function write( _value:*, _name:String):void
        {
            var bytes:ByteArray = new ByteArray();
            bytes.writeUTFBytes(_value);
            EncryptedLocalStore.setItem( _name, bytes);
            trace("saved");
        } 

( "*" weil ich viele verschiedene Dinge in meiner Appliktion reinschreiben will)

Meine Write Methode

public function read( _name:String ):*
        {
            var storedValue:ByteArray = new ByteArray();
            
            if(  EncryptedLocalStore.getItem( _name ) != null)
            {
                storedValue = EncryptedLocalStore.getItem( _name );
                var storedReturnData:*  = storedValue.readUTFBytes(storedValue.length);
                return storedReturnData;
            }
            else
            {
                return null;
            }
        } 

Grüße, nico

[Omega Psi]

Schaue dir mal die registerClassAlias Methode an.

[Nico B.]

Ich entmülle mal eben:

Habe diesen Link gefunden:
http://cookbooks.adobe.com/post_Stor...oca-10563.html

Und dementsprechend dieses Beispiel gebaut:

package 
{
    import de.nicobarelmann.LOL;
    import flash.data.EncryptedLocalStore;
    import flash.display.Sprite;
    import flash.utils.ByteArray;
    
    public class Main extends Sprite
    {
        public function Main() 
        {      
            var lol:LOL = new LOL("Hallo");
            var bytes:ByteArray = new ByteArray();
            bytes.writeObject( lol );
            EncryptedLocalStore.setItem( "contactkey", bytes );
            read();
        }
        
        private function read():void
        { 
            var bytes:ByteArray = EncryptedLocalStore.getItem( "contactkey" );
            var lol:LOL = bytes.readObject(bytes.length) as LOL;
            trace(lol);
        }
    }
} 

Leider ohne Erfolg :/ Kommt immer null heraus...

[sytch]

hi, du musst die daten wieder "manuell" erzeugen. das zb. serialisiert eine arraycollection mit einem variablen objekttypen...

private static function serializeConfigurations(valueObject:Class,collection:ArrayCollection):ArrayCollection{
			var xml:XML = describeType(new valueObject());
			var properties:XMLList = xml..variable.@name;
			var tempac:ArrayCollection = new ArrayCollection();
			
			for each( var object:Object in collection){
				var tempvo:Object = new valueObject();
				for each(var name:Object in properties){
					tempvo[name] = object[name];
				}
				tempac.addItem(tempvo);
			}
			return tempac;
		}

und

public static function getConfiguration():ArrayCollection{
			var byte:ByteArray = EncryptedLocalStore.getItem(KEY);
			var configurations:ArrayCollection = byte.readObject() as ArrayCollection;
			configurations = serializeConfigurations( ConfigurationVO, configurations);
	
			return configurations;
		}

direktes casten hat bei mir auch nie funktioniert...

[Omega Psi]

Wie ich bereits schrieb, schaue dir mal registerClassAlias an

package fs.domain
{

  import flash.net.registerClassAlias;

  public class ValueObject
  {

    public var name:String; 

    public function ValueObject()
    {
      registerClassAlias("fs.domain.ValueObject", ValueObject);
    }

    public function toString():String
    {
      return "[object Woot, name:" + name + "]";
    }
  }
}

<?xml version="1.0" encoding="utf-8"?>
<s:WindowedApplication xmlns:fx="http://ns.adobe.com/mxml/2009"
                                  xmlns:s="library://ns.adobe.com/flex/spark"
                                  xmlns:mx="library://ns.adobe.com/flex/halo"
                                  applicationComplete="onApplicationCompleteHandler(event)">
  <fx:Script>
    <![CDATA[
      import flash.utils.getQualifiedClassName;

      import fs.domain.ValueObject;

      import mx.events.FlexEvent;

      protected function onApplicationCompleteHandler(event:FlexEvent):void
      {
        var vo:ValueObject = new ValueObject();
        vo.name = "Fred";

        write("value", vo);
        var o:* = readAs("value", ValueObject);

        trace("toString             :", o);
        trace("getQualifiedClassName:", getQualifiedClassName(o));
      }

      private function readAs(key:String, type:Class):*
      {
        var bytes:ByteArray = EncryptedLocalStore.getItem(key);
        return bytes.readObject() as type;
      }  
  
      private function write(key:String, value:Object):void
      {
        var bytes:ByteArray = new ByteArray();
        bytes.writeObject(value);
        EncryptedLocalStore.setItem(key, bytes);
      }

    ]]>
  </fx:Script>
</s:WindowedApplication>

registerClassAlias kannst du prinzipiell auch zu Startup aufrufen.

[Omega Psi]

Zitat von sytch

direktes casten hat bei mir auch nie funktioniert...

Doch das geht, siehe oben.

[Omega Psi]

Vergaß den Code:

protected function onApplicationCompleteHandler(event:FlexEvent):void
{
  var vo:ValueObject = new ValueObject();
  vo.name = "Fred";

  write("value", vo);
  var o:* = readAs("value");

  trace("toString :", o);
  trace("getQualifiedClassName:", getQualifiedClassName(o));
}

private function readAs(key:String):ValueObject
{
  var bytes:ByteArray = EncryptedLocalStore.getItem(key);
  return ValueObject(bytes.readObject());
}  
  
private function write(key:String, value:Object):void
{
  var bytes:ByteArray = new ByteArray();
  bytes.writeObject(value);
  EncryptedLocalStore.setItem(key, bytes);
}

Und bitte auch die Posts drüber lesen

[sytch]

na dann, wieder was gelernt...

[Nico B.]

Ola,

danke erstmal für den Code. (Funtzt alles soweit gut )


Ich stoße nur auf ein Problem:

Sobald ich die Applikation beende und wieder starte (und auf den Store zugreifen will) ist dieser Leer.

Ich frage mich jetzt, wieso das wohl so ist. Habe absolut keinen Ansatz, bisher hat das immer ohne Probleme geklappt.

Nutzen:
Würde gerne die X/Y Position der App speichern und a) keine lokale db/File anlegen und b) nocht 2 Werte (x,y) getrennt voneinander speichern.


Grüße Nico

Edit: Es scheint daran zu liegen, dass ich es nicht per writeUTFBytes hineinschreibe. Aber wie umgehe ich das am Besten?

[Omega Psi]

Works like a charm

<?xml version="1.0" encoding="utf-8"?>
<s:WindowedApplication xmlns:fx="http://ns.adobe.com/mxml/2009" 
                       xmlns:s="library://ns.adobe.com/flex/spark"
                       xmlns:mx="library://ns.adobe.com/flex/halo"
                       applicationComplete="applicationCompleteHandler(event)">
  <fx:Script>
    <![CDATA[

      import flash.events.MouseEvent;
      import flash.utils.ByteArray;

      import fs.domain.Data;

      import mx.events.FlexEvent;

      //-----------------------------------------------------------------
      //
      //     Constants
      //
      //-----------------------------------------------------------------

      private const KEY:String = "key";

      //-----------------------------------------------------------------
      //
      //     Properties
      //
      //-----------------------------------------------------------------

      private var _data:Data;

      //-----------------------------------------------------------------
      //
      //     Methods
      //
      //-----------------------------------------------------------------
      
      private function read():Data
      {
        var bytes:ByteArray = EncryptedLocalStore.getItem(KEY);

        if (bytes)
        {
          return Data(bytes.readObject());
        }

        return new Data();
      }

      private function write(data:Data):void
      {
        var bytes:ByteArray = new ByteArray();
        bytes.writeObject(data);
        EncryptedLocalStore.setItem(KEY, bytes);
      }

      //-----------------------------------------------------------------
      //
      //     Event Handler
      //
      //-----------------------------------------------------------------

      protected function applicationCompleteHandler(event:FlexEvent):void
      {
        _data = read();
        input.text = _data.content;
      }

      protected function deleteButton_clickHandler(event:MouseEvent):void
      {
        EncryptedLocalStore.removeItem(KEY);
      }

      protected function saveButton_clickHandler(event:MouseEvent):void
      {
        _data.content = input.text;
        write(_data);
      }

    ]]>
  </fx:Script>

  <s:layout>
    <s:VerticalLayout horizontalAlign="center" />
  </s:layout>

  <s:HGroup height="24" verticalAlign="middle" width="100%">
    <s:Label id="dataLabel" text="data.content" />
    <s:TextInput id="input" />
    <s:Button id="saveButton" click="saveButton_clickHandler(event)" label="save" />
    <s:Button id="deleteButton" click="deleteButton_clickHandler(event)" label="delete" />
  </s:HGroup>  

</s:WindowedApplication>

package fs.domain
{

  import flash.events.Event;
  import flash.events.EventDispatcher;
  import flash.events.IEventDispatcher;

  [RemoteClass("fs.domain.Data")]
  public class Data extends EventDispatcher
  {

    private var _content:String;

    [Bindable("contentChanged")]
    public function get content():String
    {
      return _content;
    }

    public function set content(value:String):void
    {
      if (!value)
      {
        value = "";
      }
      if (_content == value)
      {
        return;
      }
      _content = value;
      dispatchEvent(new Event("contentChanged"));
    }

    public function Data(target:IEventDispatcher=null)
    {
      super(target);
    }
  }
}

[Omega Psi]

Et les sources...

[Nico B.]

Ola,

werd mir das mal über's WE alles reinziehen. Danke soweit (echt super von Dir)


Grüße, nico