removeChild();

[Timyy]

Hallo,

Ich hatte vor kurzem schon ein Thema mit einem sehr ähnlichem Problem erstellt. Dort hatte ich ein MovieClip aus der Bibliothek auf die Bühne gestellt und wollte es dann mit removeChild wieder entfernen:

removeChild();

Nun möchte ich Objekte ertellen welche ich per AS gezeichnet habe und nicht in der Bibliothek vorhanden sind...
Logischerweise funktioniert die Methode vom letzten Thema nicht mehr.

PHP-Code:

var kreis:MovieClip = new MovieClip();    
...
evt.target.alpha -= 0.001;
    if(evt.target.alpha <= 0){
        //removeChild(evt.target);
    } 


Ich hatte versucht das ganze folgendermaßen wie im letzten Thema zu lösen:

PHP-Code:

var kreis:MovieClip = new MovieClip();
...
evt.target.alpha -= 0.001;
    if(evt.target.alpha <= 0){
        //removeChild(evt.target as MovieClip);
    } 


Bei dieser Anwendung gibt er zwar keine Fehlfermeldung mehr aus, jedoch ruckelt es sehr sehr stark und der flashplayer reagiert nicht mehr sodass er beendet werden muss.

Ich hoffe jemand kann mir helfen und bedanke mich schon einmal im vorraus!

[Omega Psi]

Bei allem nötigen Respekt, wie soll man bei drei Zeilen Code eine Aussage treffen können?

[Timyy]

Bei allem nötigen Respekt, wie soll man bei drei Zeilen Code eine Aussage treffen können?

naja, ich habe ja auch meinen letzten beitrag verlinkt. In diesem stehet noch mehr als hier. Ich fand es überflüssig hier nocheinmal alles zu schreiben, wenn ich doch auch einen anderen beitrag verlinken kann.

Trotz dessen hier mal der code:

PHP-Code:

var pixelAnzahl:int = 100;
var pixelRadius:Number = 1;

stage.addEventListener(MouseEvent.CLICK, klick);

function klick(evt:MouseEvent){
    for(var i = 0; i < pixelAnzahl; i++){
        var kreis:MovieClip = new MovieClip();
        
        kreis.graphics.beginFill(0xff9933, 1);
        kreis.graphics.drawCircle(mouseX, mouseY, pixelRadius);
        
        kreis.addEventListener(Event.ENTER_FRAME, bewegung);
        
        kreis.speedX = (-2 + Math.random()*(2-(-2)+1)); 
        kreis.speedY = (-3 + Math.random()*(2-(-3)+1));
        
        addChild(kreis);
    }
}

function bewegung(evt:Event){
    evt.target.x += evt.target.speedX;
    evt.target.y += evt.target.speedY;
    
    evt.target.speedY += 0.02;
    evt.target.speedX -= (0 - evt.target.speedX)/15;
    
    evt.target.alpha -= 0.001;
    if(evt.target.alpha <= 0){
        //removeChild(evt.target);
        //removeChild(evt.target as MovieClip);
    }
} 


[Timyy]

Weiss niemand wie ich ein Objekt entferne dass ich zuvor per ActionScript erstellt habe?

Ich habe bisher viele methoden ausprobiert, doch bei allen hängt sich flash auf und reagiert nicht mehr oder gibt eine fehlermeldung aus:


removeChild( getChildByName("kreis") )

removeChild(evt.target as MovieClip);

evt.target.removeChild(this);

evt.target.removeChild(evt.target);

removeChild(evt.target);


Ich hoffe jemand weiss eine Lösung für dieses Problem.

[thomas_E]

deine Perfomance-probleme verdankst du Event.ENTER_FRAME. Damit solltest du sparsamer umgehen, und nicht jedem einzelnen Punkt einen eigenen Event-listener geben.

removeChild(evt.target as MovieClip); ist zwar korrekt, doch entfernst du nicht den Event-listener.

hier mal eine performantere Version:

var pixelAnzahl:int = 100;
var pixelRadius:Number = 1;
var pixelContainer:Sprite = new Sprite();
    pixelContainer.addEventListener(Event.ENTER_FRAME, bewege);
addChild(pixelContainer);
 
stage.addEventListener(MouseEvent.CLICK, klick);
 
function klick(evt:MouseEvent):void {
    for(var i = 0; i < pixelAnzahl; i++){
        var kreis:MovieClip = new MovieClip();
            kreis.graphics.beginFill(0xff9933, 1);
            kreis.graphics.drawCircle(0, 0, pixelRadius);
        
            kreis.x = mouseX;
            kreis.y = mouseY;
            
            kreis.vx = Math.random() * 4 - 2;
            kreis.vy = Math.random() * 6 - 3;
        
        pixelContainer.addChild(kreis);
    }
}
 
function bewege(evt:Event):void {
    var i:int = pixelContainer.numChildren;
    while(i-- > 0){
        var kreis:MovieClip = pixelContainer.getChildAt(i) as MovieClip;
        
        kreis.x += kreis.vx;
        kreis.y += kreis.vy;
        
        kreis.vy += .02;
        kreis.vx *= 1.0667;
        
        kreis.alpha -= .001;
        
        if(kreis.alpha <= 0){
            pixelContainer.removeChild(kreis);
        }
    }
} 

[Timyy]

Vielen Dank!

Funktioniert einwandfrei