VerifyError: Error #1014

[gregmasterl]

Hi,

ich habe folgendes Problem. Ich habe eine Promowebseite in AS3 erstellt welches ich über die Flash IDE Compiliere. Alles schön sauber über die Dokumentenklasse Main.as in in der obersten Package Ebene.

Alles wunderbar soweit ( bis auf das lehme compilieren per IDE ).
Wenn ich jetst den Hauptfilm Main.swf mit der Dokumentenklasse Main.as per Loader laden will kommt folgende Meldung: VerifyError: "Error #1014: Klasse Main wurde nicht gefunden. at global$init()"

Was bedeutet das? Ich habe nirgends nur einen hauch von Ansatz gefunden. Er läd das ding und schmeisst mir diese Meldung um die Ohren mit der ich nix anfangen kann. Die Imports sind die selben. Einige MCs sind auch doppelt aber keine Klasse wird doppelt verwendet. Selbst wenn dürfte es ja kein Problem sein weil sich das Ganze ja in 2 verschiedenen Classen abspielt.

Jemand eine Idee? Danke im voraus.

[hmpf]

zeig mal Code

[gregmasterl]

Preloader.as:

PHP-Code:

package  
{
    import gs.OverwriteManager;
    import gs.TweenLite;
    import gs.easing.Quad;
    import gs.plugins.RemoveTintPlugin;
    import gs.plugins.TintPlugin;
    import gs.plugins.TweenPlugin;

    import flash.display.Loader;
    import flash.display.MovieClip;
    import flash.events.Event;
    import flash.events.IOErrorEvent;
    import flash.events.ProgressEvent;
    import flash.net.URLRequest;    

    public class Preloader extends MovieClip 
    {
        // Elements
        private var _flasche:MovieClip;
        private var _bottle_volumen:MovieClip;
        private var _liquid:MovieClip;
        private var _cap:MovieClip;

        // Loader
        private var _loader:Loader;

        public function Preloader()
        {
            // Settings
            TweenPlugin.activate( [TintPlugin, RemoveTintPlugin] );
            OverwriteManager.init( OverwriteManager.AUTO );
            
            // Setup
            setup( );
        }

        private function setup():void
        {
            // -------| Elements |----------------------------------------
            _flasche = this.getChildByName( 'flasch_clip' ) as MovieClip;
            _bottle_volumen = _flasche.getChildByName( 'bottle_volume_mc' ) as MovieClip;
            _liquid = _flasche.getChildByName( 'liquid_mc' ) as MovieClip;
            _cap = _flasche.getChildByName( 'cap_mc' ) as MovieClip;
            _cap.y = -400;
            
            // -------| Loader |----------------------------------------
            _loader = new Loader( );
            _loader.contentLoaderInfo.addEventListener( Event.COMPLETE, loadComplete );
            _loader.contentLoaderInfo.addEventListener( ProgressEvent.PROGRESS, loadProgress );
            _loader.contentLoaderInfo.addEventListener( IOErrorEvent.IO_ERROR, loadError );
            _loader.contentLoaderInfo.addEventListener( IOErrorEvent.NETWORK_ERROR, loadError );
            _loader.load( new URLRequest( 'Main.swf' ) );
            //addChild( _loader );
            // -----------------------------------------------------------
        }

        private function loadError( e:IOErrorEvent ):void
        {
            trace( 'LOAD ERROR: ' + e.text );
            removeEvents( );
        }

        private function loadProgress( e:ProgressEvent ):void
        {
            var scale:Number = e.bytesLoaded / e.bytesTotal; 
            _bottle_volumen.scaleY = scale;
            trace( 'LOADED: ' + scale * 100 );
        }

        private function loadComplete( e:Event = null ):void
        {
            trace( 'LOAD COMPLETE!!!' );
            removeEvents( );
            addChild( _loader.content );

            TweenLite.to( _cap, 2, { y:-53, ease:Quad.easeIn, onComplete:_liquid.play } );
            TweenLite.to( _bottle_volumen, 2, { tint:'0xFCBD4F', delay:2 } );
            TweenLite.to( _bottle_volumen, 3, { alpha:1, delay:4 } );
            TweenLite.to( _liquid, 3, { autoAlpha:0, delay:8, onComplete:_liquid.stop } );
        }

        private function removeEvents():void
        {
            if( _loader != null )
            {
                _loader.contentLoaderInfo.removeEventListener( Event.COMPLETE, loadComplete );
                _loader.contentLoaderInfo.removeEventListener( ProgressEvent.PROGRESS, loadProgress );
                _loader.contentLoaderInfo.removeEventListener( IOErrorEvent.IO_ERROR, loadError );
                _loader.contentLoaderInfo.removeEventListener( IOErrorEvent.NETWORK_ERROR, loadError );
            }
        }
    }
} 


