Sind leere Displayobjekte durchklickbar?

[markox]

Hallo, ich will verhindern, dass nach dem ein Objekt angeklickt wurde und ein Tween läuft andere Objekte anklickbar sind. Deshalb habe ich eine leere Shape mit der Größe der Bühne gemacht und beim Klicken geadded. Wenn der Tween durch ist wieder removed. Ich dachte, wenn die Shape über den Buttons liegt könnt ich nicht durch sie durch klicken?

Eine Alternative wäre natürlich einen gefüllten MovieClip in die Bibliothek zu legen und den zu nehmen, oder die Shape mit draw zu füllen. Diese Massnahmen wiegen mir aber zu viel für so eine simple Sache. Gibts da eventuell noch was anderes, was man mit wenig Code unsichtbar über die Bühne legen kann oder ist es möglich irgendwie grundsätzlich die Funktion des MouseEvents zu sperren, währen der Tween läuft?

[Omega Psi]

EventListener einfach entfernen, bevor der Tween startet und wieder setzen, wenn der Tween durch ist.

[markox]

Zitat von Omega Psi

EventListener einfach entfernen, bevor der Tween startet und wieder setzen, wenn der Tween durch ist.

Naja, so einfach ist das nicht, da es sich um 24 Instanzen einer Klasse handelt die alle ihren eigenen EventListener haben.

[speedhost]

Hallo
Vlt. mit einer Variablen
etwa so:

var clickVar:Boolean=true;
 
//in der Listener Function abfragen:
if(!clickVar){return;}else {/*starteTween*/ clickVar=false;}
 
//und im Tween mit onMotionFineshed: clickVar =true; 
 

MFG

[Omega Psi]

Dann mach einen und differenziere darin die targets. Dann kannst du die einfach entfernen.

[rendner[i]]

Wenn dein Aufbau so wie der ist, kannst du mit mouseChildren den ganzen Spaß stoppen.

PHP-Code:

package  
{
    import flash.display.*;
    import flash.events.*;
    
    public class Test extends Sprite
    {
        
        public function Test() 
        {
            super();
            
            init();
        }
        
        private function init():void
        {
            // create dummy instances
            for( var i:int = 0; i < 5; i++ )
            {
                var s:Sprite = new Sprite();
                
                s.graphics.beginFill( 0xFF0000 );
                s.graphics.drawRect( 0, 0, 20, 20 );
                s.graphics.endFill();
                
                s.addEventListener( MouseEvent.CLICK, onClick );
                
                s.x = i * 30;
                addChild( s );
            }
        }
        
        private function onClick( event:MouseEvent ):void
        {
            trace("click: " + event.target );
            
            // disable mouseEvent
            this.mouseChildren = false;
        }
    }
} 


[markox]

Zitat von speedhost

Hallo
Vlt. mit einer Variablen

Das könnte ich mal versuchen, da ich sowieso schon diese extra Klasse überall rumreiche um um zu wissen welches Objekt angeklickt wurde und welche Koordinaten es hat:

package {
    public class Selected {
        private var _zahl:String;
        private var _xK:int;
        private var _yK:int;        
        public function Selected():void {
        }
        public function get zahl():String {
            return this._zahl;
        }
        public function set zahl(zahl:String):void {
            this._zahl = zahl;
        }
        public function get xK():int {
            return this._xK;
        }
        public function set xK(xK:int):void {
            this._xK = xK;
        }
        public function get yK():int {
            return this._yK;
        }
        public function set yK(yK:int):void {
            this._yK = yK;
        }
    }
} 

Zitat von Omega Psi

Dann mach einen und differenziere darin die targets. Dann kannst du die einfach entfernen.

Tut mir leid, aber ich habe keine Ahnung wie ich das machen soll.

Zitat von rendner[i]

Wenn dein Aufbau so wie der ist, kannst du mit mouseChildren den ganzen Spaß stoppen.

Da steige ich jetzt so auf den Ersten Blick auch nicht ganz durch, mouseChildren kenn ich noch nicht, das werde ich mir mal genauer ankucken.

Also, danke erstmal für die Antworten. Aber ich merk schon, dass mein Code mittlerweile so verworren geworden ist, dass es mir schwer fällt meine Proble richtig zu beschreiben. Deshalb setzt ich jetzt einfach noch mal zwei Klassen hier drunter auf die ich mich oben bezogen hatte:

