Verschwindene MovieClips | Ersetzt

[Prinzvalium]

Moin,

ich habe ein kleines Problem. Simpel gesagt: Ich lade ein jpg, schmeiße es in nen MovieClip und haue denn auf die Bühne - soweit so gut. Wenn ich genau das gleiche noch mal mache, verschwindet der MovieClip von vorher. Hier mein Code:

var loader:Loader = new Loader();
var url:URLRequest;

//Red Knobs

loader.load( new URLRequest("/GUI/knob_red.jpg") );
loader.contentLoaderInfo.addEventListener(Event.COMPLETE, load_red_knob);

function load_red_knob(e)
{
	var red_knobs:Array = new Array();
	
	red_knobs[0] = new MovieClip();
	red_knobs[0].addChild(loader);
	this.addChild(red_knobs[0]);
        //Bis hier alles gut
	
	red_knobs[1] = new MovieClip();
        //Jetzt auch noch
	red_knobs[1].addChild(loader); //Sobald das hier ausgeführt wird, verschwindet der MovieClip von oben.
	this.addChild(red_knobs[1]);
        //Zweiter MovieClip auf der Bühne. Der erste ist weg.

}

Warum wird kein neuer MovieClip erstellt bzw. warum wird er ersetzt?
Und wie kann ich das umgehen?

Fragen über fragen..

Viele Grüße,
PrinzValium

[thomas_E]

Warum wird kein neuer MovieClip erstellt bzw. warum wird er ersetzt?

es wird ein neuer MovieClip erstellt, aber kein neuer Loader.
es wird der alte Loader in einen neuen Movieclip gepackt, und der alte MC bleibt leer auf der Bühne zurück.

• in AS ist für Funktions- und Variablennamen lowerCamelCase üblich
• bitte Variablen, Funktionen und auch Funktions-parameter Typisieren. Du tust dir damit einen Gefallen, nicht uns.
• wozu das red_knobs Array? versteh den Sinn nicht.
• ein MC ist an der Stelle überdimensioniert. Sprites reichen da vollkommen aus.
• bitte erst Event-Listener hinzufügen, dann das laden starten.

PHP-Code:

var loader:Loader = new Loader();
    loader.contentLoaderInfo.addEventListener(Event.COMPLETE, loadRedKnob);
    loader.load( new URLRequest("/GUI/knob_red.jpg") );

function loadRedKnob(e:Event):void
{
    var b:Bitmap = Bitmap(loader.content);
    var mc1:Sprite = new Sprite();
        mc1.addChild(b);
    addChild(mc1);
    
    var b2:Bitmap = new Bitmap(b.bitmapData);    //neues Bitmap, selbes BitmapData-Objekt
    var mc2:Sprite = new Sprite();
        mc2.addChild(b);
    addChild(mc2);
}


//verkürzt:
function loadRedKnob(e:Event):void
{
    var bd:BitmapData = Bitmap(loader.content).bitmapData;
    for(var i:int; i<2; ++i){
        var mc:Sprite = new Sprite();
            mc.addChild(new Bitmap(bd));
        addChild(mc);
    }
} 


[Martin Kraft]

Wozu überhaupt ein MovieClip oder Sprite? Man kann doch auch einfach direkt das Bitmap auf die Bühne legen!

[Prinzvalium]

Ich habe das jetzt so gelöst:
Vielen Dank an dieser Stelle. :]

var loader:Loader = new Loader();
var url:URLRequest;

//Red Knobs
loader.contentLoaderInfo.addEventListener(Event.COMPLETE, loadRedKnob);
loader.load( new URLRequest("/GUI/knob_red.jpg") );

function loadRedKnob(e:Event):void
{
	var red_knobs:Array = new Array();
	var bd:BitmapData = Bitmap(loader.content).bitmapData;
	
	red_knobs[0] = new Sprite();
	red_knobs[0].addChild(new Bitmap(bd));
	this.addChild(red_knobs[0]);
	
	red_knobs[1] = new Sprite();
	red_knobs[1].addChild(new Bitmap(bd));
	this.addChild(red_knobs[1]);

}

Zitat von thomas_E

• wozu das red_knobs Array? versteh den Sinn nicht.
  

Ich packe die in ein Array, damit ich sie alle einzelnt ansprechen kann (als Buttons). Und will die in eine for-Schleife packen um eine bestimmte anzahl zu erstellen. Die beiden Blöcke habe ich nur gemacht, um erst mal zu probieren.

Grüße,
PrinzValium