Alle Fenster schließen

[Robbyn]

Hy, ich habe da mal eine Frage, wenn ich z.b. in einer Anwendung 2-3 Air Fenster aufhabe und z.b. in der Hautpanwendung auf einen Button klicke, geht es dann das ich sage kann, schließe mir alle Fenster die offen sind?

Grüße
Robbyn

[Dodge]

Du müsstest doch wissen, welche Fenster offen sind. Schließe diese doch einfach in deinem code.

[Robbyn]

Aber was ist wenn diese Fenster nicht in der Hautpanwendung iniialisiert worden sind, sondern z.b. in einem Content, dann habe ich darauf kein Zugriff.

[Dodge]

Dann würde ich mir eine Klasse mit Singleton anlegen, in der die Referenzen zu den aktiven Fenstern verwaltet werden können. Wenn man ein neues Fenster erstellt, übermittelt man einfach die Referenz an diese Klasse.

[Robbyn]

Wir würde so etwas aussehen, kann mir leider darunter nichts wirklich vorstellen?

[DabelDirk]

Zitat von Robbyn

Wir würde so etwas aussehen, kann mir leider darunter nichts wirklich vorstellen?

Zum Beispiel:

PHP-Code:

package
{
    public class MyClass
    {
        private static var _instance:MyClass;
        
        public var myWindows:Array = new Array();

        public function MyClass()
        {
            if(_instance!=null)
            {
                throw new Error("MyClass already exists!!");
            }
        }

        public static function getInstance():MyClass
        {
            if(!_instance)
            {
                _instance = new MyClass();
            }
            return _instance;
        }
    }
} 


Auftruf:

var myClass:MyClass = MyClass.getInstance();

dann zb.:

myClass.myWindows.push(firstWindow);

Das sollte dich auf den Weg bringen

[Robbyn]

Jo danke, hilft mir sehr weiter

[Martin Kraft]

Dank der get-Syntax sollte einen Singleton-Implementierung in AS3 eher so aussehen:

package {
   public class Singleton {
 
      private static var _instance:Singleton = null;
 
      public function Singleton(se:SingletonEnforcer) {
         if(se === null) {
            throw new Error('Singleton kann nicht direkt erstellt werden. Verwende Singleton.instance');
         } 
      }
 
      public static function get instance():Singleton {
         if(_instance === null) {
            _instance = new Singleton(new SingletonEnforcer() );
         }
         return _instance;
      }
 
   }
}
 
internal class SingletonEnforcer {} 

Und kann dann einfach so angesprochen werden:

Singleton.instance; 

Wenn man dann aber eh direkt auf das Array zugreift, kann man sich IMHO den Singleton auch schenken und einfach mit einem static-deklarieren Array arbeiten:

package {
    public class Storage {
 
        public static var windows:Array = [];
 
    }
} 

Der Zugriff sähe dann so aus:

Storage.windows.push(this);
 
trace("Meine Fenster: " + Storage.windows.join(", ") ); 

[DabelDirk]

Danke Martin für die Verbesserung

[Martin Kraft]

Zitat von DabelDirk

Danke Martin für die Verbesserung

War wirklich nicht belehrend gemeint. Deine (wahrscheinlich aus Java stammende) Implementierung ist ja nicht falsch - in AS3 geht's nur eben etwas eleganter

[Robbyn]

Danke dir Martin, aber die herangehensweise von DabelDrik hat mir schon gezeigt wie es ungefair aussehen sollte, mehr braucht ich nicht, wollte ja auch keine fertige Lösung sondern nur ein kleinen Denkanstoß. Aber dennoch danke an euch beiden für die Lösungsansätze

[DabelDirk]

Zitat von Martin Kraft

War wirklich nicht belehrend gemeint. Deine (wahrscheinlich aus Java stammende) Implementierung ist ja nicht falsch - in AS3 geht's nur eben etwas eleganter

Java nicht. Ich komme von C#.

Ja. Ist eleganter. Insbesondere das mit dem "SingletonEnforcer"
Musst mir schon den Kopf kratzen, was das jetzt genau soll. Aber dann dachte ich mir, wenn man im Team an Projekten arbeitet macht das schon Sinn den Konstruktor gar nicht benutzen zu können.

[DabelDirk]

Zitat von Robbyn

[...]wollte ja auch keine fertige Lösung sondern nur ein kleinen Denkanstoß[...]

Das sollte es sein (deshalb war ich auch etwas schludrig und hab z.B. das Array public gemacht.)