TypeError #1010 - Kann damit jemand was anfangen?

[sille]

Hi!

Ich bekomme folgende Fehlermeldung:

#1010: Ein Begriff ist nicht definiert und hat keine Eigenschaften.

Kann damit aber leider nix anfangen.

Kann mir jemand sagen, wie ich den Fehler auf eine Zeile eingrenzen kann, oder findet jemand den Fehler?

Ich arbeite mit CS4 und Flashdevelop

Hier der Code:

package 
{
    import flash.display.Loader;
    import flash.display.MovieClip;
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.ProgressEvent;
    import flash.net.URLRequest;
    
    import com.greensock.TweenLite;
 
    public class Preloader extends MovieClip {
            
        // objects
        private var eddy:MovieClip = new eddy_mc();
        private var vroni:MovieClip = new vroni_mc();
        private var ute:MovieClip = new ute_mc();
        private var robert:MovieClip = new robert_mc();
        
        // array
        private var buddys:Array = new Array(4);
        
        // container
        private var container:Sprite = new Sprite();
        
        // loader for external swf
        private var myLoader:Loader;
        
        
        public function Preloader():void {
            
            // prepare tween
            eddy.scaleX = 0;
            eddy.scaleY = 0;
            vroni.scaleX = 0;
            vroni.scaleY = 0;
            ute.scaleX = 0;
            ute.scaleY = 0;
            robert.scaleX = 0;
            robert.scaleY = 0;
            
            // array befüllen
            buddys.push(eddy, vroni, ute, robert);
            
            for(var i:int=0; i < buddys.length; i++) {
 
            //Set the x position for the circle
            buddys[i].x = i * 20;
 
            //Add to container
            container.addChild(buddys[i]);
            }
            
            // add to display
            addChild(container);
            
            //Position center
            container.x = stage.stageWidth / 2 - container.width / 2;
            container.y = stage.stageHeight / 2 - container.height / 2;
            
            // load swf
            loadContent("./seife.swf");
 
        }
        
        // Externe SWFs laden
        private function loadContent(contentName:String) {
 
            myLoader = new Loader();
            var mRequest:URLRequest = new URLRequest(contentName);
            myLoader.contentLoaderInfo.addEventListener(Event.COMPLETE, done);
            myLoader.contentLoaderInfo.addEventListener(ProgressEvent.PROGRESS, load);
            myLoader.load(mRequest);
        }
        
        
        // call while loading, update preloader
        private function load(e:ProgressEvent):void{
            
            //Check how much has been loaded (in percentages)
            var loadedPercentage:Number = (e.bytesLoaded / e.bytesTotal) * 100;
            
            trace("geladen" + loadedPercentage);
            
            // 25% loaded, tween eddy
            if (loadedPercentage == 25) {
 
            //Tween eddy
            TweenLite.to(buddys[0], 0.5, {scaleX:1, scaleY:1});
            }
            
            // 50% loaded, tween vroni
            if (loadedPercentage == 50) {
 
            //Tween vroni
            TweenLite.to(buddys[1], 0.5, {scaleX:1, scaleY:1});
            }
            
            // 75% loaded, tween ute
            if (loadedPercentage == 75) {
 
            //Tween ute
            TweenLite.to(buddys[2], 0.5, {scaleX:1, scaleY:1});
            }
            
            // 100% loaded, tween robert
            if (loadedPercentage == 100) {
 
            //Tween robert
            TweenLite.to(buddys[3], 0.5, {scaleX:1, scaleY:1});
            }
            
        }
        
        // loading has finished
        private function done(e:Event):void{
            
            // remove all
            removeChild(container);
            removeChild(text);
            removeChild(hg);
            
            addChild(myLoader);
            
            }
    
    }
    
} 

[Martin Kraft]

Eigentlich müsste Dir FlashDevelop doch die Zeile anzeigen?

Ich vermute mal, dass im Konstruktor die Eigenschaft stage einfach noch nicht belegt ist und der Fehler deshalb hier auftritt:

PHP-Code:

//Position center
container.x = stage.stageWidth / 2 - container.width / 2;
container.y = stage.stageHeight / 2 - container.height / 2; 


stage ist erst belegt, wenn sich das DisplayObject in der Anzeigeliste befindet, und das kann man so abfangen:

PHP-Code:

if (stage) stageInit();
else addEventListener(Event.ADDED_TO_STAGE, stageInit);

//...

private function stageInit(e:Event=null):void {
    removeEventListener(Event.ADDED_TO_STAGE, stageInit);
    
    // Aktionen, die auf stage zugreifen
} 


[sille]

Er gibt mir keine Zeile an, nur: at Preloader()

Hm... Habs probiert, hat leider nicht funktioniert

Übrigens: Die Fehlermeldung hab ich im Flash angezeigt bekommen
Seltsamerweise bekomme ich TypeError Meldungen immer nur in der Flash-Ausgabe und nicht im Flashdeveloper angezeigt, da is doch bestimmt irgendwas noch nicht richtig eingestellt, oder?

