For-Schleife mit URLRequest

[rnd]

Hallo,

ich möchte beim Klick auf einen Movieclip ein *.jpg Bild auf die Bühne laden.
Bisher habe ich diesen Code:

var picloader:Loader = new Loader();
picloader.addEventListener(IOErrorEvent.IO_ERROR, onIOError);
picloader.contentLoaderInfo.addEventListener(Event.COMPLETE, onComplete);

function onComplete(evt:Event):void
{
	try
	{
		picloader.width = 200;
		picloader.height = 150;
		picloader.x = 275;
		picloader.y = 150;
		picloader.removeEventListener(Event.COMPLETE, onComplete);
		picloader.removeEventListener(IOErrorEvent.IO_ERROR, onIOError);
	}
	catch (err:Error)
	{
		trace(err.message);
	}
}

function onIOError(evt:IOErrorEvent):void
{
	trace(evt.text);
}
addChild( picloader );

for (var i:int = 1; i<=8; i++)
{
	regio_gesamt["regio_" + i].addEventListener(MouseEvent.CLICK, click_regio);
	function click_regio(evt:MouseEvent):void
	{
		picloader.load(new URLRequest("images/1.jpg"));
	}
}

Das funktioniert soweit auch schon, es wir nur bei jedem der Movieclips das bild "1.jpg" geladen. Kann ich die oben fett markierte Zeile so ändern, dass sie mit der Variable "i" funktioniert?
A la picloader.load(new URLRequest("images/"+[i]+".jpg")); (was leider nicht funktioniert).

Ich möchte folgendes erreichen:
Klick auf MC regio_1 --> 1.jpg wird angezeigt
Klick auf MC regio_6 --> 6.jpg wird angezeigt

Vielen Dank schon mal!

[Martin Kraft]

Hallo und willkommen im Forum!

Versuch's mal so:

import flash.display.InteractiveObject;
import flash.display.Loader;
import flash.events.Event;
import flash.events.IOErrorEvent;
import flash.events.MouseEvent;
import flash.net.URLRequest;
import flash.utils.Dictionary;
 
////
 
function onComplete(evt:Event):void {
    if(picloader) {
        picloader.width = 200;
        picloader.height = 150;
        picloader.x = 275;
        picloader.y = 150;
        picloader.removeEventListener(IOErrorEvent.IO_ERROR, onIOError);
        picloader.contentLoaderInfo.removeEventListener(Event.COMPLETE, onComplete);
    }
}
 
function onIOError(evt:IOErrorEvent):void {
    trace(evt.text);
}
 
function clickRegio(evt:MouseEvent):void {
    picloader.addEventListener(IOErrorEvent.IO_ERROR, onIOError);
    picloader.contentLoaderInfo.addEventListener(Event.COMPLETE, onComplete);
    
    var url:String = urlsByBtn[evt.currentTarget] as String;
    picloader.load(new URLRequest(url));
}
 
////
 
var picloader:Loader = new Loader();
addChild(picloader);
 
var urlsByBtn:Dictionary = new Dictionary();
var btn:InteractiveObject;
 
for (var i:uint = 1; i <= 8; i++) {
    if(btn  = regio_gesamt["regio_" + i] as InteractiveObject){
        btn.addEventListener(MouseEvent.CLICK, clickRegio);
        urlsByBtn[btn] = "images/" + i + ".jpg";
    } else {
        trace("regio_" + i + " ist leider nicht vorhanden!");
    }
} 

[rnd]

Hallo!

Herzlichen Dank für die schnelle Hilfe, das funktioniert einwandfrei

Ein schönes neues Jahr wünsch ich Ihnen!