AIR für android - Stream abspielen!

[_-danie-_]

Hi,

ich bin schon mehrere Tage damit beschäftigt aber iwie will das alles nicht so wie ich will :P
wäre cool wenn mir jemand helfen könnte!

Ich versuche eine app für android zu bauen die einen Stream abspielt, dies funktioniert auch so weit ohne Probleme.
Ich hab einen "play-Button" und einen "Stop-Button", auf dem PC kann ich den Stream beliebig oft starten und stoppen nur auf dem Smartphone kann ich den Stream nur 2-mal abspielen danach muss ich die app schließen um wieder etwas zu hören!

Hier mal mein AS3-Code:

import flash.media.Sound;
import flash.net.URLRequest;
import flash.events.MouseEvent;
import flash.events.Event;
import flash.events.ProgressEvent;
import flash.events.IOErrorEvent;
import flash.media.SoundChannel;

var sound:Sound;
var channel:SoundChannel;
var lastPosition:int;
var i = '1';

play_btn.addEventListener(MouseEvent.CLICK, Click_play);
stop_btn.addEventListener(MouseEvent.CLICK, Click_stop);

function Click_play(event:MouseEvent):void {
	if(i == 1) {
		sound = new Sound();
		sound.addEventListener(Event.OPEN, onOpen);
		sound.addEventListener(ProgressEvent.PROGRESS, onLoading);
		sound.addEventListener(IOErrorEvent.IO_ERROR, onError);
		sound.load(new URLRequest("meinStream.mp3"),new SoundLoaderContext(1000, true));
		channel = sound.play();
		i = '2';
	}
}

function Click_stop(event:MouseEvent):void {
	if(i == 2) {
		AUSGABE.text = "Stream Stop!";
		channel.stop()
		sound.close();
		i = '1';
	}
}

function onOpen(event:Event):void {
	AUSGABE.text = "Stream Play!";
}

function onLoading(event:ProgressEvent):void {
	trace((event.bytesLoaded/event.bytesTotal)*100);
}

function onError(event:IOErrorEvent):void {
	AUSGABE.text = "Stream kann nicht geladen werden! " + event.text;
}

[Silver_Surfer]

verusuch mal nach sound.close(),

sound = null;

[speedjunkie]

Hallo Silver_Surfer, hallo _-danie-_,

@ _-danie-_

wie empfängst Du Deinen Stream? (Wi-Fi, UMTS, GPRS, sonstiges)

Mach mal bitte ein Häkchen bei Permissions.

• ACCESS_NETWORK_STATE
• ACCESS_WIFI_STATE

Und schau mal, ob die Verbindung wegknickt…

Anmerkung:

Funktionen bzw. Event Handler Funktionen mit einem kleinen Buchstaben beginnen.
Dann die Variable i, die Du für die Statusabfrage nutzt, so wie es aussieht.
i wird meist als Zählervariable genutzt. Bei Dir ist i ohne Typisierung und dann kommt ein String, das ist nicht schön.
Dafür gibt es das Boolean Object das zwei Werte annehmen kann true oder false;

var flag:Boolean = true;
var flag:Boolean = false;
 
//oder 
var flag:Boolean = !0; //true
var flag:Boolean = !1; //false
 
//oder 32 Bit Datentyp ohne internes Vorzeichen-Bit
 
var flag:uint = 0;
var flag:uint = 1;
 
//ähnlich wie in C die keinen eigenen Datentyp für logische Werte hat. Kommt darauf an was man macht und wie advanced das Ganze sein soll. 
 

Wolltest Du die letzte Position wieder abspielen?

var lastPosition:int; 

import flash.media.Sound;
import flash.media.SoundChannel;
import flash.events.MouseEvent;
import flash.net.URLRequest;
import flash.events.Event;
import flash.events.IOErrorEvent;
import flash.events.ProgressEvent;
import flash.desktop.NativeApplication;
import flash.net.NetworkInterface;
import flash.net.NetworkInfo;
import flash.net.InterfaceAddress;
 
var snd:Sound,ch:SoundChannel,lastPosition:Number = 0, isPlaying:Boolean;
 
trace(isPlaying);
 
function init(url:String):void
{
    snd = new Sound(new URLRequest(url));
    snd.addEventListener(Event.OPEN, onOpen);
    snd.addEventListener(ProgressEvent.PROGRESS, onLoading);
    snd.addEventListener(IOErrorEvent.IO_ERROR, onError);
 
    play_mc.addEventListener(MouseEvent.CLICK, playSound);
    pause_mc.addEventListener(MouseEvent.CLICK, pauseSound);
    return;
}
 
function playSound(m:MouseEvent):void
{
    isPlaying || (isPlaying=true, ch=snd.play(lastPosition,uint.MAX_VALUE));
    return;
}
 
function pauseSound(m:MouseEvent):void
{
    lastPosition = ch.position;
    ch.stop();
    trace("lastPosition: " + ch.position);
    isPlaying = false;
    return;
}
 
function onOpen(e:Event):void
{
    trace("Stream Play!");
    return;
}
 
function onLoading(e:ProgressEvent):void
{
    trace(uint(e.bytesLoaded/e.bytesTotal*100));
    return;
 
}
 
function onError(e:IOErrorEvent):void
{
    trace("Stream kann nicht geladen werden! " + e.text);
    return;
}
 
function initNetworkInfo():void
{
    NativeApplication.nativeApplication.systemIdleMode = SystemIdleMode.KEEP_AWAKE;
    NetworkInfo.isSupported ? (trace("Netzwerk unterstützt"), showChanges(null), NetworkInfo.networkInfo.addEventListener(Event.NETWORK_CHANGE, showChanges) ) : trace("Netzwerk nicht unterstützt");
    return;
}
 
function showChanges(e:Event):void
{
    trace("neue Schnittstellen INFO:");
    var list:Vector.<NetworkInterface>  = NetworkInfo.networkInfo.findInterfaces();
    for each (var netInterf:NetworkInterface in list)
    {
        var addrStr:String = "";
        for each (var address:InterfaceAddress in netInterf.addresses)
        {
            addrStr = "\n\t adress " + address.address + 
             "\n\tbroadcast " + address.broadcast +
             "\n\t\ipVersion " + address.ipVersion + "\n";
        }
        
        var output:String = netInterf.name + " ::: " + netInterf.displayName +   
        " adress " + addrStr + 
        " mtu " + netInterf.mtu;
        trace(output);
    }
}
 
init('http://www.deine-domaine.de/mothers_secret_music_box_workeGroup.mp3');
initNetworkInfo();