xml parsen in actionscript 3 - tiefere bäume

[javaFlasher]

Hallo,
ich bin dabei einen xml-baum zu parsen. Ich habe bisher nicht herausgefunden, wie ich selbst einfach nur die Kinder der nächsten Ebene bekomme, um selber danach weiter runterzugehen , indem ich für jeden Knoten dann selbst noch eine Schleife mache. Ich finde immer nur Beispiele für eine XML-Datei mit einer Generation von Kindern. Wenn ich bei meiner verschachtelten XML-Datei das anwende, bekomme ich immer die gesamten Generationen unter einem Tag. Ich will aber nur die nächste bekommen und dann mir jedes einzeln angucken, um dann von jedem einzeln wieder weiter runter zu gucken.
Ist das verständlich ausgedrückt?
Wäre sehr dankbar, wenn mir jemand helfen könnte.
Vielen Dank,
java F.

[rudi66]

Gibt viele Mittel und Wege,
hier mal ein uralter Schnipsel von mir...

Adobe beschreibt aber in der Hilfe das Parsen von komplexen XML
mit den neuen Kurzformen:
XML (ActionScript 3.0)

var result:XML = XML((event.target as URLLoader).data);            
			
			var myXML:XMLDocument=new XMLDocument();
			myXML.ignoreWhite=true;
			myXML.parseXML(result.toXMLString());
			
			/*
			<data>
				<category id="1">
					<name><![CDATA[Name]]></name>
					<subitem id="9">sub 1-1</subitem>
					<subitem id="4">sub 2-1</subitem>
				</category>	
			*/
			
			var node:XMLNode=myXML.firstChild;
			var n:int=int(node.childNodes.length);
			
			for(var j:int=0;j<n;j++)
			{
				if (node.childNodes[j].nodeName=="category")
				{
					var obj:Object=new Object();
					obj.id=result..@id[j];						
					obj.catname=result.category[j].catname;					
					obj.subcats=[];
					
					var sub:int=int(node.childNodes[j].childNodes.length);					
					for(var p:int=0;p<sub;p++)
					{
						if (node.childNodes[j].childNodes[p].nodeName=="subitem")
						{
							var mysubcat:Object=new Object();							
							mysubcat.subcatname=node.childNodes[j].childNodes[p].firstChild.nodeValue;
							mysubcat.id=(node.childNodes[j].childNodes[p].attributes['subid']);
							obj.subcats.push(mysubcat);	
						}
					}
					
				}
			}

[joeydee]

Man kann ganz einfach rekursiv parsen:

var myXml:XML=
<data>
    <category id="1" test="bla">
        <name><![CDATA[Name]]></name>
        <subitem id="9">sub 1-1</subitem>
        <subitem id="4">sub 2-1</subitem>
    </category>
</data>
;
 
 
parseRecursive(myXml);
 
function parseRecursive(xml:XML,ebene:int=0){
    trace("Ebene: "+ebene);
    trace("  Knoten: "+xml.name());
    trace("  Attribute: ");
    for each(var a:XML in xml.attributes())trace("    "+a.name()+"="+a);
    trace("  Inhalt: "+xml.text());
    for each(var child:XML in xml.children())if(child.name())parseRecursive(child,ebene+1);
    } 
 

[Omega Psi]

Generisch:

function traverse(xml:XML):void
{
    var children:XMLList = xml.children();
 
    for each(var child:XML in children)
    {
        traverse(child);
    }
} 
 

Wenn du nach bestimmten Knoten suchst, würde ich E4X (analog zu XPath) nutzen.

[javaFlasher]

wow, eine antwort besser als die andere. vielen dank euch allen! das hat mich schritt für schritt weiter gebracht.