[sille]

Habs jetzt nochmal angepasst, der Fehler liegt irgendwo hier:
at Preloader/stageInit()


Aktueller Code:

package 
{
    import flash.display.Loader;
    import flash.display.MovieClip;
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.ProgressEvent;
    import flash.net.URLRequest;
    
    import flash.display.Stage;
    
    import com.greensock.TweenLite;
 
    public class Preloader extends MovieClip {
            
        // objects
        private var eddy:MovieClip = new eddy_mc();
        private var vroni:MovieClip = new vroni_mc();
        private var ute:MovieClip = new ute_mc();
        private var robert:MovieClip = new robert_mc();
        
        // array
        private var buddys:Array = new Array(4);
        
        // container
        private var container:Sprite = new Sprite();
        
        // loader for external swf
        private var myLoader:Loader;
        
        
        public function Preloader():void {
 
            addEventListener(Event.ADDED_TO_STAGE, stageInit);
 
        }
        
        private function stageInit(e:Event=null):void {
            
            // array befüllen
            buddys.push(eddy, vroni, ute, robert);
            
            for(var i:int=0; i < buddys.length; i++) {
 
            //Set the x position
            buddys[i].x = i * 20;
            
            //prepare tween
            buddys[i].scaleX = 0;
            buddys[i].scaleY = 0;
 
            //Add to container
            container.addChild(buddys[i]);
            }
            
            // add to display
            addChild(container);
            
            //Position center
            container.x = stage.stageWidth / 2 - container.width / 2;
            container.y = stage.stageHeight / 2 - container.height / 2;
            
            // load swf
            loadContent("./seife.swf");
        }  
        
        //------------------------ Externe SWFs laden  ------------------------
        private function loadContent(contentName:String) {
            
 
            myLoader = new Loader();
            var mRequest:URLRequest = new URLRequest(contentName);
            myLoader.contentLoaderInfo.addEventListener(Event.COMPLETE, done);
            myLoader.contentLoaderInfo.addEventListener(ProgressEvent.PROGRESS, load);
            myLoader.load(mRequest);
        }
        
        
        // call while loading, update preloader
        private function load(e:ProgressEvent):void{
            
            //Check how much has been loaded (in percentages)
            var loadedPercentage:Number = (e.bytesLoaded / e.bytesTotal) * 100;
            
            trace("geladen" + loadedPercentage);
            
            // 25% loaded, tween eddy
            if (loadedPercentage == 25) {
 
            //Tween eddy
            TweenLite.to(buddys[0], 0.5, {scaleX:1, scaleY:1});
            }
            
            // 50% loaded, tween vroni
            if (loadedPercentage == 50) {
 
            //Tween vroni
            TweenLite.to(buddys[1], 0.5, {scaleX:1, scaleY:1});
            }
            
            // 75% loaded, tween ute
            if (loadedPercentage == 75) {
 
            //Tween ute
            TweenLite.to(buddys[2], 0.5, {scaleX:1, scaleY:1});
            }
            
            // 100% loaded, tween robert
            if (loadedPercentage == 100) {
 
            //Tween robert
            TweenLite.to(buddys[3], 0.5, {scaleX:1, scaleY:1});
            }
            
        }
        
        // loading has finished
        private function done(e:Event):void{
            
            // remove all
            removeChild(container);
            removeChild(text);
            removeChild(hg);
            
            addChild(myLoader);
            
            }
 
    }
    
} 

[ING]

Zitat von sille

Übrigens: Die Fehlermeldung hab ich im Flash angezeigt bekommen
Seltsamerweise bekomme ich TypeError Meldungen immer nur in der Flash-Ausgabe und nicht im Flashdeveloper angezeigt, da is doch bestimmt irgendwas noch nicht richtig eingestellt, oder?

nein, das ist ein laufzeitfehler den die ide so nicht feststellen kann, der tritt erst zur laufzeit auf, heißt der code ansich ist fehlerfrei, die programmlogik nicht.

eigentlich wird aber auch bei einem laufzeit fehler die zeile (in klammer) so wie die komplette history zum fehler angezeigt

[Martin Kraft]

Schreib mal:

PHP-Code:

private var buddys:Array = []; 


statt

PHP-Code:

private var buddys:Array = new Array(4) 


Aktuell erzeugst Du nämlich ein Array mit 4 leeren Element, an das Du dann mit push nochmal 4 anhängst. Das sind dann insgesamt 8, wovon die ersten 4 aber null sind, was wiederum für Deine Fehlermeldung verantwortlich sein dürfte!

[sille]

Das war der Fehler!

Vielen Dank!

Noch eine Frage:

Über Download simulieren kann ich doch den Preloader testen.
Hast du zufällig ne Ahnung warum der bei mir selbst bei niedriger Einstellung sauschnell geladen ist?