2 kurze fragen zu drag and drop

[cargos]

hallo leute,

ich hab mal 2 fragen zu dem drag und drop event in Air (2.5)

- kann man ein bild von einer webseite direkt in ein Air app draggen und darstellen?

- kann man ein bild aus einem Air app direkt auf den desktop draggen und ablegen?

freue mich über antworten.
cargos

[Nico B.]

1. bin ich mir nicht sicher.
(Evtl. kannst Du per "Bild kopieren" es in die Zwischenablage holen und diese dann mit air auswerten. Aber wie gesagt, bin mir nicht sicher)

2. Ja, habe ich bereits 1-2 mal gemacht und klappt super. Musst Du mal googlen, gehört zu den "Standard Anfänger Tutorials" für air.


grüße, nico

[cargos]

Zitat von Nico B.

2. Ja, habe ich bereits 1-2 mal gemacht und klappt super. Musst Du mal googlen, gehört zu den "Standard Anfänger Tutorials" für air.

punkt 2. ist erledigt! danke dir!

1. bin ich mir nicht sicher.
(Evtl. kannst Du per "Bild kopieren" es in die Zwischenablage holen und diese dann mit air auswerten. Aber wie gesagt, bin mir nicht sicher)

punkt 1.:
also es geht mir um das direkte drag und drop ohne "Bild kopieren".
falls da jemand etwas darüber weiss bitte antworten!

grüße
cargos

[thomas_E]

Google sei dank: Drag-n-Drop file into an AIR app « Brian Chau
nur gefunden, nicht getestet

[cargos]

Zitat von thomas_E

Google sei dank: Drag-n-Drop file into an AIR app « Brian Chau
nur gefunden, nicht getestet

das gilt aber nur für den desktop. ich suche eine möglichkeit direkt aus einer webseite/browser das bild ins Air app zu bekommen.

grüße

[thomas_E]

PHP-Code:

package 
{
    import flash.desktop.Clipboard;
    import flash.desktop.ClipboardFormats;
    import flash.desktop.NativeDragManager;
    import flash.display.Bitmap;
    import flash.display.BitmapData;
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.NativeDragEvent;
    
    /**
     * ...
     * @author Thomas Ersosi
     */
    public class Main extends Sprite 
    {
        private var s:Sprite;
        private var b:Bitmap;
        
        public function Main():void 
        {
            if (stage) init();
            else addEventListener(Event.ADDED_TO_STAGE, init);
        }
        
        private function init(e:Event = null):void 
        {
            removeEventListener(Event.ADDED_TO_STAGE, init);
            // entry point
            
            s = new Sprite();
            s.graphics.beginFill(0xEFEFEF);
            s.graphics.drawRect(0,0,stage.stageWidth, stage.stageHeight);
            s.addEventListener(NativeDragEvent.NATIVE_DRAG_ENTER, doDragEnter);
            s.addEventListener(NativeDragEvent.NATIVE_DRAG_DROP, doDragDrop);
            addChild(s);
            
            b = new Bitmap();
            b.x = b.y = 5;
            addChild(b);
        }
        
        private function doDragEnter(e:NativeDragEvent):void 
        {
            if (e.clipboard.hasFormat(ClipboardFormats.BITMAP_FORMAT)) {
                NativeDragManager.acceptDragDrop(s);
                
            }else {
                trace(e.clipboard.formats);
            }
        }

        private function doDragDrop(e:NativeDragEvent):void 
        {
            b.bitmapData = e.clipboard.getData(ClipboardFormats.BITMAP_FORMAT) as BitmapData;
        }
    }
} 


evtl solltest du noch eine Unterstützung für base64-kodierte Bilder ergänzen

[cargos]

danke für das feedback.

ich konnte gerade noch andere browser testen.
ergebnis: im Firefox funktioniert das draggen direkt aus der webseite in ein Air app.
Opera 11.52 und Internet Explorer unterstützen das leider nicht.

[Nico B.]

Wahrscheinlich weil Firefox das Bild, während des dragen, temporär in den Zwischenspeicher knallt - die anderen jedoch nicht.


oder?

[thomas_E]

Opera 11.52 und Internet Explorer unterstützen das leider nicht

also, im IE läuft es bei mir (*bedingt), Opera, Chrome und Safari hab ich hier grad nicht.

*bedingt heisst, es funktioniert bei mir, wenn das Bild nicht verlinkt ist; wenn es verlinkt ist, kopiert er scheinbar nur den Link in den Speicher, nicht das Bild. (FF kopiert beides, dazu noch ne html-version und afaik ne rtf-Version des Links, sowie den html-Code als String)
Rechtsklick -> Bild anzeigen -> nun kann ich das Bild auch im IE draggen (ist aber unzumutbar)