package {
    import flash.display.*;
    import flash.events.*;
    import fl.transitions.TweenEvent;
    public class Main extends MovieClip {
        private var snowFlake:SnowFlake;
        private var numFlakes:int;
        private var selected:Selected=new Selected();
        private var blockingShape:Shape=new Shape();
        private var sterneArray:Array=new Array();
        private var datum:Date=new Date();
        private var tag:int=datum.getDate();
        private var monat:int=datum.getMonth()+1;
        private var imgLoader:IMGLoader;
        private var einStern:Stern;
        private var inhalt:Inhalt;
        private var bufferStern:Stern;
        private var anzahlSterne:int;
        private var SternXK:int;
        private var SternYK:int;
        private var zufallsZahl:int;
        private var spalte:int;
        private var zeile:int;
        public var zahl:int;
        public function Main() {
            makeBackground();
            debugger();
            lastDayExtender();
            dateChecker();
        }
        private function makeBackground():void {
            numFlakes = 1000;
            for (var i:int; i<numFlakes; i++) {
                createFlakes();
            }
            imgLoader=new IMGLoader("imgs/background.jpg");
            addChildAt(imgLoader,0);
        }
        function createFlakes():void {
            snowFlake=new SnowFlake();
            addChildAt(snowFlake,0);
        }
        private function debugger():void {
            //zum testen
            tag=1;
            monat=12;
        }
        private function lastDayExtender():void {
            //letztes Türchen kann bis Monatsende geöffnet werden
            if (tag>24) {
                tag=24;
            }
        }
        private function dateChecker():void {
            if (monat!=12) {
            } else {
                buildInterface();
            }
        }
        private function buildInterface():void {
            //24 Objekte vom Typ "Stern" erzeugen und ins Array pushen
            for (var i:int=1; i<=24; i++) {
                einStern=new Stern(i.toString(),selected);
                einStern.addEventListener("onMotionFinish",motionFinishHandler);
                einStern.addEventListener("onStarSelected",starSelectedHandler);
                sterneArray.push(einStern);
                //Auf Wunsch die alten Türchen automatisch öffnen
                /*if (i<=tag) {
                einStern.filmLaden();
                }*/
            }
            //Sterne durchmischen
            anzahlSterne=sterneArray.length;
            bufferStern=new Stern("bufferStern",selected);
            //jedes Element mit einem anderen zufälligen tauschen
            for (i=0; i<anzahlSterne; i++) {
                zufallsZahl=Math.floor(Math.random()*anzahlSterne);
                //tauschen
                bufferStern=sterneArray[i];
                sterneArray[i]=sterneArray[zufallsZahl];
                sterneArray[zufallsZahl]=bufferStern;
            }
            //Sterne positionieren und anzeigen
            for (i=0; i<24; i++) {
                spalte=i%4;
                zeile=Math.floor(i/4);
                SternXK=60+spalte*100;
                SternYK=50+zeile*100;
                sterneArray[i].positionieren(SternXK,SternYK);
                addChildAt(sterneArray[i],1);
            }
        }
        private function starSelectedHandler(event:Event):void {
            blockingShape.width=800;
            blockingShape.height=600;
            addChildAt(blockingShape,2);
        }
        //Annimation nach klicken auf Stern beendet?
        private function motionFinishHandler(event:Event):void {
            inhalt=new Inhalt(selected);
            inhalt.x=selected.xK;
            inhalt.y=selected.yK;
            addChild(inhalt);
            removeChild(blockingShape);
        }
    }
} 

package {
    import flash.display.*;
    import flash.text.*;
    import flash.events.*;
    import fl.transitions.Tween;
    import fl.transitions.easing.*;
    import fl.transitions.TweenEvent;
    public class Stern extends Sprite {
        private var dateiName:String;
        private var loader:Loader;
        private var rotationsgrad:Number=new Number(0);
        private var rotationTween:Tween;        
        private var alphaTween:Tween;
        private var selected:Selected=new Selected();
        public function Stern(zahl:String,selected:Selected) {
            this.zahl.text=zahl;
            this.selected=selected;
            this.addEventListener(MouseEvent.MOUSE_DOWN,mouseDownHandler);
        }
        private function mouseDownHandler(event:MouseEvent):void {
            this.removeEventListener(MouseEvent.MOUSE_DOWN,mouseDownHandler);
            //setzen der aktuell gewählten Zahl
            selected.zahl=zahl.text;
            selected.xK=this.x;
            selected.yK=this.y;
            removeChild(zahl);
            rotationTween = new Tween(this, "rotation", Regular.easeInOut, 0, 360, 5, true);
            alphaTween = new Tween(this, "alpha", Regular.easeOut, 1, 0, 5, true);
            alphaTween.addEventListener(TweenEvent.MOTION_FINISH,motionFinishHandler);      
            dispatchEvent(new Event("onStarSelected")); 
        }
        private function motionFinishHandler(event:TweenEvent):void {
            parent.removeChild(this);
            dispatchEvent(new Event("onMotionFinish")); 
        }
        public function positionieren(sternXK:int,sternYK:int) {
            //wird von Main aufgerufen
            this.x=sternXK;
            this.y=sternYK;
        }
    }
} 

[markox]

Was es alles gibt .
stage.mouseChildren=false;
stage.mouseChildren=true;
...zwei Zeilen, genau was ich brauche. Danke!