Zugriff aus .as Datei auf Variablen aus .fla?

[primate]

Hallo nochmal folgendes eigentlich simples Problem hat sich mir aufgetan:

Ich habe ein .fla Datei test.fla in dieser erstelle ich ein Array:

var liste:Array=new Array();

Ebenfalls habe ich eine .as Datei(Klasse) pictureLoader.as welche auf die Datei test.fla zielt.
Diese Datei(KLasse) pictureLoader wird auch in der Datei test.fla aufgerufen:

var myLoader=new pictureLoader();
addChild(myLoader);

Der Inhalt der Klasse pictureLoader ist folgender:

package {
   import flash.display.Sprite;
   import flash.events.*;
   import flash.net.URLLoader;
   import flash.net.URLLoaderDataFormat;
   import flash.net.URLRequest;
   
   public class pictureLoader extends Sprite{
	   
	   public function pictureLoader(){
	   
	   var request:URLRequest=new URLRequest("pictures.txt");
	   var loader:URLLoader=new URLLoader();
	   loader.load(request);
	   
	   loader.addEventListener( Event.COMPLETE, handleComplete );
	   
	   loader.dataFormat = URLLoaderDataFormat.TEXT; 
   	   }
	   
	   public function handleComplete(event:Event){
		   
	   var loader:URLLoader = URLLoader(event.target); 
	   var results:Array=loader.data.split(/&/);
	   return results;
	   }
		   
   }
}

Der Inhalt der Datei pictures.txt lautet schlicht und einfach:

ground.jpg&smili.jpg&test.jpg

Nun würde ich gerne das Array results welches durch das splitten in die einzelnen Dateinamen entsteht in das Array liste übertragen, damit ich die Dateinamen durch as3 in der Datei test.fla weiterverarbeiten kann.

Ich hoffe nun habe ich mein Anliegen klarer geschildert.

lg primat

[hgseib]

du hast doch schon alles!!??

public function handleComplete(event:Event){
var loader:URLLoader = URLLoader(event.target);
var results:Array=loader.data.split(/&/);
// so wie du hier das array in results schreibst, so kannst du das auch in jede andere zu diesem zeitpunkt bekannte variable schreiben bzw. funktion übergeben.

return results;
// ein event gibt nichts zurück. wohin sollte dieses auch was zurückgeben? an den server?
}

[primate]

Ja klar ich kann es an jeder global Variable im package übergeben was ich jetzt auch mache.

Nur wenn ich aus dem Hauptfilm auf diese Variable durch

myLoader.liste

oder:

myLoader.returnListe (die Function returnListe macht nicht als

return liste;

)

zugreifen will kommt folgender Fehler.
ReferenceError: Error #1069: Eigenschaft returnListe für pictureLoader nicht gefunden und es ist kein Standardwert vorhanden.
at dynamischerLoader_fla::MainTimeline/frame1()

weswegen?

[hgseib]

ich sehe nicht ob und wann du etwas in myLoader.liste reinschreibst. nicht an den scriptfetzen, die du veröffentlicht hast.
wenn nichts drinn ist, dann kann man auch nichts rausholen.

und zugriff hast du sowieso erst, wenn zeitlich gesehen:
handleComplete
aufgerufen wurde. vorher ist auch noch nichts da.

[primate]

-.- das Problem war das weder de Variable liste noch die funktion returnListe public waren -.- ziemlich dummm....

aber das von dir angesprochene Problem habe ich immer noch... wie kann ich denn warten bis handleComplete aufgerufen wurde??

[hgseib]

Zitat von primate

wie kann ich denn warten bis handleComplete aufgerufen wurde??

ei genau dafür ist doch das event da. zeitlich nach handleComplete ist das zeugs angekommen. und dann kannst du es benützen. ab dem zeitpunkt ab dem handleComplete aufgerufen wurde. der computer wartet für dich - in der zwischenzeit kannst 'du' andere sachen machen. wenns dann soweit ist, dann wirft der computer das event.
man kann nicht eher in den zug einsteigen, als dass der im bahnhof angekommen ist. irgendwann heisst es dann (event) 'bitte einsteigen' und dann kann man halt.

wenn du deinen kaosladen nicht im griff hast ;-) dann musst du halt vorher testen, ob die sachen existieren, die du benützen willst:

if (myLoader && myLoader!=null) {
  // existiert und da scheint was drinn zu sein
  if (myLoader.returnListe && myLoader.returnListe!=null) {
    // juchhu, da isses
    trace(myLoader.returnListe);
  } else {
    // kein myLoader.returnListe, was soll dann passieren?
  }
} else {
  // kein myLoader, was soll dann passieren?
}

[thomas_E]

um das ganze an dieser Stelle etwas abzukürzen:

package {
    import flash.events.EventDispatcher;
    import flash.events.Event;
    import flash.net.URLLoader;
    import flash.net.URLLoaderDataFormat;
    import flash.net.URLRequest;
 
    public class PictureLoader extends EventDispatcher
    {
        public static const DEFAULT_URL:String = "pictures.txt";
        
        private var _url:String;
        private var _liste:Array;
        
        public function get url():String {
            return _url;
        }
        
        public function get liste():Array {
            return _liste;
        }
        
        public function PictureLoader(url:String=null):void {
            this._url = ((url!=null && url!="")? url: DEFAULT_URL);
 
            update();
        }
 
        public function update():void {
            var loader:URLLoader = new URLLoader();
                loader.dataFormat = URLLoaderDataFormat.TEXT;
                loader.addEventListener(Event.COMPLETE, handleComplete);
                loader.load(new URLRequest(_url));
        }
        
        //wieso sollte diese Funktion denn public sein?
        private function handleComplete(e:Event):void {
            var loader:URLLoader = URLLoader(e.target);
            
            //split('&') vs. split(/&/)
            //ein String dürfte deutlich performanter sein alr eine RegExp.
            _liste = loader.data.split('&');
            dispatchEvent(new Event(Event.COMPLETE));
        }
    }
} 

und

var myLoader:PictureLoader = new PictureLoader();
    myLoader.addEventListener(Event.COMPLETE, onPicsLoaded);
 
function onPicsLoaded(e:Event):void {
    trace("Bilder geladen:", myLoader.liste);
    // Bitte jetzt das verarbeiten dieser Liste anstossen!!!
}
 
/*
myLoader.update();
myLoader.update();
myLoader.update();
*/ 

@primate: kannst du den Quelltext nachvollziehen?