AS3-Projekt als AIR-Applikation

[Bastl-Wastl]

Hallo Leute,

wir versuchen gerade, ein reines AS3-Projekt als AIR-Applikation zum Laufen zu bekommen. Die einzigen brauchbaren Lösungsansätze aus dem Netz waren:

• phi² Flex Builder:AIR aus ActionScript-Projekt erstellen.
• Ted On Flash: Configuring ActionScript-Only AIR projects with Flash Builder 4

Wir haben mal die 1. Lösung versucht zu implementieren. Als MeinBaseClass haben folgenden Code genutzt:

package
{
	import flash.display.MovieClip;
	import flash.text.TextField;
	
	public class MeinBaseClass extends MovieClip
	{
		public function MeinBaseClass()
		{			
			var tf:TextField = new TextField();
			tf.text = "Hello Flex/Flash Builder";
			addChild(tf);
		}
	}
}

Auf der Anzeigefläche (stage) kommt es zu Größenprobleme. Es wirkt so, als wären alle Inhalte skaliert, obwohl scaleX und scaleY auf 1 gesetzt sind. Außerdem wird MeinBaseClass nur am linken Rand angezeigt, sofern man das Fenster nach unten/oben vergrößert.

Hier seht ihr noch die MeinAIR-Klasse, welche unsere MeinBaseClass aufruft und einbindet:

package
{
	import flash.desktop.NativeApplication;
	import flash.display.NativeWindow;
	import flash.display.NativeWindowInitOptions;
	import flash.display.Sprite;
	import flash.events.Event;
	
	//[SWF(backgroundColor="0x003772", width="800", height="600", frameRate="30")]  // <<-- Kommentiert dies mal ein und schaut euch den trace an =) 
	public class MainAIR extends Sprite
	{
		private var proj:MyApplication;
		private var meinFenster:NativeWindow;

		public function MainAIR()
		{
			var options:NativeWindowInitOptions = new NativeWindowInitOptions();
			options.resizable = true;
			
			this.meinFenster = new NativeWindow(options);
			meinFenster.width = 800;
			meinFenster.height = 600;
			meinFenster.activate(); 
			meinFenster.x = 0;
			meinFenster.y = 0;
			//meinFenster.maximize();
			
			proj =  new MyApplication();
		
			var stagecolor:Sprite = new Sprite();
			stagecolor.graphics.beginFill(0xFF0000);
			stagecolor.graphics.drawRect(0,0,meinFenster.stage.stageWidth, meinFenster.stage.stageHeight);
			stagecolor.graphics.endFill();
			
			meinFenster.stage.addChild(stagecolor);
			meinFenster.stage.addChild(this.proj);
			meinFenster.stage.addEventListener(Event.RESIZE, onRezise);
			meinFenster.addEventListener("close", closedWindow);
			
			trace(stage.stageWidth + " x " + stage.stageHeight);
		}
		private function onRezise(evt:Event):void
		{
			trace(stage.width);
		}
		
		private function closedWindow(e:Event):void
		{
			NativeApplication.nativeApplication.exit();
		}
	}
}

Alternativ dazu haben wir noch die Möglichkeit ausprobiert:

stage.nativeWindow.activate();
stage.stageWidth = 800;
stage.stageHeight = 600;

Dabei war das Problem, dass wir keine NativeWindowOptions (MainAir-app.xml) zur Verfügung haben. Ansonsten war das Ergebnis bei dieser Alternative, auf den ersten Blick, bzgl. der missglückten Größenverhältnisse recht gut.

Vielleicht kennt jemand dieses Problem und/oder kann irgendwie helfen. Ziel ist es, seine reines AS3-Projekt (Ohne die Verwendung des Flex-Frameworks) als AIR-App releasen zu können.

Grüße und vielen Dank ;-)

[ANTICHRIST]

Hey ho.

Hast Du folgendes mal versucht

PHP-Code:

meinFenster.stage.scaleMode = StageScaleMode.NO_SCALE;
meinFenster.stage.align = StageAlign.TOP_LEFT; 


Zu dem phi²-Artikel: Mittlerweile hab ich festgestellt, daß das eigentlich noch einfacher geht, nämlich indem Du beim Projekt-Setup einfach direkt auf, in deinem Falle, "MainAir.as" umänderst. Dann brauchst Du hinterher nicht in irgendwelchen XML-Dateien rumkriechen

Muss ich bei Gelegenheit mal aktualisieren.