Timer neu starten nach Click auf Button

[Brakelkatze]

Hallo Helfer,

bin ein absoluter Einsteiger, was Actionscript betrifft, und habe ein Problem mit einem Timer. Ich habe einen Tween auf der x-Achse umgesetzt, der alle 5 Sekunden einen der 3 MCs (red_cnt, green_cnt und blue_cnt) von rechts nach links auf die Bühne fahren lässt. Dazu gibt es noch 3 Buttons (red_btn, green_btn, blue_btn), die bei Anklicken ihr MC-Pendant auf die Bühne holen (vgl. den content slider auf FatSak Sitzsäcke und Sitzkissen Online Shop - FatSak - Mehr als nur ein Sitzsack).

Soweit, so gut. Was jetzt aktuell nicht funktioniert und wo ich auch nichts zu finden kann bzw. nicht verstehe, ist folgendes: wenn ich einen Button klicke, fährt zwar das gewünschte Bild auf die Bühne, jedoch zählt der Timer im Hintergrund weiter hoch bis 5 Sekunden, und dann wird direkt wieder das nächste Bild gewechselt. Ich möchte jedoch, dass der Timer bei Klick auf einen Button neu gestartet wird. Ich habe das bereits mit reset usw. versucht, aber ohne Erfolg. Wäre super, wenn mir ein fähiger AS-Programmierer weiterhelfen könnte

Hier mein Code:

import flash.events.MouseEvent;
import fl.transitions.Tween;
import fl.transitions.easing.*;
import flash.utils.Timer;
import flash.events.TimerEvent;
 
//legt Handcursor auf movie_clips, imitiert Buttoneigenschaft
red_cnt.buttonMode = true;
blue_cnt.buttonMode = true;
green_cnt.buttonMode = true;
 
//Anzeigedauer Content und Tween-Geschwindigkeit
var anzeigedauer = 5000;
var tweendauer = 3;
 
//Startbedingung
var aktuell_cnt = red_cnt;
 
//Timer für Bildwechsel
var myTimer:Timer = new Timer(anzeigedauer,0);
myTimer.addEventListener("timer", changecontent);
myTimer.start();
 
//Funktion für Timerevent heißt "changecontent"
function changecontent(event:TimerEvent):void{
    if (aktuell_cnt == red_cnt) {
    var red_out:Tween = new Tween(aktuell_cnt, "x", Strong.easeOut, 0, -120, tweendauer, true);
    var greencontent_in:Tween = new Tween(green_cnt, "x", Strong.easeOut, 120, 0, tweendauer, true);
    aktuell_cnt = green_cnt;    
    }
 else if (aktuell_cnt == green_cnt) {
    var green_out:Tween = new Tween(aktuell_cnt, "x", Strong.easeOut, 0, -120, tweendauer, true);
    var bluecontent_in:Tween = new Tween(blue_cnt, "x", Strong.easeOut, 120, 0, tweendauer, true);
    aktuell_cnt = blue_cnt; 
    }
 else {
    var blue_out:Tween = new Tween(aktuell_cnt, "x", Strong.easeOut, 0, -120, tweendauer, true);
    var redcontent_in:Tween = new Tween(red_cnt, "x", Strong.easeOut, 120, 0, tweendauer, true);
    aktuell_cnt = red_cnt;
    }
}
 
//Buttons für Benutzerinteraktion
//GRÜNER BUTTON
green_btn.addEventListener(MouseEvent.CLICK, greenClick);
function greenClick(Event:MouseEvent):void{
    var aktuell_out:Tween = new Tween(aktuell_cnt, "x", Strong.easeOut, 0, -120, tweendauer, true);
    var greencontent_in:Tween = new Tween(green_cnt, "x", Strong.easeOut, 120, 0, tweendauer, true);
    aktuell_cnt = green_cnt;
    
}
 