Main.as

PHP-Code:

package
{
    import gs.OverwriteManager;
    import gs.TweenLite;
    import gs.easing.Quad;
    import gs.plugins.BlurFilterPlugin;
    import gs.plugins.RemoveTintPlugin;
    import gs.plugins.TintPlugin;
    import gs.plugins.TweenPlugin;
    
    import de.cap.data.Contents;
    import de.cap.elements.PicHolder;
    import de.cap.elements.ProduktClip;
    import de.cap.particles.Particles;
    
    import flash.display.MovieClip;
    import flash.events.Event;    

    public class Main extends MovieClip
    {
        private var _particles:Particles;
        private var _wellen:MovieClip;
        private var _logo:MovieClip;
        private var _produktKarusell:MovieClip;
        private var _flashe:MovieClip;
        private var _drinkSystem:MovieClip;
        private var _drinkHolder:PicHolder;
        private var _heading:MovieClip;

        private var _xmlPath:String = 'xml/';
        private var _lang:String;

        private var contents:Contents = Contents.getInstance( );

        public function Main()
        {
            stop( );
            setup( 'en' );
        }

        public function setup( lang:String = 'en' ):void
        {
            _lang = lang;
            
            TweenPlugin.activate( [TintPlugin, RemoveTintPlugin, BlurFilterPlugin] );
            OverwriteManager.init( OverwriteManager.AUTO );
            
            contents.addEventListener( Event.COMPLETE, onXML );
            contents.load( 'navis', _xmlPath + _lang + '/navi.xml' );
            contents.load( 'products', _xmlPath + _lang + '/products.xml' );
            contents.load( 'pages', _xmlPath + _lang + '/pages.xml' );
            
            // -------| Elements |-----------------------------------------
            _wellen = this.getChildByName( 'wellen_mc' ) as MovieClip;
            _logo = this.getChildByName( 'logo_clip' ) as MovieClip;
            _flashe = this.getChildByName( 'flasch_clip' ) as MovieClip;
            _produktKarusell = this.getChildByName( 'produktKarusell' ) as MovieClip;
            _drinkSystem = this.getChildByName( 'drinkSystem_clip' ) as MovieClip;
            _drinkHolder = _drinkSystem.getChildByName( 'holder' ) as PicHolder;
            _heading = this.getChildByName( 'heading' ) as MovieClip;
            
            _particles = new Particles( this );
            addChildAt( _particles, this.getChildIndex( _produktKarusell ) );
            // -----------------------------------------------------------
        }

        private function onXML( e:Event ):void
        {
            trace( 'CONTENTS LOADED!' );
            
            // top navi, first item label
            trace( contents.navis..navi.( @name == 'top' ).item[0].@label );
            
            // secound product name
            trace( contents.products..item[1].name.text( ) );
            
            // page discover, screen use, item 2, text 
            trace( contents.pages..screen.( @name == 'use' )..item[1].text.text( ) );
        }

        public function get wellen():MovieClip
        {
            return _wellen;
        }

        public function get particles():Particles
        {
            return _particles;
        }
    }
} 


[hmpf]

Ich kann den Fehler nicht reproduzieren (nachdem ich alles auskommentiert habe, was wegen fehlender Klassen etc. andere Fehler verursacht). In loadComplete() wird mir als e.target.content [object Main] ausgegeben.
Und warum

public class Preloader extends MovieClip 

? Wenn die Klasse kein MovieClip sein muß, dann sollte man besser Sprite nehmen.

[gregmasterl]

Hast du auch aus der Flash IDE Compiliert?

Wenn die Klasse kein MovieClip sein muß, dann sollte man besser Sprite nehmen.

Weil es ja Dokumentenklassen sind und die FLAs eventuell noch schlüsselbilder bekommen könnten. Möchte nur unnötige probleme verhindern.

[hmpf]

Ja, hab aus Flash CS3 compiliert.

[gregmasterl]

Hier ein Clip der schwierigkeiten macht! Dies ist die Untere Navi die ich per Verknüpfung die Klasse "de.cap.navi.Bottom" zugewiesen habe. Als Basisklasse ist "flash.display.MovieClip" eingetragen. In der Main.fla läuft das so! ( auch wenns nicht auskommentiert ist ) Aber wenn ich das ganze mit meine Preloader lade bekomme ich folgende Fehlmeldung:

