URLLoader Event.COMPLETE will nicht so ganz

[szylla]

hi,

ich hab grad mal eine frage.
und zwar, ich hab eine klasse, die extended EventDispatcher. in dieser klasse hab ich einen URLLoader und auf den loader hab ich mit addEventListener das Event.COMPLETE gesetzt. ich möchte halt eine externe datei laden und warten bis die fertig geladen ist. und genau das funktioniert nicht. aaber, wenn ich die klasse Sprite extenden lasse und nicht EventDispatcher und dann noch meine klasse mit addChild der DisplayList hinzufüge klappts!
wieso ist das so? und das ist natürlich keine lösung. ich hatte das nur per zufall beim testen erfahren. ich würde aber wieder gerne EventDispatcher extenden.

danke für eure hilfe,
szylla

[Omega Psi]

Was willst du laden?

[szylla]

z.B. eine txt datei... ganz simpel

edit: es geht ja wie gesagt auch, aber nur wenn ich die klasse mit dem loader mit addChild der displaylist hinzufüge?!

[Omega Psi]

Code?

[szylla]

PHP-Code:

package {
    
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.EventDispatcher;
    import flash.events.IOErrorEvent;
    import flash.net.URLLoader;
    import flash.net.URLLoaderDataFormat;
    import flash.net.URLRequest;
    import org.flashdevelop.utils.FlashConnect;

    public final class Test extends Sprite {

        public function Test():void { }
´
        public function load( path:String ):void {

            var urlLoader:URLLoader = new URLLoader();
                urlLoader.dataFormat = URLLoaderDataFormat.TEXT;
                urlLoader.addEventListener( Event.COMPLETE, this.onLoadComplete, false, 0, true );
                urlLoader.addEventListener( IOErrorEvent.IO_ERROR, this.onIOError, false, 0, true );
                urlLoader.load( new URLRequest( path ) );
        }
        
        private function onLoadComplete( e:Event ):void {
            
            FlashConnect.trace( "onLoadComplete" );
            
        }
        
        private function onIOError( e:IOErrorEvent ):void {
            
            FlashConnect.trace( "onIOError: " + e );
            
        }

        
    }
    
} 


so gehts wie gesagt... ich adde die klasse zur stage. ist ja auch ein sprite...

aber eigentlich wollte ich die klasse EventDispatcher extenden lassen und nicht adden.. was ja auch gar nicht geht.

so sieht der aufruf aus:

PHP-Code:

var test:Test= new Test();
                test.load( "test.txt" );
                
            addChild( test ); 


aber das addChild ist ja blödsinn in diesem fall.. das möchte ich nicht haben

[Omega Psi]

Die Klasse muss in dem Zustand noch gar nichts extenden. Ich denke, der Loader wird schon "garbage collected":

package {
    
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.EventDispatcher;
    import flash.events.IOErrorEvent;
    import flash.net.URLLoader;
    import flash.net.URLLoaderDataFormat;
    import flash.net.URLRequest;
    import org.flashdevelop.utils.FlashConnect;

    public final class Test extends EventDispatcher {

        var urlLoader:URLLoader
        public function Test():void { }
´
        public function load( path:String ):void {

            urlLoader = new URLLoader();
                urlLoader.dataFormat = URLLoaderDataFormat.TEXT;
                urlLoader.addEventListener( Event.COMPLETE, this.onLoadComplete, false, 0);
                urlLoader.addEventListener( IOErrorEvent.IO_ERROR, this.onIOError, false, 0);
                urlLoader.load( new URLRequest( path ) );
        }
        
        private function onLoadComplete( e:Event ):void {
            
            FlashConnect.trace( "onLoadComplete" );
            // remove event handlers
        }
        
        private function onIOError( e:IOErrorEvent ):void {
            
            FlashConnect.trace( "onIOError: " + e );
            // remove event handlers
        }

        
    }
    
}

Die "weak references" musst du nicht nutzen, da der URLLoader zusammen mit der Test Instanz gelöscht wird.

[Omega Psi]

Je nachdem, was du machen möchtest, müsste ich den Code noch mal anpassen: "mehrere Connections" vs "lade entweder oder".

[szylla]

hi,
ich weiß, das ist jetzt nur der erste grobe aufbau der klasse! da kommt später noch mehr rein weshalb ich die den eventdispatcher extenden lassen will. ich kann das extenden aber zum jetztigen zeitpunkt auch weglassen, es geht aber trotzdem nicht! ich komm einfach nicht ins onLoadComplete rein?!

[szylla]

oh man, du hattest recht. ich hab die drei letzten 3 params bei addEventListener weggelassen und schon gehts!

[Omega Psi]

Du erzeugst den URLLoader in einer Funktion. Wenn diese Funktion angelaufen ist, und es keine weiteren Referenzen auf die in den Funktion erzeugten Objekten gibt, werden diese von der Garbage Collection gelöscht. Und auch wenn du Event handler registriert hast, die eigentlich dafür sorgen dass die Referenz gehalten wird, so sorgt das letzte Argument dafür, dass die Objekte trotzdem gelöscht werden können.

[szylla]

kapiert, macht sinn! vielen dank

[Omega Psi]

Sehr gern.