//BLAUER BUTTON
blue_btn.addEventListener(MouseEvent.CLICK, blueClick);
function blueClick(Event:MouseEvent):void{
    var aktuell_out:Tween = new Tween(aktuell_cnt, "x", Strong.easeOut, 0, -120, tweendauer, true);
    var bluecontent_in:Tween = new Tween(blue_cnt, "x", Strong.easeOut, 120, 0, tweendauer, true);
    aktuell_cnt = blue_cnt;
    
    }
        
//ROTER BUTTON
red_btn.addEventListener(MouseEvent.CLICK, redClick);
function redClick(Event:MouseEvent):void{
    var aktuell_out:Tween = new Tween(aktuell_cnt, "x", Strong.easeOut, 0, -120, tweendauer, true);
    var redcontent_in:Tween = new Tween(red_cnt, "x", Strong.easeOut, 120, 0, tweendauer, true);
    aktuell_cnt = red_cnt;
    
    } 

[hmpf]

so sollte es doch gehen?

//ROTER BUTTON
red_btn.addEventListener(MouseEvent.CLICK, redClick);
function redClick(Event:MouseEvent):void{
    var aktuell_out:Tween = new Tween(aktuell_cnt, "x", Strong.easeOut, 0, -120, tweendauer, true);
    var redcontent_in:Tween = new Tween(red_cnt, "x", Strong.easeOut, 120, 0, tweendauer, true);
    aktuell_cnt = red_cnt;
   
timer.reset();
timer.start();
    } 

[Brakelkatze]

Hallo,

leider funktioniert das nicht, ich erhalte einen Compiler-Error:

"1120: Access of undefined property mytimer."

Was sagt mir die Meldung?

Danke für Eure Hilfe.

[thomas_E]

"1120: Access of undefined property mytimer."
Was sagt mir die Meldung?

das er nichts namens "mytimer" kennt. hast du den vielleicht umbenannt?
edit: myTimer, großes T!

PHP-Code:

//ungetestet
import flash.events.MouseEvent;
import fl.transitions.Tween;
import fl.transitions.easing.*;
import flash.utils.Timer;
import flash.events.TimerEvent;
 
//Anzeigedauer Content und Tween-Geschwindigkeit
var anzeigedauer = 5000;
var tweendauer = 3;
 
//Startbedingung
var buttons:Array = [red_btn, green_btn, blue_btn];
var contents:Array = [red_cnt, green_cnt, blue_cnt];
var currentContent:Sprite = contents[0];

//Timer für Bildwechsel
var timer:Timer = new Timer(anzeigedauer, 0);
    timer.addEventListener(TimerEvent.TIMER, showNext);
    timer.start();

//legt Handcursor auf movie_clips, imitiert Buttoneigenschaft
var item:InteractiveObject;
for each(item in contents)
    item.buttonMode = true;


//Buttons für Benutzerinteraktion
for each(item in buttons)
    item.addEventListener(MouseEvent.CLICK, onBtnClick);
    
function onBtnClick(e:MouseEvent):void
{
    goto( buttons.indexOf(e.currentTarget) );
    timer.reset();
    timer.start();
}


//springt zum nächten Objekt in der Liste
function showNext(e:Event=null):void
{
    var i:int = contents.indexOf(currentContent) + 1;
    goto( i==contents.length? 0: i );
}

//springt zu einer bestimmten Position in der Liste
function goto(index:int):void
{
    if(index < 0 || index >= contents.length) return;
    
    new Tween(currentContent, "x", Strong.easeOut, 0, -120, tweendauer, true);
    currentContent = contents[ index ];
    new Tween(currentContent, "x", Strong.easeOut, 120, 0, tweendauer, true);
} 


[Brakelkatze]

Leute, großartig :-) es funktioniert. Und ich bin echt blind...

Danke vielmals.

[Brakelkatze]

Und Danke Thomas für das Aufzeigen eines gekürzten Quellcodes. Dass man hier irgendwie mit Arrays arbeiten sollte, war mir bewusst, nur fehlt mir da einfach der Hintergrund. Ich brauchs dann auch nicht täglich...

Aber sauber, kann ich viel draus mitnehmen :-)