ReferenceError: Error #1056: Eigenschaft b1 in de.cap.navi.Bottom kann nicht erstellt werden.
at flash.display::Sprite/flash.display:Sprite::constructChildren()
at flash.display::Sprite$iinit()
at flash.display::MovieClip$iinit()
at de.tapcap.navi::Bottom$iinit()
at flash.display::Sprite/flash.display:Sprite::constructChildren()
at flash.display::Sprite$iinit()
at flash.display::MovieClip$iinit()
at Main$iinit()

Was soll das denn? Die gesamte Funktion Setup ist auskommentiert und eigentlich alles...aber er sagt die eigenschaft b1 in de.cap.navi.Bottom???
Was soll das denn darstellen??? Ich bin echt am ende...

de.cap.navi.Bottom.as

PHP-Code:

package de.cap.navi 
{
    import gs.OverwriteManager;
    import gs.plugins.RemoveTintPlugin;
    import gs.plugins.TintPlugin;
    import gs.plugins.TweenPlugin;

    import flash.display.MovieClip;    

    public class Bottom extends MovieClip 
    {
        //private var _color:uint = 0xFF7B32;
        //private var _delay:Number = 3.5;

        public function Bottom()
        {
            TweenPlugin.activate( [TintPlugin, RemoveTintPlugin] );
            OverwriteManager.init( OverwriteManager.AUTO );
            
            //_setup( );
        }
//
//        private function _setup():void
//        {
//            
//            TweenLite.from( this, 1, { delay:3, autoAlpha:0, y:this.y + this.height } );
//            
//            for (var e:int = 1; e <= 6 ; e++) 
//            {
//                var el:MovieClip = this.getChildByName( 'b' + e ) as MovieClip;
//                var hit:Mask = new Mask( );
//                hit.contentH = 21 + 4;
//                hit.contentW = el.width + 4;
//                hit.top( -2 );
//                hit.right( 2 );
//                hit.alpha = 0;
//                el.addChild( hit );
//                el.buttonMode = true;
//                el.addEventListener( MouseEvent.MOUSE_OVER, onOver );
//                el.addEventListener( MouseEvent.MOUSE_OUT, onOut );
//                el.addEventListener( MouseEvent.CLICK, onClick );
//                
//                TweenLite.from( el, 1, { delay:e * .4 + _delay, autoAlpha:0, y:"30" } );
//            }
//        }
//
//        private function onOver( e:MouseEvent ):void
//        {
//            var item:MovieClip = e.currentTarget as MovieClip;
//            TweenLite.to( item, .1, { tint:_color } );
//        }
//
//        private function onOut( e:MouseEvent ):void
//        {
//            var item:MovieClip = e.currentTarget as MovieClip;
//            TweenLite.to( item, .2, { removeTint:true } );
//        }
//
//        private function onClick( e:MouseEvent ):void
//        {
//            var item:MovieClip = e.currentTarget as MovieClip;
//            TweenLite.to( item, .1, { removeTint:true } );
//            TweenLite.to( item, .1, { delay:.15, tint:_color } );
//        }
    }
} 


Edit:
b1 ist mein Erster MovieClip innerhelb des NaviBottom Clips. Er beinhaltet nur ein statisches Textfeld.
Wieso kann der denn nicht erstellt werden?

[gregmasterl]

Ich habe jetzt herausgefunden das dieser Fehler nur auftaucht wenn ich den Preloader mit Flash CS3 Compiliere. Jemand eine Ahnung? Ich habe alle Updated installiert aber es hat nichts gebracht. Die CS4 Stürzt immer ab wenn ich den FlashPlayer ausschalte. Wenn ich es mit CS4 mache gibt es keinen #1014 error! Es kommt nur ein Sandbox Error:

Error #2044: securityError unverarbeitet. text=Error #2048: Verletzung der Sicherheits-Sandbox: /Volumes/Daten HD/Projekte/Extenso/Flash3D/.metadata/.plugins/com.adobe.flash.profiler/ProfilerAgent.swf?host=localhost&port=9999 kann keine Daten von localhost:9999 laden.
at ProfilerAgent()[C:\SVN\branches\3.2.0\modules\profiler3\as\Profile rAgent.as:127]
Error #2044: securityError unverarbeitet. text=Error #2048: Verletzung der Sicherheits-Sandbox: /Volumes/Daten HD/Projekte/Extenso/Flash3D/.metadata/.plugins/com.adobe.flash.profiler/ProfilerAgent.swf?host=localhost&port=9999 kann keine Daten von localhost:9999 laden.
at ProfilerAgent/ioErrorHandler()[C:\SVN\branches\3.2.0\modules\profiler3\as\Profile rAgent.as:527]

Lustig nur das ich auf nem Mac arbeite und kein C:\ Laufwerk habe.